I need to pass a query in form of string to DBMS_XMLQUERY.GETXML package...the parameters to the query are date and varchar ..please help me..

Question

I need to pass a query in form of string to DBMS_XMLQUERY.GETXML package...the parameters to the query are date and varchar ..please help me build the string .Below is the query and the out put. ( the string is building fine except the parameters are with out quotes)
here is the procedure
create or replace
procedure temp(
    P_MTR_ID VARCHAR2,
    P_FROM_DATE    IN DATE ,
    P_THROUGH_DATE IN DATE ) AS
    L_XML CLOB;
    l_query VARCHAR2(2000);
BEGIN
l_query:=  'SELECT
    a.s_datetime DATETIME,
    a.downdate Ending_date,
    a.downtime Ending_time,
    TO_CHAR(ROUND(a.downusage,3),''9999999.000'') kWh_Usage,
    TO_CHAR(ROUND(a.downcost,2),''$9,999,999.00'') kWh_cost,
    TO_CHAR(ROUND(B.DOWNUSAGE,3),''9999999.000'') KVARH
  FROM
    (SELECT s_datetime + .000011574 s_datetime,
      TO_CHAR(S_DATETIME ,''mm/dd/yyyy'') DOWNDATE,
      DECODE(TO_CHAR(s_datetime+.000011574 ,''hh24:'
      ||'mi''), ''00:'
      ||'00'',''24:'
      ||'00'', TO_CHAR(s_datetime+.000011574,''hh24:'
      ||'mi'')) downtime,
      s_usage downusage,
      s_cost downcost
    FROM summary_qtrhour
    WHERE s_mtrid = '
    ||P_MTR_ID||
   ' AND s_mtrch   = ''1''
    AND s_datetime BETWEEN TO_DATE('
    ||P_FROM_DATE||
    ',''DD-MON-YY'') AND (TO_DATE('
    ||P_THROUGH_DATE||
    ',''DD-MON-YY'') + 1)
    ) a,
    (SELECT s_datetime + .000011574 s_datetime,
      s_usage downusage
    FROM summary_qtrhour
    WHERE s_mtrid = '
    ||P_MTR_ID||
    ' AND s_mtrch   = ''2''
    AND s_datetime BETWEEN TO_DATE('
    ||P_FROM_DATE||
    ',''DD-MON-YY'') AND (TO_DATE('
    ||P_THROUGH_DATE||
    ','' DD-MON-YY'') + 1)
    ) B
  where a.S_DATETIME = B.S_DATETIME(+)';
SELECT DBMS_XMLQUERY.GETXML('L_QUERY') INTO L_XML   FROM DUAL;
INSERT INTO NK VALUES (L_XML);
DBMS_OUTPUT.PUT_LINE('L_QUERY IS :'||L_QUERY);
END;
OUTPUT parameters are in bold (the issue is they are coming without single quotes otherwise th equery is fine
L_QUERY IS :SELECT
    a.s_datetime DATETIME,
    a.downdate Ending_date,
    a.downtime Ending_time,
    TO_CHAR(ROUND(a.downusage,3),'9999999.000') kWh_Usage,
    TO_CHAR(ROUND(a.downcost,2),'$9,999,999.00') kWh_cost,
    TO_CHAR(ROUND(B.DOWNUSAGE,3),'9999999.000') KVARH
  FROM
    (SELECT s_datetime + .000011574 s_datetime,
      TO_CHAR(S_DATETIME ,'mm/dd/yyyy') DOWNDATE,
      DECODE(TO_CHAR(s_datetime+.000011574 ,'hh24:mi'), '00:00','24:00', TO_CHAR(s_datetime+.000011574,'hh24:mi')) downtime,
      s_usage downusage,
      s_cost downcost
    FROM summary_qtrhour
    WHERE s_mtrid = N3165 AND s_mtrch   = '1'
    AND s_datetime BETWEEN TO_DATE(01-JAN-13,'DD-MON-YY') AND (TO_DATE(31-JAN-13,'DD-MON-YY') + 1)
    ) a,
    (SELECT s_datetime + .000011574 s_datetime,
      s_usage downusage
    FROM summary_qtrhour
    WHERE s_mtrid = N3165 AND s_mtrch   = '2'
    AND s_datetime BETWEEN TO_DATE(01-JAN-13,'DD-MON-YY') AND (TO_DATE(31-JAN-13,' DD-MON-YY') + 1)
    ) B
  where a.S_DATETIME = B.S_DATETIME(+)

Answer 1

The correct way to handle this is to use bind variables.
And use DBMS_XMLGEN instead of DBMS_XMLQUERY :
create or replace procedure temp (
  p_mtr_id       in varchar2
, p_from_date    in date
, p_through_date in date
is
  l_xml   CLOB;
  l_query VARCHAR2(2000);
  l_ctx   dbms_xmlgen.ctxHandle;
begin
  l_query:=  'SELECT
    a.s_datetime DATETIME,
    a.downdate Ending_date,
    a.downtime Ending_time,
    TO_CHAR(ROUND(a.downusage,3),''9999999.000'') kWh_Usage,
    TO_CHAR(ROUND(a.downcost,2),''$9,999,999.00'') kWh_cost,
    TO_CHAR(ROUND(B.DOWNUSAGE,3),''9999999.000'') KVARH
  FROM
    (SELECT s_datetime + .000011574 s_datetime,
      TO_CHAR(S_DATETIME ,''mm/dd/yyyy'') DOWNDATE,
      DECODE(TO_CHAR(s_datetime+.000011574 ,''hh24:'
      ||'mi''), ''00:'
      ||'00'',''24:'
      ||'00'', TO_CHAR(s_datetime+.000011574,''hh24:'
      ||'mi'')) downtime,
      s_usage downusage,
      s_cost downcost
    FROM summary_qtrhour
    WHERE s_mtrid = :P_MTR_ID
    AND s_mtrch   = ''1''
    AND s_datetime BETWEEN TO_DATE(:P_FROM_DATE,''DD-MON-YY'')
                       AND (TO_DATE(:P_THROUGH_DATE,''DD-MON-YY'') + 1)
    ) a,
    (SELECT s_datetime + .000011574 s_datetime,
      s_usage downusage
    FROM summary_qtrhour
    WHERE s_mtrid = :P_MTR_ID
    AND s_mtrch   = ''2''
    AND s_datetime BETWEEN TO_DATE(:P_FROM_DATE,''DD-MON-YY'')
                       AND (TO_DATE(:P_THROUGH_DATE,'' DD-MON-YY'') + 1)
    ) B
  where a.S_DATETIME = B.S_DATETIME(+)';
  l_ctx := dbms_xmlgen.newContext(l_query);
  dbms_xmlgen.setBindValue(l_ctx, 'P_MTR_ID', p_mtr_id);
  dbms_xmlgen.setBindValue(l_ctx, 'P_FROM_DATE', to_char(p_from_date, 'DD-MON-YY'));
  dbms_xmlgen.setBindValue(l_ctx, 'P_THROUGH_DATE', to_char(p_through_date, 'DD-MON-YY'));
  l_xml := dbms_xmlgen.getXML(l_ctx);
  dbms_xmlgen.closeContext(l_ctx);
  insert into nk values (l_xml);
end;