Most efficient way to add a lot of text?

Question

Hey all,
I have a project for a client who wants me to make flash cards for 350 scripture passages. Basically the cards need the Passage name and number on the top, with the actual passage underneath. Originally I was looking up each passage online, copying it, and pasting it into a new text box one at a time. However, this is taking forever.
I was able to locate an XML Bible and was wondering if its at all possible to use that to speed up my process? Is it possible to set up the text boxes with the correct tags so that when I import the XML it fills them in with the proper specific passage? If not, is there an easier way to do this than one at a time?
I'm quite new to using XML with Indesign, so detailed advice would be appreciated! Thanks for any help!

Answer 1

Can you work with ready-to-place XML?
I've tinkered a bit with a file called KJV.XML and a custom style sheet, and came up with this scheme. All you have to do is fill the variable "list" with the names of the books and chapter and verse number, then save the style sheet.
Choose "Import XML", then select the file "KJV.XML" (since that's what the style sheet is based upon -- if you have another XML data file, the names of the individual elements may not match). In the dialog, select "Choose XSLT"; browse for the XSLT file and select that. ID will import the verses as "quote", with the name of the book and verse in a tag "title" and the text itself in a tag "verse". From then on you'd have to consult someone who knows how to process it any further
This is the style sheet -- copy, paste into a plain text editor, and save as "verses.xslt". The variable you should fill in is on line #6; be sure to use a comma to separate Book name and verse, and put a colon between chapter and verse number. Hope it works for you!
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:variable name="list" select="'Exodus 23:5|Exodus 28:3|Job 28:16'" />
<!-- Match everything in the root -->
<xsl:template match="/">
     <xsl:apply-templates />
</xsl:template>
<xsl:template match="bible">
     <xsl:element name="quotes">
          <xsl:call-template name="nextEntry">
               <xsl:with-param name="list" select="$list" />
          </xsl:call-template>
     </xsl:element>
</xsl:template>
<xsl:template name="nextEntry">
     <xsl:param name="list" select="''" />
     <xsl:param name="this" select="substring-before(concat($list,'|'), '|')"/>
     <xsl:param name="next" select="substring-after($list, '|')"/>
     <xsl:element name="title">
          <xsl:value-of select="$this" />
     </xsl:element>
     <xsl:variable name="book" select="substring-before($this, ' ')" />
     <xsl:variable name="chap" select="substring-before(substring-after($this, ' '), ':')" />
     <xsl:variable name="vers" select="substring-after($this, ':')" />
     <xsl:element name="verse">
          <xsl:apply-templates select="testament/book[@name=$book]/chapter[@number=$chap]/verse[@number=$vers]" />
     </xsl:element>
<xsl:text>
</xsl:text>
     <xsl:if test="string-length($next) &gt; 0">
          <xsl:call-template name="nextEntry">
               <xsl:with-param name="list" select="$next" />
          </xsl:call-template>
     </xsl:if>
</xsl:template>
</xsl:stylesheet>