How to upload a file to a BLOB column in the DB using PL/SQL???

Question

Hi
I am trying to upload a file to a BLOB column in my database. I wana do this using some pl/sql procedure.I don't wana use webutil. is it possible??? and if so can anybody help me with this???
Regards
Shiraz

Answer 1

Hello,
This is a stored procedure sample that show how insert into CLOB, BLOB and BFILE columns
CREATE OR REPLACE PROCEDURE Insert_document
     PC$Type IN DOCUMENT.TYP%TYPE
    ,PC$Nom IN DOCUMENT.NOM_DOC%TYPE
    ,PC$Texte IN VARCHAR2
    ,PC$Image IN VARCHAR2 
    ,PC$Fichier IN VARCHAR2
   ) IS
  L$Blob BLOB;
  L$Clob CLOB;
  L$Bfile BFILE;
  LN$Len NUMBER := dbms_lob.lobmaxsize;
  LN$Num NUMBER ;
  LN$src_off PLS_INTEGER := 1 ;
  LN$dst_off PLS_INTEGER := 1 ;
  LN$Langctx NUMBER := dbms_lob.default_lang_ctx ;
  LN$Warn NUMBER;
  BEGIN
    -- Création of new raw --
    If PC$Fichier is not null Then
       L$Bfile := BFILENAME( 'FICHIERS_IN', PC$Fichier );
    End if ;
    -- Creation of temporary objetcs --
    dbms_lob.createtemporary( L$Clob, TRUE ) ;
    dbms_lob.createtemporary( L$Blob, TRUE ) ; 
    -- Loading text in CLOB column --
    If PC$Texte is not null Then
       L$Bfile := BFILENAME( 'FICHIERS_IN', PC$Texte );
       dbms_lob.fileopen(L$Bfile, dbms_lob.file_readonly);
       If dbms_lob.fileexists( L$Bfile ) = 1 Then
         dbms_output.put_line(PC$Texte || ' open' ) ;
         dbms_lob.loadclobfromfile(
                                   L$Clob,                -- Destination CLOB
                                   L$Bfile,               -- Source file pointer
                                   LN$Len,                -- # bytes to read
                                   LN$src_off,            -- Source start position
                                   LN$dst_off,            -- Target start position
                                   dbms_lob.default_csid, -- CSID
                                   LN$Langctx,            -- Language Context
                                   LN$Warn);              -- Warning message
         dbms_lob.fileclose(L$Bfile);
      Else
         raise_application_error( -20100, 'Erreur ouverture ' || PC$Texte ) ;
      End if ;
    End if ;
    -- Loading image in BLOB column --
    If PC$Image is not null Then
       L$Bfile := BFILENAME( 'FICHIERS_IN', PC$Image );
       dbms_lob.fileopen(L$Bfile, dbms_lob.file_readonly);
       dbms_lob.loadblobfromfile(
                                 L$Blob,       -- BLOB de destination
                                 L$Bfile,      -- Pointeur de fichier en entrée
                                 LN$Len,       -- Nombre d'octets à lire
                                 LN$src_off,   -- Position source de départ
                                 LN$dst_off);  -- Position destination de départ
       dbms_lob.fileclose(L$Bfile);
    End if ; 
    -- Save --
    Insert into DOCUMENT (ID, NOM_DOC, TYP, UTILISE, LOB_TEXTE, LOB_DATA, LOB_FICHIER)
           Values( SEQ_DOCUMENT.NEXTVAL, PC$Nom, PC$Type, NULL, L$Clob, L$Blob, L$Bfile ) ; 
    -- Free the temporary objects --
    dbms_lob.freetemporary( L$Clob ) ;
    dbms_lob.freetemporary( L$Blob ) ; 
  END;
/The table structure for this sample is the following:
CREATE TABLE DOCUMENT (
  ID           NUMBER (5) PRIMARY KEY,
  TYP          VARCHAR2 (20),
  UTILISE      VARCHAR2 (30),
  LOB_TEXTE    CLOB,
  LOB_DATA     BLOB,
  LOB_FICHIER  BFILE,
  NOM_DOC      VARCHAR2 (100))
/Francois