Need an applecript to copy filtered cells from a Numbers table to another Numbers file

Question

Hi,
I would like to be able to build a new table in an existing file based on a filtered selection.
My file covers the whole year and have many more columns but let's make a short example:
Starting table: Table 1 Sheet 1 file 1
Date
Quantity
Price
Action
Port
10/3/2014
1050
100
IN
Venice
11/3/2014
35
104
CES
Venice
16/3/2014
2045
90
IN
Barcelona
21/3/2014
545
9
CUS
Barcelona
25/3/2014
50
123
CES
Venice
28/3/2014
50
21
CUS
Rome
I would like to have on a separte file(table 1 Sheet 3 File 2) a table like this (filtered by Action: IN + CUS and Port: Venice + Barcelona)
Date
Quantity
Price
Action
Port
10/3/2014
1050
100
IN
Venice
16/3/2014
2045
90
IN
Barcelona
21/3/2014
545
9
CUS
Barcelona
Any help?

Answer 1

Although I would have preferred to have a script beacuse the data origin file - let's call it STORAGE - is already quite heavy and I would like to use the filtered data on a separate file - let's call it MANAGEMENT - for further analysis and integration with other data coming from other STORAGE files and from other company areas.
Hi Paolo,
Below is a script that should do what you want. (Tested in Numbers 3.2). Copy into AppleScript Editor, set up the Numbers documents as indicated (or change the script to match your document setup), and click the green triangle 'Run' button.
It assumes you have both the source document ("Storage.numbers") and target document ("Management.numbers") open and that you have already set up the target table with 1 header row.  You can change your filter columns and values and filter logic where indicated.
For simplicity (and also to avoid apparent Numbers bugs in removing rows via AppleScript) I assumed the user will manually check to make sure that the target table does not contain too many rows. It needs at least 2 rows to work properly as the results are inserted starting in cell A2 (which can be changed as needed).
SG
--filters a table and passes the results to an existing table in the same or different document
--set filter column and values to filter for here:
property filter1 : {colNum:4, filterFor:{"CUS", "IN"}}
property filter2 : {colNum:5, filterFor:{"Barcelona", "Venice"}}
--set properties of source's and target's document, sheet, table here:
property source : {d:"Storage.numbers", s:"Sheet 1", t:"Table 1"}
property target : {d:"Management.numbers", s:"Sheet 1", t:"Table 1"}
tell application "Numbers"
          activate
          set filteredList to {}
           --load source table's values into a list of lists
          try
                    set valuesList to value of document (source's d as string)'s ¬
                              sheet (source's s as string)'s table (source's t as string)'s ¬
                             rows's cells
          on error
                    display dialog "Having trouble. Does your source document, sheet, and table exist?"
          end try
           --create filtered list of lists
          tell valuesList to repeat with anItem in items
                    --if needed, logic can be changed to 'not in', etc.
                    set satisfiesFilter1 to anItem's item (filter1's colNum) is in filter1's filterFor
                    set satisfiesFilter2 to anItem's item (filter2's colNum) is in filter2's filterFor
                    --if needed, logic can be changed here to 'or', etc.
                    if satisfiesFilter1 and satisfiesFilter2 then ¬
                              copy anItem's items to end of filteredList
          end repeat
          if (count filteredList) = 0 then display dialog "No rows meet your criteria" buttons "Cancel"
           --load values into target table (in this or another document, as specified in properties above)
          try
                    tell document (target's d as string)'s sheet (target's s as string)'s ¬
                              table (target's t as string)
                             --load the values into the cells starting at cell A2:
                              set pasteStr to ""
                              set {oTid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, tab}
                              repeat with anItem in filteredList's items
                                        set pasteStr to (pasteStr & anItem as string) & return
                              end repeat
                              set the clipboard to pasteStr
                              set the selection range to cell "A2" --assumes 1 header row
                              tell application "System Events" to keystroke "v" using {option down, shift down, command down}
                    end tell
          on error
                    display dialog "Having trouble. Does your target (destination) document, sheet, and table exist?"
          end try
end tell
--end of script