How to print out the text for Info record in ME23?

Question

Dear all,
I need to print out a report of PO data. need to print out the text from Info record note (like the picture shown below) in ME23, how should I pull that field and display out?
I need the solution urgently. Hope experts can help.
Thank you very much.
[http://img293.imageshack.us/img293/238/inforecordnd1.png]

Answer 1

Please check below sample code:
PARAMETERS: p_ebeln TYPE ebeln OBLIGATORY.
TYPES: BEGIN OF ty_ekpo,
         ebeln TYPE ebeln,
         ebelp TYPE ebelp,
       END OF ty_ekpo.
DATA: i_ekpo TYPE TABLE OF ty_ekpo,
      wa_ekpo TYPE ty_ekpo.
DATA: l_name TYPE tdobname,
      i_tline TYPE TABLE OF tline,
      wa_tline TYPE tline.
CONSTANTS: c_id   TYPE tdid VALUE 'F02',
           c_object TYPE tdobject VALUE 'EKPO'.
AT SELECTION-SCREEN.
  SELECT SINGLE ebeln INTO p_ebeln
         FROM ekko
         WHERE ebeln = p_ebeln.
  IF sy-subrc NE 0.
    MESSAGE e001(00) WITH 'Enter valid PO Number'.
  ENDIF.
START-OF-SELECTION.
  SELECT ebeln ebelp INTO TABLE i_ekpo
         FROM ekpo
         WHERE ebeln = p_ebeln.
  LOOP AT i_ekpo INTO wa_ekpo.
    CONCATENATE wa_ekpo-ebeln wa_ekpo-ebelp
       INTO l_name.
    CALL FUNCTION 'READ_TEXT'
      EXPORTING
        id                      = c_id
        language                = sy-langu
        name                    = l_name
        object                  = c_object
      TABLES
        lines                   = i_tline
      EXCEPTIONS
        id                      = 1
        language                = 2
        name                    = 3
        not_found               = 4
        object                  = 5
        reference_check         = 6
        wrong_access_to_archive = 7
        OTHERS                  = 8.
    IF sy-subrc EQ 0.
      LOOP AT i_tline INTO wa_tline.
        WRITE:/ wa_tline-tdline.
        " Format wa_tline-tdline in the way you need to print out
      ENDLOOP.
    ENDIF.
  ENDLOOP.
Regards
Eswar