How to use BRF plus application in abap programs (Report or Module pool)

Question

Hi All,
I have created an BRF plus application through FDT_WORKBENCH to calculate bonus of the employee with the help of SDN tutorial.
Now my concern is that how can i use this application in my report.
I have also read in the tutorial that we can create BRF plus application through ABAP coding but my question is, if i created an application through FDT_WORKBENCH then how can i use it in my ABAP report.
Thanks a lot in advance.
Regards,
Sheelesh

Answer 1

Hi,
CALLING BRF+ FROM ABAP REPORT PROGRAM :
I think the program may be helpful for you guys.
*CALLING THE BRF+ FROM ABAP REPORT PROGRAM :
REPORT Z_BRFPLUS_REPORT_01.
PARAMETERS : P_SEL TYPE STRING .
TYPES : BEGIN OF TYPE_PRICE ,
        NUMBER TYPE DECFLOAT16 ,
        CURRENCY TYPE STRING ,
        END OF TYPE_PRICE .
DATA : LO_FUNCTION      TYPE REF TO     IF_FDT_FUNCTION ,
       LO_CONTEXT       TYPE REF TO     IF_FDT_CONTEXT ,
       LO_RESULT        TYPE REF TO     IF_FDT_RESULT .
DATA : LO_MESSAGE TYPE REF TO CX_FDT .
FIELD-SYMBOLS : <FS_PRODUCT> TYPE IF_FDT_TYPES=>S_MESSAGE .
DATA : PRODUCT TYPE STRING ,
       LS_PRICE TYPE TYPE_PRICE .
CLEAR LS_PRICE .
PRODUCT = P_SEL .
TRY .
* GET THE BRF PLUS FUNCTION .
  LO_FUNCTION ?= CL_FDT_FACTORY=>IF_FDT_FACTORY~GET_INSTANCE( )->GET_FUNCTION('0050569E629D1ED39DD2090294D9A5BD' ) .
* SET THE BRFPLUS FUNCTION CONTEXT .
  LO_CONTEXT = LO_FUNCTION->GET_PROCESS_CONTEXT( ) .
  LO_CONTEXT->SET_VALUE( IV_NAME = 'PRODUCT' IA_VALUE = PRODUCT ) .
* PROCESS THE BRF PLUS FUNCTION .
  LO_FUNCTION->PROCESS(
               EXPORTING
                 IO_CONTEXT = LO_CONTEXT
               IMPORTING
                 EO_RESULT = LO_RESULT   ) .
* RETRIEVE THE BRF PLUS FUNCTION RESULT .
  LO_RESULT->GET_VALUE(
                IMPORTING
                  EA_VALUE = LS_PRICE ) .
WRITE : LS_PRICE-NUMBER ,
        / LS_PRICE-CURRENCY .
CATCH CX_FDT INTO LO_MESSAGE .
ENDTRY .
Thanks & Regards,
Joyjit Biswas