ME21N Custom Field in Document Header.

Question

Hi Guys,
Could you guys please help me with the following problem.
I have a custom field in a custom tab in the header of ME21N. But When I change that field manually the transaction does not update the pricing. But if I change any standard field, the transacction update the pricing.
Do you have any Idea why and how to solve this ?
Thank you very much.

Answer 1

Hi , Thanks for your answer Raymond.   But now I have the answer. Let's pretend that I want to insert a new field in EKKO . the field is ZZPUERTO and i want the transaction recalculate the price if i change that field.
1-. the first thing that you need is to create a copy of this function group MEPOBADIEX. There you have to create your new screen. Comment all the code in all function modules.  Use function module ZMEPOBADIEX_PUSH. Insert there your code. for example:
  zmepo_badi_struct = im_dynp_data.
2-. Use ME_GUI_PO_CUST and populate method suscribe with the data from the screen that you just create in the first step. in the following way :
Method: Suscribe
CHECK im_application = 'PO'.
   CHECK im_element     = 'HEADER'.
* each line in re_subscribers generates a subscreen.
*    We add one subscreen in this example
   CLEAR re_subscribers[].
* the name is a unique identifier for the subscreen and
*  defined in this class definition
   ls_subscriber-name = subscreen1.
* the dynpro number to use
   ls_subscriber-dynpro = '9000'.
* the program where the dynpro can be found
   ls_subscriber-program = 'SAPLZMEPOBADIEX'.
* each subscreen needs his own DDIC-Structure
   ls_subscriber-struct_name = 'ZMEPO_BADI_STRUCT'.
* a label can be defined
   ls_subscriber-label = text-001.
* the position within the tabstrib can be defined
   ls_subscriber-position = 13.
* the height of the screen can be defined here.
*  Currently we suport two screen sizes:
* value <= 7 a sevel line subscreen
* value > 7  a 16 line subscreen
   ls_subscriber-height = 7.
   APPEND ls_subscriber TO re_subscribers.
3-. populate the following code in method MAP_DYNPRO_FIELDS
FIELD-SYMBOLS: <mapping> LIKE LINE OF ch_mapping.
   CONSTANTS: mmmfd_cust_01 TYPE mmpur_metafield VALUE 90000000.
   LOOP AT ch_mapping ASSIGNING <mapping>.
     CASE <mapping>-fieldname.
       WHEN 'ZZPUERTO'.
         <mapping>-metafield = mmmfd_cust_01.
     ENDCASE.
4-. The followin Code for the method TRANSPORT FROM MODEL
transport_from_model
DATA: l_header       TYPE REF TO if_purchase_order_mm,
         ls_mepoheader  TYPE mepoheader,
         ls_customer    TYPE zmepo_badi_struct.
* system asks to transport data from the business
*  logic into the view.
   CASE im_name.
     WHEN subscreen1.
* is it an item? im_model can be header or item.
       mmpur_dynamic_cast l_header im_model.
       CHECK NOT l_header IS INITIAL.
* transport standard fields
       ls_mepoheader = l_header->get_data( ).
*      ls_customer-zzpuerto = ls_mepoheader-zzpuerto.
* store info for later use
*      MOVE-CORRESPONDING ls_mepoheader TO dynp_data_pbo.
       MOVE ls_mepoheader-zzpuerto TO dynp_data_pbo-zzpuerto.
     WHEN OTHERS.
   ENDCASE.
5-. Method TRANSPORT_TO_DYNP
CASE im_name.
     WHEN subscreen1.
       CALL FUNCTION 'ZMEPOBADIEX_PUSH'
         EXPORTING
           im_dynp_data = dynp_data_pbo.
     WHEN OTHERS.
   ENDCASE.
6-. Method : TRANSPORT_FROM_DYNP
CASE im_name.
     WHEN subscreen1.
       CALL FUNCTION 'ZMEPOBADIEX_POP'
         IMPORTING
           ex_dynp_data = dynp_data_pai.
       IF dynp_data_pai NE dynp_data_pbo.
         re_changed = mmpur_yes.
       ENDIF.
     WHEN OTHERS.
   ENDCASE.
7-.  METHOD TRANSPORT_TO_MODEL
DATA: l_header       TYPE REF TO if_purchase_order_mm,
         ls_mepoheader  TYPE mepoheader.
* data have to be transported to business logic
   CASE im_name.
     WHEN subscreen1.
* is it an item? im_model can be header or item.
       mmpur_dynamic_cast l_header im_model.
       CHECK NOT l_header IS INITIAL.
       ls_mepoheader = l_header->get_data( ).
* customer fields changed?
       IF dynp_data_pbo-zzpuerto NE dynp_data_pai-zzpuerto.
* update customerfields
         ls_mepoheader-zzpuerto = dynp_data_pai-zzpuerto.
         CALL METHOD l_header->set_data( ls_mepoheader ).
       ENDIF.
     WHEN OTHERS.
   ENDCASE.
8-. Now we go to BADI ME_PROCESS_PO_CUST and we insert the next code in method FIELDSELECTION_HEADER. This is to show the screen in transactions. 
DATA: l_persistent TYPE mmpur_bool.
   FIELD-SYMBOLS: <fs> LIKE LINE OF ch_fieldselection.
   READ TABLE ch_fieldselection ASSIGNING <fs>
     WITH TABLE KEY metafield = mmmfd_cust_01.
   IF sy-subrc IS INITIAL.
     CASE sy-tcode.
       WHEN 'ME21N' OR 'ME22N' OR 'ME29N'.
         <fs>-fieldstatus = '.'. " Modify
       WHEN OTHERS.
         <fs>-fieldstatus = '*'. " Display
     ENDCASE.
   ENDIF.
9-. Finally we go to Method PROCESS_HEADER and there we put the logic that we want for our new screen. For example I put the following code because if the user don't populate the new field I want to use some querys to populate it .
DATA: ls_mepoheader TYPE mepoheader,
         lv_adrnr      TYPE adrnr,
         lv_adrc       TYPE ad_addrnum,
         lv_transpzone TYPE lzone.
   ls_mepoheader = im_header->get_data( ).
   IF im_header->is_persistent( ) EQ mmpur_no.
     IF ls_mepoheader-zzpuerto IS INITIAL.
       mmpur_metafield mmmfd_cust_01.
       SELECT SINGLE adrnr
       INTO lv_adrnr
       FROM lfa1
       WHERE lifnr = ls_mepoheader-lifnr.
       IF sy-subrc EQ 0.
         lv_adrc = lv_adrnr.
         SELECT SINGLE transpzone
         INTO lv_transpzone
         FROM adrc
         WHERE addrnumber = lv_adrc.
         IF sy-subrc EQ 0.
           ls_mepoheader-zzpuerto = lv_transpzone.
           CALL METHOD im_header->set_data( ls_mepoheader ).
           CLEAR ls_mepoheader.
         ENDIF.
       ENDIF.
     ENDIF.
   ENDIF.
10. Any questions please let me know. I know it is difficult but it works.
Thanks .