How to set a keyboard shortcut for open with VLC player

Question

Hey everyone!
I have reffered the earlier discussion upon creating a shortcut for the open with function and the below is the correct answer for it by using applescript editor submitted by Barney. However, I couldn't get past the 1st paragraph. It all just went over my head. Especially the "open (thefilelist) " part. Which filelist is being referred to here? All I want is a shortcut for opening files with .avi, .mpeg, and .3gp exts. with VLC player. Please help me out by providing the exact stuff I need to paste in the applescript.
Thanks
Ok, this one works both on the finder selection and as a droplet:
property htmlList : {"htm", "html"}
property htmleditor : "TextWrangler"
property textList : {"txt", "text"}
property texteditor : "TextEdit"
--property myappextlist: {"ext1","ext2","ext3"}
-- property myappsname: "myAppName" on run
tell application "Finder"
set the fileList to the selection
repeat with aFile in fileList
set theFile to aFile as string
my myOpen(theFile)
end repeat
end tell
end run on open (thefileList)
repeat with i from 1 to number of items in thefileList
set this_item to item i of thefileList
my myOpen(this_item)
end repeat
end open on myOpen(aFileAlias)
set theItemInfo to info for (alias aFileAlias)
if not folder of theItemInfo then
set theExtension to name extension of theItemInfo
if theExtension is in htmlList then
tell application htmleditor
open aFileAlias
activate
end tell
end if
if theExtension is in textList then
tell application texteditor
open aFileAlias
activate
end tell
end if
-- if theExtension is in myappextlist then
-- tell application myAppName
-- open this_item
-- activate
-- end tell
-- end if
end if end myOpen

Answer 1

Luds.R wrote:
I have reffered the earlier discussion
I have the feeling of dropping in in the middle of the conversation.
Anyway, try this
--script begins
property myVLC : "/Applications/VLC/VLC.app"
property myTypes : {"avi", "mpeg", "mpg", "3gp"}
on run
          my vlcTest(myVLC)
          tell application "Finder" to set fileList to selection
          my vlcOpen(fileList)
end run
on open fileList
          my vlcTest(myVLC)
          my vlcOpen(fileList)
end open
on vlcTest(myVLC)
          try
  POSIX file myVLC as alias
          on error
                    display dialog "Sorry, could not locate VLC. Please add the correct POSIX path to the script." buttons {"Cancel"} default button 1
          end try
end vlcTest
on vlcOpen(fileList)
          tell application "Finder"
                    repeat with i in fileList
                              if name extension of i is in myTypes then open i using (POSIX file myVLC)
                    end repeat
          end tell
end vlcOpen
--script ends