Microsoft Excel Capability to Open files .

Question

Hello
I have 80 number excel files and each volume is near to 30 mb . My system configuration is about "CPU=Cor i7","RAM=8GB","Hard=1.5 T" . I want to open all files simultaneous and run a macro . I think Excel cant open them is it
true ? if so what should I do ?
Thanks

Answer 1

Does it really matter?
You can read the filenames into an array, then sort the array, and finally loop through the names in the sorted array:
Sub ProcessFolder()
' Path of the workbooks; must end in \
Const strFolder = "C:\Excel\"
Dim strFile As String
Dim arrFiles() As String
Dim i As Long
Dim n As Long
Dim wbk As Workbook
' Don't update the screen for efficiency
Application.ScreenUpdating = False
' Get first filename
strFile = Dir(strFolder & "*.xls*")
' Loop through the files
Do While strFile <> ""
' Increase counter
n = n + 1
' Expand array
ReDim Preserve arrFiles(1 To n)
' Set last array item to filename
arrFiles(n) = strFile
' Get the next filename
strFile = Dir
Loop
' Sort the filenames
Call BubbleSort(arrFiles)
' Loop through the sorted filenames
For i = 1 To n
' Open the workbook
Set wbk = Workbooks.Open(strFolder & arrFiles(i))
' Do something with the workbook
Call Macro1
' Close the workbook - use True if you want to save it
wbk.Close SaveChanges:=False
Next i
' Update the screen again
Application.ScreenUpdating = True
End Sub
Sub BubbleSort(arr)
Dim i As Long
Dim j As Long
Dim tmp
' Outer loop
For i = LBound(arr) To UBound(arr) - 1
' Inner loop
For j = i + 1 To UBound(arr)
' Items in wrong order?
If arr(i) > arr(j) Then
' If so, swap them
tmp = arr(i)
arr(i) = arr(j)
arr(j) = tmp
End If
Next j
Next i
End Sub
Regards, Hans Vogelaar (http://www.eileenslounge.com)