Need a dificult script can't to it myself.

Question

Hello,
I try to keep it short.
We have a new idea for a customer of ours. Don't know if it's possible and I hope there is someone that's want to try it and give it a go. I can work it out on paper altough my applescript / programmer skills want do the job.
We will work with an excel file. We want to keep it simple for our customer.
They have (more or less) 60 diffferent leaflets and from 100 to 200 agencies.
We would like to print all leaflets for 1 agency from 1 line in excel.
Normally 1 person will get the orders from all agencies (central) and will write it down in excel.
Once a week we will get the database for printing.
But in this case I can't print unless there is a automated procces that fix the database like I need it.
I first run a applescript for converting the database to tab delimit and unicode check.
So it will be an TXT file TAB delimited unicode MAC starting this script.
So the database must have in the beginning the basic customer information. Such as company name, street, delivery adresse,...
From A to N is the agency information. This information must be copied on every line.
From colum O the database will have the PROD1-PROD2-PROD3
We will have 70 PROD at start
So it's from colum O to CF the PRODUCTS.
UNder PROD they will write the quantaty the need of this leaflet.
Important : Now i write zero for visibilaty but zero need to be a blank field.(for printing software)
So this is the tricky part : The script needs to duplicate the records in a new database AND
it needs to begin with PROD 1 to PROD 70 AND may only copie the quantaty of PROD1 then leave the other PRODUCTS quantaties blank and go on. Please See example.
Customer info - PROD1 - PROD 2 - PROD 3
Customer 1 - 5-6-2
Customer 2 - 0-3-5
Customer 200
MUST BECOME:
Customer info - PROD1 - PROD 2 - PROD 3
Customer 1 - 5-0-0
Customer 1 - 5-0-0
Customer 1 - 5-0-0
Customer 1 - 5-0-0
Customer 1 - 5-0-0
Customer 1 - 0-6-0
Customer 1 - 0-6-0
Customer 1 - 0-6-0
Customer 1 - 0-6-0
Customer 1 - 0-6-0
Customer 1 - 0-6-0
Customer 1 - 0-0-2
Customer 1 - 0-6-2
Customer 2 - 0-3-0
Customer 2 - 0-3-0
Customer 2 - 0-3-0
Customer 2 - 0-0-5
Customer 2 - 0-0-5
Customer 2 - 0-0-5
Customer 2 - 0-0-5
Customer 2 - 0-0-5
want to give it a try?
Many thanks in advance.

Answer 1

Hello Colin,
Ah, I didn't take the field names' line into consideration...
Here's the revised code to handle it (hopefully). I assumed the field names' line is the 1st line of the input file and the rest are data lines.
Also in my previous code, customerRange and quantityRange are being set to {1, 1} and {2, 6} respectively to process the reduced sample data. However, according to your original description of input data, they should be changed as follows:
property customerRange : {1, 14} -- field range for customer info (e.g. {1, 14} for A..N)
property quantityRange : {15, 84} -- field range for quantities {e.g. {15, 84} for O..CF)
Hope this may help,
Hiroto
-- SCRIPT
  v0.2
    Modified such that
     - it treats the 1st line (field names line) in the input text file properly.
     - it now preserves the empty lines in the input text file.
  Usage:
    Set the following four properties to fit your need and run the script.
    property fp : "HFS:path:to:input:file"
    property fp1 : "HFS:path:to:output:file"
    property customerRange : {1, 14} -- field range for customer info (e.g. {1, 14} for A..N)
    property quantityRange : {15, 84} -- field range for quantities {e.g. {15, 84} for O..CF)
    It will
     - read the input text file (assumed in UTF-8, currently),
     - convert text to array,
     - expand each record according to given fields' ranges,
     - convert processed array back to text,
     - write (or overwrite) output text file (in UTF-8, currently).
