Need help with querying pl/sql collections

Question

hi all,
i have a requirement wherein i look thru a number of records and then updates. then i need to check if these records were successfully updated. i have the following code but it doesn't work on the part where i query the collection.
declare
  type ap_invoices_all_tbl is table of ap_invoices_all%rowtype;
  ap_invoices_all_rec ap_invoices_all_tbl;
  cursor cai is
    select *
      from ap_invoices_all ai
     where source = 'XXX';
begin
  open cai;
  fetch cai bulk collect into ap_invoices_all_rec;
  for i in 1..ap_invoices_all_rec.count loop
    begin
    dbms_output.put_line('Invoice Status: ' || ap_invoices_pkg.get_approval_status( ap_invoices_all_rec(i).invoice_id, ap_invoices_all_rec(i).invoice_amount, ap_invoices_all_rec(i).payment_status_flag, ap_invoices_all_rec(i).invoice_type_lookup_code));
    exception
      when no_data_found then
        null;
    end;
  end loop;
  for j in ( select * from ap_invoices_all ai
              where invoice_id in ( select invoice_id
                                      from ap_invoices_all_rec ))
  loop
    dbms_output.put_line('Invoice Number: ' || j.invoice_num);
  end loop;
end;i do understand that i cannot use select statement directly on a collection but i just wanted to show what i'm trying to achieve.
any suggestions on what i should do?
thanks
allen

Answer 1

You can not use locally defined collection(pl/sql) in SELECT statement directly, instead use Objects defined in schema.
For example:
SQL> CREATE OR REPLACE TYPE emp_rec IS OBJECT (
  2                      v_sal    NUMBER(7,2),
  3                      v_name   VARCHAR2(35),
  4                      v_empno  NUMBER(4),
  5                      v_deptno NUMBER(2)
  6                      )
  7  ;
  8  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_tab IS TABLE OF emp_rec;
  2  /
Type created.
SQL> CREATE OR REPLACE TYPE dept_rec IS OBJECT (
  2                      v_deptno NUMBER,
  3                      v_dname VARCHAR2(50)
  4                      )
  5  ;
  6  /
Type created.
SQL> CREATE OR REPLACE TYPE dept_tab IS TABLE OF dept_rec;
  2  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_dept_rec IS
  2                     OBJECT (
  3                      v_sal     NUMBER,
  4                      v_name     VARCHAR2(35),
  5                      v_deptname VARCHAR2(30)
  6                      );
  7  /
Type created.
SQL> CREATE OR REPLACE TYPE emp_dept_tab_type IS TABLE OF emp_dept_rec;
  2  /
Type created.
SQL> set serverout on
SQL> DECLARE
  2    l_emp_dept_tab emp_dept_tab_type; --emp_dept_tab_type declared in database
  3    l_emp_tab      emp_tab; --emp_tab declared in database
  4    l_dept_tab     dept_tab; --dept_tab declared in database
  5 
  6    CURSOR e1 IS
  7      SELECT emp_rec(sal, ename, empno, deptno) FROM emp; --Note the type casting here
  8 
  9    CURSOR d1 IS
10      SELECT dept_rec(deptno, dname) FROM dept; --Note the type casting here
11  BEGIN
12    OPEN e1;
13 
14    FETCH e1 BULK COLLECT
15      INTO l_emp_tab;
16 
17    OPEN d1;
18 
19    FETCH d1 BULK COLLECT
20      INTO l_dept_tab;
21 
22    SELECT CAST(MULTISET (SELECT em.v_sal, em.v_name, dep.v_dname
23                   FROM TABLE(l_emp_tab) em, TABLE(l_dept_tab) dep
24                  WHERE em.v_deptno = dep.v_deptno) AS emp_dept_tab_type)
25      INTO l_emp_dept_tab
26      FROM DUAL;
27    FOR i IN 1 .. l_emp_dept_tab.COUNT LOOP
28      dbms_output.put_line(l_emp_dept_tab(i)
29                           .v_sal || '--' || l_emp_dept_tab(i)
30                           .v_name || '--' || l_emp_dept_tab(i).v_deptname);
31    END LOOP;
32 
33  END;
34  /
1300--MILLER--ACCOUNTING
5000--KING--ACCOUNTING
2450--CLARK--ACCOUNTING
3000--FORD--RESEARCH
1100--ADAMS--RESEARCH
3000--SCOTT--RESEARCH
2975--JONES--RESEARCH
800--SMITH--RESEARCH
950--JAMES--SALES
1500--TURNER--SALES
2850--BLAKE--SALES
1250--MARTIN--SALES
1250--WARD--SALES
1600--ALLEN--SALES
PL/SQL procedure successfully completed.
SQL>