Parsing a html file with pl/sql

Question

hi,
does anybody know how can I reach an html file source code and parse it for obtaining a useful data with pl/sql? Can utl_http solve the problem? If it can how?
thanks
bahar karaoglu

Answer 1

CREATE OR REPLACE FUNCTION search_pattern_exists(
   url IN VARCHAR2,
   search_pattern IN VARCHAR2 )
   RETURN VARCHAR2
IS
   result         VARCHAR2(8) := 'UNKNOWN';
   http_request   UTL_HTTP.req;
   http_response  UTL_HTTP.resp;
   little_buffer  VARCHAR2(32767);
   big_buffer     CLOB;
BEGIN
   DBMS_LOB.createTemporary( big_buffer, TRUE );
   http_request := UTL_HTTP.begin_request( url );
   http_response := UTL_HTTP.get_response( http_request );
   <<big_buffer_construction>>
   BEGIN
      LOOP
         little_buffer := NULL;
         UTL_HTTP.read_line( http_response, little_buffer, TRUE);
         IF little_buffer IS NOT NULL THEN
            DBMS_LOB.writeAppend( big_buffer, LENGTH(little_buffer), little_buffer );
         END IF;
      END LOOP;
      UTL_HTTP.end_response( http_response );
   EXCEPTION
       WHEN UTL_HTTP.end_of_body THEN UTL_HTTP.end_response( http_response );
   END big_buffer_construction;
   IF DBMS_LOB.instr( big_buffer, search_pattern ) != 0 THEN
      result := 'TRUE';
   ELSE
      result := 'FALSE';
   END IF;
   DBMS_LOB.freeTemporary( big_buffer );
   RETURN result;
END search_pattern_exists;
SELECT search_pattern_exists( 'http://otn.oracle.com', 'Oracle9i Application Server' )
FROM DUAL;Michael