E.g. (customerRange = {1, 1}, quantityRange = {2, 6})
INPUT TEXT (tab delimited)
Field Names (Column Title) Line
Customer1  0  5  1  0  0
Customer2  2  0  0  0  1
Customer3  0  0  0  0  0
Customer4  1  1  0  0  3
Customer5  0  0  4  0  0
OUTPUT TEXT (tab delimited)
Field Names (Column Title) Line
Customer1    5      
Customer1    5      
Customer1    5      
Customer1    5      
Customer1    5      
Customer1      1    
Customer2  2        
Customer2  2        
Customer2          1
Customer4  1        
Customer4    1      
Customer4          3
Customer4          3
Customer4          3
Customer5      4    
Customer5      4    
Customer5      4    
Customer5      4    
main()
on main()
script o
-- input file path
property fp : "HFS:path:to:input:file" -- #
-- output file path
property fp1 : "HFS:path:to:output:file" -- #
-- field ranges
property customerRange : {1, 14} -- # field range for customer info (e.g. {1, 14} for A..N)
property quantityRange : {15, 84} -- # field range for quantities {e.g. {15, 84} for O..CF)
-- working lists
property aa : {} -- original array
property dd : {} -- original quantity list
property ee : {} -- modified array (expanded quantity lists)
property ee0 : {}
property ee1 : {}
local c1, c2, d1, d2, c, t, t1
-- (0) preparation
set {c1, c2} to customerRange
set {d1, d2} to quantityRange
-- make empty data list (ee0)
repeat with i from d1 to d2
set end of my ee0 to ""
end repeat
-- (1) read input file (text of paragraphs of tab delimited values)
set t to read file fp as «class utf8» -- UTF-8
--set t to read file fp as Unicode text -- UTF-16
--set t to read file fp -- plain text (in System's primary encoding)
-- (2) convert text to 2d array
set my aa to text2array(t, tab)
-- (3) process each record
set end of my ee to my aa's item 1 -- get the 1st record that is field names record
set aa to my aa's rest -- exclude the 1st record from subsequent processing
repeat with a in my aa -- for each record entry
set a to a's contents
if a is {""} then -- ignore empty record (i.e. empty line in input text if any)
set end of my ee to a -- just leave the empty record alone
else
set c to a's items c1 thru c2 -- customer info parts
set my dd to a's items d1 thru d2 -- quantities
repeat with i from 1 to count my dd -- for each quantity entry
set d to my dd's item i as number
if d > 0 then
copy my ee0 to my ee1 -- make copy of empty data list
set my ee1's item i to d
repeat d times
set end of my ee to (c & ee1)
end repeat
end if
end repeat
end if
end repeat
-- (4) convert 2d array to text
set t1 to array2text(my ee, tab, return)
-- (5) write output file (text of paragraphs of tab delimited values)
writeData(fp1, t1, {_append:false, _class:«class utf8»}) -- UTF-8
--writeData(fp1, t1, {_append:false, _class:Unicode text}) -- UTF-16BE
--writeData(fp1, t1, {_append:false, _class:string}) -- plain text (in System's primary encoding)
-- (*) for test
--return {t, t1}
return t1
end script
tell o to run
end main
on text2array(t, cdelim) -- v1.1, with column delimiter as parameter
  text t: text of which paragrahps consist of values delimited by cdelim. e.g. (Let cdelim = tab)
    "11  12
     21  22
     31  32"
  string cdelim : column delimiter
  return list: two dimentional array. e.g. {{11, 12}, {21, 22}, {31, 32}}
script o
property aa : t's paragraphs
property xx : {}
property astid : a reference to AppleScript's text item delimiters
local astid0
try
set astid0 to astid's contents
set astid's contents to {cdelim}
repeat with a in my aa
set end of my xx to (a's text items)
end repeat
set astid's contents to astid0
on error errs number errn
set astid's contents to astid0
error "text2array(): " & errs number errn
end try
return my xx's contents
end script
tell o to run
end text2array
on array2text(dd, cdelim, rdelim) -- v1.1, with column delimiter and row delimiter as parameter
  list dd: two dimentional array. e.g. {{11, 12}, {21, 22}, {31, 32}}
  string cdelim : column delimiter
  string rdelim : row delimiter (e.g. CR, LF, CRLF, etc)
  return string : paragraphs of items delimited by cdelim.
  e.g.
  (Let cdelim = tab, rdelim = CR)
    "11  12
     21  22
     31  32"
  i.e.
    11 [tab] 12 [CR]
    21 [tab] 22 [CR]
    31 [tab] 32 [CR]
script o
property aa : dd's contents
property xx : {}
property astid : a reference to AppleScript's text item delimiters
local t, astid0
try
set astid0 to astid's contents
set astid's contents to {cdelim}
repeat with a in my aa
set end of my xx to ("" & a)
end repeat
set astid's contents to {rdelim}
set t to "" & my xx
set astid's contents to astid0
on error errs number errn
set astid's contents to astid0
error "array2text(): " & errs number errn
end try
return t
end script
tell o to run
end array2text
on writeData(fp, x, {append:append, class:class})
  text fp: output file path
  data x: anything to be written to output file
  boolean _append: true to append data, false to replace data
  type class _class: type class as which the data is written (_class = "" indicates x's class as is)
local a
try
open for access (file fp) with write permission
set a to fp as alias
if not _append then set eof a to 0
if _class = "" then
write x to a starting at eof
else
write x to a as _class starting at eof
end if
close access a
on error errs number errn
try
close access file fp
on error --
end try
error "writeData(): " & errs number errn
end try
end writeData
-- END OF SCRIPT
Message was edited by: Hiroto