Print label image in GIF format returned by Web Service XML string.

Question

Hi All
I have extremely interesting situations and have been struggling with this for a past week. I have been looking everywhere but nobody seems to have an answer. This is my last resort.
Detail -
I am consuming UPS web service from my ABAP program. Everything works fine until I have to print UPS label.  The label image is returned to my ABAP program via XML by the UPS reply transaction as a GIF image.
When I download this image to my PC I can see it and print it, but for the love of god I cannot print this image from my ABAP program. The GIF image is passed to me as a binary data string it looks like bunch on numbers - (2133FFDGFGFGFHHu2026..) very long string about 89800 bites. I cannot use smart forms since smart form requires to have graphic stored in  SAP before smart form print, so this is not possible. I need help figuring out how print GIF image form ABAP or any other SAP method dynamically.  Any ideas are extremely appreciated. I am just puzzled that I cannot find any info on something like this. I cannot be the first one who needs to print GIF image in SAP.

Answer 1

Hi all,
I understand this thread was started long back. But wanted to share this solution since I see the same question in many forums without any particular conclusive answer. So the steps I am explaining here, if it helps in some way, I will be really happy. I won't say this is the perfect solution. But it definitely helps us to print the images. This solution is infact implemented successfully in my client place & works fine.
And please note there may be  better solutions definitely available in ECC6 or other higher releases. This solution is mainly for lesser versions, for people don't have ADOBE forms or other special classes.
Important thing here is binary string is converted to postscript here. So you need to make sure your printer supports postscripts. (Ofcourse, if anybody is interested, they can do their R&D on PCL conversion in the same way...and pls let me know). Once the binary data is converted to postscript, we are going to write it in the binary spool. so you will still see junk characters (or numberssss) in spool. But when you print it in postscript printer , it should work.
First step, assuming you have your binary data ready from tiff or pdf based on your requirement.
Basically below compress/decompress function modules convert the binary data from lt_bin (structure TBL1024) to target_tab (structure SOLIX). From Raw 1024 to Raw 255
DATA: aux_tab LIKE soli OCCURS 10. - temp table
Compress table
              CALL FUNCTION 'TABLE_COMPRESS'
                TABLES
                  in             = lt_bin
                  out            = aux_tab
                EXCEPTIONS
                  compress_error = 1
                  OTHERS         = 2.
Decompress table
              CALL FUNCTION 'TABLE_DECOMPRESS'
                TABLES
                  in                   = aux_tab
                  out                  = target_tab
                EXCEPTIONS
                  compress_error       = 1
                  table_not_compressed = 2
                  OTHERS               = 3.
In my case, since I have to get it from archived data using function module, ARCHIV_GET_TABLE which gives RAW 1024, above conversion was necessary.
Second step: Application server temporary files for tif/postscript files.
We need two file names here for tif file & for converted postscript file. Please keep in mind, if you are running it in background, user should have authorization to read/write/delete this file.
Logical file name just to make sure the file name is maintainable. Hard code the file name if you don't want to use logical file name.
              CALL FUNCTION 'FILE_GET_NAME'
                EXPORTING
                  logical_filename = 'ABCD'
                  parameter_1      = l_title
                  parameter_2      = sy-datum
                  parameter_3      = sy-uzeit
                IMPORTING
                  file_name        = lv_file_name_init
                EXCEPTIONS
                  file_not_found   = 1
                  OTHERS           = 2.
              IF sy-subrc <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
        WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
              ENDIF.
Now concatenate with the different extensions to get two different files.
              CONCATENATE lv_file_name_init '.tif' INTO lv_file_name_tif.
              CONCATENATE lv_file_name_init '.ps' INTO  lv_file_name_ps.
