Need help in Performance tuning for function...

Question

Hi all,
I am using the below algorithm for calculating the Luhn Alogorithm to calculate the 15th luhn digit for an IMEI (Phone Sim Card).
But the below function is taking about 6 min for 5 million records. I had 170 million records in a table want to calculate the luhn digit for all of them which might take up to 4-5 hours.Please help me performance tuning (better way or better logic for luhn calculation) to the below function.
A wikipedia link is provided for the luhn algorithm below
Create or Replace FUNCTION AddLuhnToIMEI (LuhnPrimitive VARCHAR2)
      RETURN VARCHAR2
   AS
      Index_no     NUMBER (2) := LENGTH (LuhnPrimitive);
      Multiplier   NUMBER (1) := 2;
      Total_Sum    NUMBER (4) := 0;
      Plus         NUMBER (2);
      ReturnLuhn   VARCHAR2 (25);
   BEGIN
      WHILE Index_no >= 1
      LOOP
         Plus       := Multiplier * (TO_NUMBER (SUBSTR (LuhnPrimitive, Index_no, 1)));
         Multiplier := (3 - Multiplier);
         Total_Sum  := Total_Sum + TO_NUMBER (TRUNC ( (Plus / 10))) + MOD (Plus, 10);
         Index_no   := Index_no - 1;
      END LOOP;
      ReturnLuhn := LuhnPrimitive || CASE
                                         WHEN MOD (Total_Sum, 10) = 0 THEN '0'
                                         ELSE TO_CHAR (10 - MOD (Total_Sum, 10))
                                     END;
      RETURN ReturnLuhn;
   EXCEPTION
      WHEN OTHERS
      THEN
         RETURN (LuhnPrimitive);
   END AddLuhnToIMEI;
http://en.wikipedia.org/wiki/Luhn_algorithmAny sort of help is much appreciated....
Thanks
Rede

Answer 1

There is a not needed to_number function in it. TRUNC will already return a number.
Also the MOD function can be avoided at some steps. Since multiplying by 2 will never be higher then 18 you can speed up the calculation with this.
create or replace
FUNCTION AddLuhnToIMEI_fast (LuhnPrimitive VARCHAR2)
      RETURN VARCHAR2
   AS
      Index_no     pls_Integer;
      Multiplier   pls_Integer := 2;
      Total_Sum    pls_Integer := 0;
      Plus         pls_Integer;
      rest         pls_integer;
      ReturnLuhn   VARCHAR2 (25);
   BEGIN
      for Index_no in reverse 1..LENGTH (LuhnPrimitive) LOOP
         Plus       := Multiplier * TO_NUMBER (SUBSTR (LuhnPrimitive, Index_no, 1));
         Multiplier := 3 - Multiplier;
         if Plus < 10 then
            Total_Sum  := Total_Sum + Plus ;
         else
            Total_Sum  := Total_Sum + Plus - 9;
         end if;  
      END LOOP;
      rest := MOD (Total_Sum, 10);
      ReturnLuhn := LuhnPrimitive || CASE WHEN rest = 0 THEN '0' ELSE TO_CHAR (10 - rest) END;
      RETURN ReturnLuhn;
   END AddLuhnToIMEI_fast;
/My tests gave an improvement for about 40%.
The next step to try could be to use native complilation on this function. This can give an additional big boost.
Edited by: Sven W. on Mar 9, 2011 8:11 PM