How to update unique values

Question

I want to update the unique values, if they are not inserted... Please help in this regard
CREATE OR REPLACE PROCEDURE PR IS
lv_operator VARCHAR2(1) := 'N';
TYPE subset_rt IS RECORD
ltt_whse_loc oe_sales_ord_commit.whse_loc%TYPE,
ltt_shape oe_sales_ord_commit.shape%TYPE,
ltt_isize oe_sales_ord_commit.isize%TYPE,
ltt_grade oe_sales_ord_commit.grade%TYPE,
ltt_length oe_sales_ord_commit.length%TYPE,
ltt_pieces NUMBER,
ltt_inv_lbs_commit oe_sales_ord_commit.inv_lbs_commit%TYPE,
ltt_roll_lbs_commit oe_sales_ord_commit.roll_lbs_commit%TYPE,
ltt_ishcom_lbs oe_sales_ord_commit.ishcom_lbs%TYPE);
TYPE subset_aat IS TABLE OF subset_rt
INDEX BY PLS_INTEGER;
aa_subset subset_aat;
errors NUMBER;
dml_errors EXCEPTION;
PRAGMA EXCEPTION_INIT(dml_errors, -24381);
BEGIN
lv_operator := sy_checkpriv(USER,
'SY_OPERATIONS');
SELECT whse_loc,
shape,
isize,
grade,
length,
0,
inv_lbs_commit,
roll_lbs_commit,
ishcom_lbs
BULK COLLECT INTO aa_subset
FROM oe_sales_ord_commit_temp
WHERE processed_datetime IS NULL
AND username = decode(lv_operator,
'Y',
username,
USER);
BEGIN
FORALL indx IN 1 .. aa_subset.COUNT SAVE EXCEPTIONS
INSERT INTO
(SELECT loc,
shape,
isize,
grade,
length,
pieces,
inv_lbs_commit,
roll_lbs_commit,
ishcom_lbs FROM oe_inventory_temp)
VALUES
aa_subset(indx);
EXCEPTION
WHEN OTHERS THEN
*+<<Trap the rows that have failed due to dup_val_on_index exception and update the inv_lbs_commit,+*
*+roll_lbs_commit, ishcom_lbs columns in oe_inventory_temp table>>+*
-- loc,shape, isize,grade, length, pieces are composite primary keys.
errors := SQL%BULK_EXCEPTIONS.COUNT;
DBMS_OUTPUT.PUT_LINE('Number of statements that failed: ' || errors);
FOR i IN 1..errors LOOP
DBMS_OUTPUT.PUT_LINE('Error #' || i || ' occurred during '||
'iteration #' || SQL%BULK_EXCEPTIONS(i).ERROR_INDEX);
DBMS_OUTPUT.PUT_LINE('Error message is ' ||
SQLERRM(-SQL%BULK_EXCEPTIONS(i).ERROR_CODE));
DBMS_OUTPUT.PUT_LINE(aa_subset(SQL%BULK_EXCEPTIONS(i).ERROR_INDEX));
END LOOP;
END;
END PR;
/

Answer 1

Due to the following restriction a number of simple collections is used instead of the collection of records.
[FORALL Statement|http://download.oracle.com/docs/cd/B19306_01/appdev.102/b14261/forall_statement.htm#sthref2742]: You cannot refer to individual record fields within DML statements called by a FORALL statement. Instead, you can specify the entire record with the SET ROW clause in an UPDATE statement, or the VALUES clause in an INSERT statement.
10g syntax of FORALL statement is used:
SQL> select * from a;
       INT DT         STR
         1 10.02.2009 123
         2 11.02.2009 567
SQL> desc a
Name                                      Null?    Type
INT                                       NOT NULL NUMBER(38)
DT                                                 DATE
STR                                                VARCHAR2(20)
SQL> select * from a;
       INT DT         STR
         1 10.02.2009 123
         2 11.02.2009 567
SQL> DECLARE
  2    TYPE T_Int_List IS TABLE OF A.Int%TYPE INDEX BY PLS_INTEGER;
  3    TYPE T_Dt_List IS TABLE OF A.Dt%TYPE INDEX BY PLS_INTEGER;
  4    TYPE T_Str_List IS TABLE OF A.Str%TYPE INDEX BY PLS_INTEGER;
  5  
  6    vInts T_Int_List;
  7    vDts T_Dt_List;
  8    vStrs T_Str_List;
  9 
10    eBulk_Error EXCEPTION;
11    PRAGMA EXCEPTION_INIT(eBulk_Error, -24381);
12  BEGIN
13    vInts(1) := 2;
14    vDts(1) := sysdate - 1;
15    vStrs(1) := '888';
16 
17    vInts(2) := 3;
18    vDts(2) := sysdate - 22;
19    vStrs(2) := '0000';
20 
21    BEGIN
22      FORALL indx IN INDICES OF vInts SAVE EXCEPTIONS
23        INSERT INTO A(Int, Dt, Str)
24          VALUES(vInts(indx), vDts(indx), vStrs(indx));
25    EXCEPTION
26      WHEN eBulk_Error THEN
27        DECLARE
28          vErr_Count INTEGER;
29          vErr_Message VARCHAR2(2000);
30          vErr_Indices T_Int_List;
31        BEGIN
32          vErr_Count := SQL%BULK_EXCEPTIONS.COUNT;
33          -- Getting the indices of rows with duplicate key
34          -- FOR vI IN 1 .. SQL%BULK_EXCEPTIONS.COUNT LOOP - Doesn't work for some reason on 10.2.0.1.0
35          FOR vI IN 1 .. vErr_Count LOOP
36            IF SQL%BULK_EXCEPTIONS(vI).Error_Code <> 1 THEN
37              -- Error other that duplicate key is reraised
38              vErr_Message := SQLERRM(-SQL%BULK_EXCEPTIONS(vI).Error_Code);
39              Raise_Application_Error(-20001, vErr_Message);
40            END IF;
41            vErr_Indices(SQL%BULK_EXCEPTIONS(vI).ERROR_INDEX) := SQL%BULK_EXCEPTIONS(vI).ERROR_INDEX;
42          END LOOP;
43       
44          -- Bulk update
45          FORALL vI IN INDICES OF vErr_Indices
46            UPDATE A SET
47                Dt = vDts(vI),
48                Str = vStrs(vI)
49              WHERE Int = vInts(vI);
50        END;
51    END;
52  END;
53  /
PL/SQL procedure successfully completed.
SQL> select * from a;
       INT DT         STR
         1 10.02.2009 123
         2 09.02.2009 888
         3 19.01.2009 0000Regards,
Dima
Edited by: DimaCit on Feb 10, 2009 10:39 AM