Third step: Write the target_tab to tif file.
Open dataset for writing the tif file.
              OPEN DATASET lv_file_name_tif FOR OUTPUT IN BINARY MODE.
              IF NOT sy-subrc IS INITIAL.
                RAISE open_failed.
              ELSE.
                LOOP AT target_tab INTO w_target_tab.
                  CATCH SYSTEM-EXCEPTIONS dataset_write_error = 1
                                          OTHERS = 4.
                    TRANSFER w_target_tab TO lv_file_name_tif.
                  ENDCATCH.
                  IF NOT sy-subrc IS INITIAL.
                    RAISE write_failed.
                  ENDIF.
                ENDLOOP.
                CATCH SYSTEM-EXCEPTIONS dataset_cant_close = 1
                                        OTHERS = 4.
                  CLOSE DATASET lv_file_name_tif.
                ENDCATCH.
              ENDIF.
Fourth Step: Convert the tiff file to postscript file.
This is the critical step. Create an external command (SM49/SM69) for this conversion. In this example, Z_TIFF2PS is created. Infact, I did get help from our office basis gurus in this. so I don't have the exact code of this unix script. You can refer the below link or may get some help from unix gurus.
http://linux.about.com/library/cmd/blcmdl1_tiff2ps.htm
Since my external command needs .ps file name and .tif file name as input, concatenate it & pass it as additional parameter. Command will take care of the conversion & will generate the .ps file.
   CONCATENATE lv_file_name_ps lv_file_name_tif INTO lw_add SEPARATED BY space.
Call the external command with the file paths.
              CALL FUNCTION 'SXPG_COMMAND_EXECUTE'
                EXPORTING
                  commandname           = 'Command name'
                  additional_parameters = lw_add
                TABLES
                  exec_protocol         = t_comtab.
Fifth step: Read the converted ps file and convert it to RAW 255.
  DATA:lw_content TYPE xstring.
Open dataset for reading the postscript (ps) file
              OPEN DATASET lv_file_name_ps FOR INPUT IN BINARY MODE.
Check whether the file is opened successfully
              IF NOT sy-subrc IS INITIAL.
                RAISE open_failed.
              ELSE.
                READ DATASET lv_file_name_ps INTO lw_content.
              ENDIF.
Close the dataset
              CATCH SYSTEM-EXCEPTIONS dataset_cant_close = 1
                                      OTHERS = 4.
                CLOSE DATASET lv_file_name_ps.
              ENDCATCH.
Make sure you delete the temporary files so that you can reuse the same names again & again for next conversions.
              DELETE DATASET lv_file_name_tif.
              DELETE DATASET lv_file_name_ps.
Convert the postscript file to RAW 255
              REFRESH target_tab.
              CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
                EXPORTING
                  buffer     = lw_content
                TABLES
                  binary_tab = target_tab.
Sixth step: Write the postscript data to binary spool by passing the correct print parameters.
              IF NOT target_tab[] IS INITIAL.
                PERFORM spo_job_open_cust USING l_device
                                                     l_title
                                                     l_handle
                                                     l_spoolid
                                                     lw_nast.
                LOOP AT target_tab INTO w_target_tab.
                  PERFORM spo_job_write(saplstxw) USING l_handle
                                                        w_target_tab
                                                      l_linewidth.
                ENDLOOP.
                PERFORM spo_job_close(saplstxw) USING l_handle
                                                      l_pages.
                IF sy-subrc EQ 0.
                  MESSAGE i014 WITH
                   'Spools for'(019) lw_final-vbeln
               'created successfully.Check transaction SP01'(020).
                ENDIF.
              ENDIF.
Please note the parameters when calling function module RSPO_SR_OPEN. Change the print parameters according to your requirement. This is very important.
FORM spo_job_open_cust USING value(device) LIKE tsp03-padest
                        value(title) LIKE tsp01-rqtitle
                        handle  LIKE sy-tabix
                        spoolid LIKE tsp01-rqident
                        lw_nast TYPE nast.
  DATA: layout LIKE tsp01-rqpaper,
        doctype LIKE tsp01-rqdoctype.
  doctype = 'BIN'.
  layout = 'G_RAW'.
  CALL FUNCTION 'RSPO_SR_OPEN'
      EXPORTING
        dest                   = device "Printer name
    LDEST                  =
        layout                 = layout
    NAME                   =
        suffix1                = 'PDF'
    SUFFIX2                =
    COPIES                 =
     prio                   = '5'
       immediate_print        = 'X'
