Malformed SQL92 string at position: 227

Question

What is wrong with the following anonymous block? I am getting an error - "Malformed SQL92 string at position: 227".
DECLARE    
  TYPE   typ_tb_bw_lg_mstr IS TABLE OF tb_bw_lg_mstr%ROWTYPE INDEX BY BINARY_INTEGER;
  my_tab typ_tb_bw_lg_mstr;
  v_sql  VARCHAR2(128);   
BEGIN
  v_sql:=q'{'SELECT * FROM tb_bw_lg_mstr WHERE system_date='31-JUL-2011'}';
  OPEN v_sql
  LOOP
    FETCH v_sql BULK COLLECT INTO my_tab LIMIT 500;
    FOR i IN my_tab.FIRST .. my_tab.LAST
    LOOP
      IF my_tab.EXISTS(i) THEN
        Dbms_Output.Put_Line( my_tab(i).sales_code ) ;
      END IF;
    END LOOP;
    EXIT WHEN v_sql%NOTFOUND;
  END LOOP;
EXCEPTION
  WHEN OTHERS THEN
    Dbms_output.put_line(SQLERRM);
END;
/

Answer 1

Oops, I missed two more errors. You are using v_sql as a cursor which is completely wrong. It is a string holding SQL statement text - nothing more. And I also missed SQL statement has extra quote. Use:
SQL> create table tb_bw_lg_mstr
  2  as select ename, job as sales_code,date'2011-07-31' as system_date from emp
  3  /
Table created.
SQL> set serveroutput on
SQL> DECLARE
  2    TYPE   typ_tb_bw_lg_mstr IS TABLE OF tb_bw_lg_mstr%ROWTYPE INDEX BY BINARY_INTEGER;
  3    my_tab typ_tb_bw_lg_mstr;
  4    v_sql  VARCHAR2(128);
  5    v_cur sys_refcursor;
  6  BEGIN
  7    v_sql:=q'{SELECT * FROM tb_bw_lg_mstr WHERE system_date=date'2011-07-31'}';
  8    OPEN v_cur FOR v_sql;
  9    LOOP
10      FETCH v_cur BULK COLLECT INTO my_tab LIMIT 500;
11      FOR i IN my_tab.FIRST .. my_tab.LAST
12      LOOP
13        IF my_tab.EXISTS(i) THEN
14          Dbms_Output.Put_Line( my_tab(i).sales_code ) ;
15        END IF;
16      END LOOP;
17      EXIT WHEN v_cur%NOTFOUND;
18    END LOOP;
19  EXCEPTION
20    WHEN OTHERS THEN
21      Dbms_output.put_line(SQLERRM);
22  END;
23  /
CLERK
SALESMAN
SALESMAN
MANAGER
SALESMAN
MANAGER
MANAGER
ANALYST
PRESIDENT
SALESMAN
CLERK
CLERK
ANALYST
CLERK
PL/SQL procedure successfully completed.
SQL> SY.