Passing the Total/Subtotal Text in ALV

Question

Hi All,
I would like to know is there any chance with ALV to pass Total/Subtotal Text.
PS:I'm not looking for the text ls_layout-totals_text = 'Grand Total'.
ls_layout-subtotals_text = 'SubTotal'.
What i'm looking for is In My below Output:
112365               TDS Windsor Sequencing                           
112365               TDS Windsor Sequencing                           
112365               TDS Windsor Sequencing                           
* Total  <Group text>  "Here My   total amount is showing                                                         
112313               Operations and Engineering                       
* Total   <Group text>      "Here My   total amount is showing                                                         
112363               DCX Windsor                                      
* Total      <Group text>            "Here My   total amount is showing                                                                               
** Subtotal <Group text>   "Here My  "SUB total" amount is showing of above three totals
I've <Group text> in My Final ALV one of field, but need to show at the place of <Group text> in above output.
PS:And For Totals/Subtotals i'm using standard function of ALV by passing IT_SORT(which is in Reuse_Alv..FM)
Any Hints?
Thank You,
Cheers,
Amit.

Answer 1

Hi Amit,
  Please check this example..I used the event BEFORE_LINE_OUTPUT to populate the subtotal texts
dynamically..Used the Field-symbols technique to populate the subtotals text...Hope this is what you
are looking for.
TYPE-POOLS: slis,kkblo.
DATA: BEGIN OF wa,
        vbeln TYPE vbeln,
        posnr TYPE posnr,
        matnr TYPE matnr,
        netpr TYPE netpr,
        waerk TYPE waerk,
        text  TYPE char20,
      END OF wa.
DATA: BEGIN OF wa_vbak,
        vbeln TYPE vbeln,
      END OF wa_vbak.
DATA: i_event   TYPE slis_t_event,
      t_sort    TYPE slis_t_sortinfo_alv,
      s_sort    TYPE LINE OF slis_t_sortinfo_alv,
      l_s_event TYPE LINE OF slis_t_event.
DATA: t_fieldcatalog TYPE slis_t_fieldcat_alv.
DATA: s_layout       TYPE slis_layout_alv.
DATA: v_repid        TYPE syrepid.
DATA: s_fieldcatalog TYPE slis_fieldcat_alv.
DATA: itab1          LIKE TABLE OF wa.
DATA: itab           LIKE TABLE OF wa_vbak.
START-OF-SELECTION.
* Field catalog populate.
  s_fieldcatalog-col_pos = '1'.
  s_fieldcatalog-fieldname = 'VBELN'.
  s_fieldcatalog-rollname = 'VBELN'.
  s_fieldcatalog-outputlen = '12'.
  APPEND s_fieldcatalog TO t_fieldcatalog.
  CLEAR: s_fieldcatalog.
  s_fieldcatalog-col_pos = '2'.
  s_fieldcatalog-fieldname = 'POSNR'.
  s_fieldcatalog-rollname = 'POSNR'.
  APPEND s_fieldcatalog TO t_fieldcatalog.
  CLEAR: s_fieldcatalog.
  s_fieldcatalog-col_pos = '3'.
  s_fieldcatalog-fieldname = 'MATNR'.
  s_fieldcatalog-rollname = 'MATNR'.
  APPEND s_fieldcatalog TO t_fieldcatalog.
  CLEAR: s_fieldcatalog.
  s_fieldcatalog-col_pos = '4'.
  s_fieldcatalog-fieldname = 'NETPR'.
  s_fieldcatalog-ref_tabname = 'VBAP'.
  s_fieldcatalog-ref_fieldname = 'NETPR'.
  s_fieldcatalog-do_sum = 'X'.
  APPEND s_fieldcatalog TO t_fieldcatalog.
  CLEAR: s_fieldcatalog.
* Get vbak
  SELECT vbeln UP TO 100 ROWS
  FROM
  vbak
  INTO TABLE itab.
  IF NOT itab[] IS INITIAL.
* Get vbap
    SELECT vbeln posnr matnr netpr waerk arktx
    FROM vbap
    INTO TABLE itab1
    FOR ALL ENTRIES IN itab
    WHERE vbeln = itab-vbeln.
  ENDIF.
  v_repid = sy-repid.
* Build sort internal table.
  s_sort-spos      = '1'.
  s_sort-fieldname = 'VBELN'.
  s_sort-tabname  = 'ITAB1'.
  s_sort-up = 'X'.
  s_sort-subtot = 'X'.
  s_sort-group = 'UL'.
  APPEND s_sort TO t_sort.
* Get alv events.
  CALL FUNCTION 'REUSE_ALV_EVENTS_GET'
    EXPORTING
      i_list_type     = 2
    IMPORTING
      et_events       = i_event
    EXCEPTIONS
      list_type_wrong = 0
      OTHERS          = 0.
* Before line output.
  READ TABLE i_event  INTO l_s_event
                    WITH KEY name = 'BEFORE_LINE_OUTPUT'.
  IF sy-subrc = 0.
    MOVE 'BEFORE_LINE_OUTPUT' TO l_s_event-form.
    MODIFY i_event FROM l_s_event INDEX sy-tabix.
  ENDIF.
* Populate dummy text.
  s_layout-subtotals_text = 'Dummy'.
* Init
  CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_INIT'
    EXPORTING
      i_callback_program = v_repid.
* Append
  CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_APPEND'
    EXPORTING
      is_layout                  = s_layout
      it_fieldcat                = t_fieldcatalog
      i_tabname                  = 'ITAB1'
      it_events                  = i_event
      it_sort                    = t_sort
    TABLES
      t_outtab                   = itab1
    EXCEPTIONS
      program_error              = 1
      maximum_of_appends_reached = 2
      OTHERS                     = 3.
* Display
  CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_DISPLAY'.
*&      Form  BEFORE_LINE_OUTPUT
*       text
*      -->GS_LINEINFO  text
FORM before_line_output USING gs_lineinfo TYPE kkblo_lineinfo.
  FIELD-SYMBOLS: <fs_layout>  TYPE kkblo_layout.
  ASSIGN ('(SAPLKKBL)GT_STACK-IS_LAYOUT') TO <fs_layout>.
  CHECK sy-subrc = 0.
* Check if it is subtotal line.
  CHECK gs_lineinfo-subtot = 'X'.
* Get the text
  READ TABLE itab1 INTO wa INDEX gs_lineinfo-sumindex.
  IF sy-subrc = 0.
    <fs_layout>-subtotals_text = wa-text.
  ENDIF.
ENDFORM.                    "BEFORE_LINE_OUTPUT
Thanks
Naren