immediate_print        = lw_nast-dimme
        auto_delete            = ' '
        titleline              = title
    RECEIVER               =
    DIVISION               =
    AUTHORITY              =
    POSNAME                =
    ACTTIME                =
    LIFETIME               = '8'
        append                 = ' '
        coverpage              = ' '
    CODEPAGE               =
        doctype                = doctype
    ARCHMODE               =
    ARCHPARAMS             =
    TELELAND               =
    TELENUM                =
    TELENUME               =
      IMPORTING
        handle                 = handle
        spoolid                = spoolid
      EXCEPTIONS
        device_missing         = 1
        name_twice             = 2
        no_such_device         = 3
        operation_failed       = 4.
  CASE sy-subrc.
    WHEN 0.
      PERFORM msg_v1(saplstxw) USING 'S'
                       'RSPO_SR_OPEN o.k., Spoolauftrag $'(128)
                       spoolid.
      sy-subrc = 0.
    WHEN 1.
      PERFORM msg_v1(saplstxw)  USING 'E'
                           'RSPO_SR_OPEN Fehler: Gerät fehlt'(129)
                           space.
      sy-subrc = 1.
    WHEN 2.
      PERFORM msg_v1(saplstxw)  USING 'E'
                         'RSPO_SR_OPEN Fehler: Ungültiges Gerät $'(130)
                         device.
      sy-subrc = 1.
    WHEN OTHERS.
      PERFORM msg_v1(saplstxw)  USING 'E'
                           'RSPO_SR_OPEN Fehler: $'(131)
                           sy-subrc.
      sy-subrc = 1.
  ENDCASE.
ENDFORM.                    "spo_job_open_cust
Thats it. We are done. If you open the spool, still you will see numbers/junk characters. if you print it in postscript printer, it will be printed correctly. If you try to print it PCL, you will get lot of pages wasted since it will print all junk characters. So please make sure you use postscript printer for this.
Extra step for mails (if interested):
Mails should work fine without any extra conversion/external command since it will be opened again using windows. So after the first step (compress & decompress)
Create attachment notification for each attachment
              objpack-transf_bin = 'X'.
              objpack-head_start = 1.
              objpack-head_num   = 1.
              objpack-body_start = lv_num + 1.
              DESCRIBE TABLE  lt_target_tab LINES objpack-body_num.
              objpack-doc_size   =  objpack-body_num * 255.
              objpack-body_num = lv_num + objpack-body_num.
              lv_num = objpack-body_num.
              objpack-doc_type   =  'TIF'.
              CONCATENATE 'Attachment_' l_object_id INTO objpack-obj_descr.
              reclist-receiver = l_email.
              reclist-rec_type = 'U'.
              reclist-express = 'X'.
              APPEND reclist.
              CALL FUNCTION 'SO_NEW_DOCUMENT_ATT_SEND_API1'
                EXPORTING
                  document_data              = docdata
                  put_in_outbox              = 'X'
                  commit_work                = 'X'
                TABLES
                  packing_list               = objpack
                  contents_txt               = objtxt
                  contents_hex               = target_tab
                  receivers                  = reclist
                EXCEPTIONS
                  too_many_receivers         = 1
                  document_not_sent          = 2
                  document_type_not_exist    = 3
                  operation_no_authorization = 4
                  parameter_error            = 5
                  x_error                    = 6
                  enqueue_error              = 7
                  OTHERS                     = 8.
              IF sy-subrc <> 0.
                RAISE email_not_sent.
              ENDIF.
              COMMIT WORK.
Hope this helps. I am sure this (print/email both) can be improved further by removing some conversions/by using some other methods.Please check & let me know if you have any such suggestions or any other comments.
Regards,
Gokul
Edited by: Gokul R Nair on Nov 16, 2011 2:59 AM</pre>
Edited by: Gokul R Nair on Nov 16, 2011 3:01 AM
Edited by: Gokul R Nair on Nov 16, 2011 3:15 AM