Raise IGNORE_RECORD Exception

Question

Hi All,
I have the following code. What I do not understand is when processing certain records, when the v_per = 100, record gets written to the "ct_vv_chargeback_actual" table but not to the other following tables like CT_ORIG_ORDER, CT_VV_CHARGEBACK etc.
Is it because of the raise IGNORE_RECORD? If so, can any one explain how the user defined exception works? (apologize for the long code)
Thanks,
DECLARE
CURSOR GET_TKT_CB_DETAILS IS
  SELECT orh.order_no,
         ssku.shipment,
         ssku.sku,
         orh.supplier,
         sum(ssku.qty_expected) tkt_qty,
         sum(ssku.qty_expected) tkt_cost,
      ctt.qty_printed ctt_qty_printed,
      ctt.qty_printed ctt_tkt_cost
    FROM ordhead orh,
         ct_chargeback_shipment shp,
         shipsku ssku,
         uda_item_lov uil,
         (select order_no,pack_no,sum(qty_printed) qty_printed
         from ct_tkt_ticket_print_hist
        group by order_no,pack_no)   ctt
   WHERE shp.receive_date = (select trunc(vdate) from period)
     AND shp.location = 930
     AND shp.tkt_flag is null
     AND shp.order_no = orh.order_no
     AND orh.import_order_ind = 'N'
     AND orh.written_date > to_date('31-MAY-03')
     AND shp.shipment = ssku.shipment
     AND ssku.sku = uil.item                       
     AND uil.uda_id = 6                            
     AND uil.uda_value <> 7
     AND shp.order_no = ctt.order_no
     AND ssku.sku = ctt.pack_no
   group by orh.order_no,
         ssku.shipment,
         ssku.sku,
         orh.supplier,
      ctt.qty_printed ,
      ctt.qty_printed ;
v_chk      varchar2(1);
v_old_quantity number;
v_sku_qty  number;
v_order_no number;
v_shipment number;
v_tkt_cost number;
v_pack_no  number;
v_tkt_qty  number;
v_orig_qty number;
v_supplier number;
v_cb_id    number;
v_vdate    date;
v_dept     number;
v_tkt_dept number;
v_tkt_div  varchar2(2);
v_per      number(12,4);
v_orig_ord_qty number;
v_rate     number(12,4);
v_yn       varchar2(1);
v_err_desc varchar2(200);
v_mail_country_id varchar2(4);
v_pre_tick varchar2(1);
v_actual   number;
IGNORE_RECORD   EXCEPTION;
IGNORE_SUPPLIER EXCEPTION;
BEGIN
select vdate
  into v_vdate
  from period;
FOR get_tkt_cb IN get_tkt_cb_details LOOP
BEGIN
BEGIN
   SELECT '1'
     INTO v_chk
     FROM CT_ORIG_ORDER
    WHERE ORDER_NO = get_tkt_cb.order_no
      AND PACK_NO = get_tkt_cb.sku;
   RAISE IGNORE_RECORD;
EXCEPTION
   WHEN NO_DATA_FOUND THEN
     NULL;
END;
v_old_quantity := 0;
v_sku_qty := 0;
v_order_no := null;
v_shipment := null;
v_tkt_cost := 0;
v_actual   := 0;
v_err_desc := null;
v_chk := null;
v_pack_no := 0;
v_tkt_qty := 0;
v_orig_qty := 0;
v_supplier := 0;
v_cb_id    := 0;
v_dept := 0;
v_tkt_dept := 0;
v_tkt_div := 0;
v_per := 0;
v_rate := 0;
v_yn := null;
v_pre_tick := null;
   v_pack_no  := get_tkt_cb.sku;
   BEGIN
    select sum(sku_qty)
      into v_sku_qty
      from packsku
     where pack_no =v_pack_no;
   EXCEPTION
    WHEN NO_DATA_FOUND THEN
       v_sku_qty := 1;
   END;
   select dept
     into v_dept
     from desc_look
    where sku = v_pack_no;
   v_supplier := get_tkt_cb.supplier;
   v_order_no := get_tkt_cb.order_no;
   BEGIN
    select nvl(per,0),
           nvl(rate,1)
      into v_per,
           v_rate
      from AP_CB_EXCEPTIONS
     where vendor_number = lpad(to_char(v_supplier),'6','0')
       and nvl(div,'0') = decode(length(v_dept),4,substr(to_char(v_dept),1,1),'1')
       and nvl(dept,0) = v_dept
       and nvl(cb_no,410) = 410
       and trunc(v_vdate) between trunc(start_date) and nvl(trunc(end_date),trunc(v_vdate));
   EXCEPTION
     WHEN NO_DATA_FOUND THEN
      BEGIN
        select nvl(per,0),
               nvl(rate,1)
          into v_per,
               v_rate
          from AP_CB_EXCEPTIONS
         where vendor_number = lpad(to_char(v_supplier),'6','0')
           and nvl(div,'0') = decode(length(v_dept),4,substr(to_char(v_dept),1,1),'1')
           and nvl(dept,0) = 0
           and nvl(cb_no,410) = 410
           and trunc(v_vdate) between trunc(start_date) and nvl(trunc(end_date),trunc(v_vdate));
      EXCEPTION
       WHEN NO_DATA_FOUND THEN
       BEGIN
        select nvl(per,0),
               nvl(rate,1)
          into v_per,
               v_rate
          from AP_CB_EXCEPTIONS
         where vendor_number = lpad(to_char(v_supplier),'6','0')
           and nvl(div,'0') = '0'
           and nvl(dept,0) =  v_dept
           and nvl(cb_no,410) = 410
           and trunc(v_vdate) between trunc(start_date) and nvl(trunc(end_date),trunc(v_vdate));
       EXCEPTION
        WHEN NO_DATA_FOUND THEN
          BEGIN
           select nvl(per,0),
                  nvl(rate,1)
             into v_per,
                  v_rate
             from AP_CB_EXCEPTIONS
            where vendor_number = lpad(to_char(v_supplier),'6','0')
              and nvl(div,'0') = '0'
              and nvl(dept,0) = 0
              and nvl(cb_no,410) = 410
              and trunc(v_vdate) between trunc(start_date) and nvl(trunc(end_date),trunc(v_vdate));
          EXCEPTION
           WHEN NO_DATA_FOUND THEN
             v_per := 0;
             v_rate := .01;
             --RAISE IGNORE_SUPPLIER;
          END;
       END;
      END;
   END;
   BEGIN
    select country_id
      into v_mail_country_id
      from addr
     where key_value_1 = to_char(v_supplier)
       and seq_no in (select mail_addr_type_seq_no
                        from ct_ordhead
                       where order_no = v_order_no)
       and addr_type = 15;
    IF v_mail_country_id <> 'US' THEN
     Select import_rate
       into v_rate
       from ap_ticket_cb_rates;
    END IF;
   EXCEPTION
    WHEN NO_DATA_FOUND THEN
      RAISE IGNORE_RECORD;
   END;
   BEGIN
    select qty_ordered
      into v_orig_ord_qty
      from ct_po_log
     where order_no = v_order_no
       and sku = v_pack_no
       and date_changed = (select min(date_changed)
                             from ct_po_log
                            where order_no = v_order_no
                              and sku = v_pack_no);
   EXCEPTION
     when others then 
       v_err_desc := substr(sqlerrm,1,100);
       INSERT INTO IF_ERRORS VALUES (
         'CT_TKTCHB.SQL',SYSDATE,'Order no ' || v_order_no || ' sku ' || v_pack_no || ' ',
          v_err_desc);
       commit;
       RAISE IGNORE_RECORD;
   END;
   v_shipment := get_tkt_cb.shipment;
   v_tkt_qty  := get_tkt_cb.ctt_qty_printed;
   v_orig_qty := get_tkt_cb.tkt_qty*v_sku_qty;
   v_orig_ord_qty := v_orig_ord_qty * v_sku_qty;
   v_tkt_cost := round(v_orig_ord_qty*v_rate*((100-v_per)/100)*1.15,2);
   v_actual   := round(v_orig_ord_qty*1.15,2);
   IF v_per = 100 THEN
     insert into ct_vv_chargeback_actual values (
        null,
        v_supplier,
        v_order_no,
        v_shipment,
        v_pack_no,
        '410',
        v_actual,
        1,
        v_vdate);
     COMMIT;
     raise IGNORE_RECORD;
   END IF;
   select ct_vv_chargeback_seq.nextval
     into v_cb_id
     from dual;
   INSERT INTO CT_ORIG_ORDER VALUES (
        v_order_no,
        v_shipment,
        v_pack_no,
        v_tkt_qty,
        v_orig_qty,
        v_orig_ord_qty,
        'N',
        v_supplier,
        v_cb_id,
        'N',
        v_tkt_cost,
        v_vdate);
   INSERT INTO CT_VV_CHARGEBACK VALUES (
     v_cb_id,
        v_order_no,
        'A',
        v_supplier,
        null,
        null,
        null,
        null,
        v_shipment);
   INSERT INTO CT_VV_CHARGEBACK_DETAIL VALUES (
        v_cb_id,
        v_pack_no,
        '410',
        v_tkt_cost,
        1);
   IF v_tkt_cost <> v_actual THEN
     insert into ct_vv_chargeback_actual values (
        v_cb_id,
        v_supplier,
        v_order_no,
        v_shipment,
        v_pack_no,
        '410',
        v_actual,
        1,
        v_vdate);
   END IF;    
   UPDATE CT_CHARGEBACK_SHIPMENT
      SET TKT_FLAG = 'C'
    WHERE shipment = get_tkt_cb.shipment;
   COMMIT;
EXCEPTION
  WHEN IGNORE_SUPPLIER THEN
    NULL;
  WHEN IGNORE_RECORD THEN
    NULL;
  WHEN NO_DATA_FOUND THEN
   UPDATE CT_CHARGEBACK_SHIPMENT
      SET TKT_FLAG = 'D'
    WHERE shipment = get_tkt_cb.shipment;
   COMMIT;
  WHEN OTHERS THEN
   rollback;
   v_err_desc := substr(sqlerrm,1,200);
   insert into if_errors values ('ct_tktchb.sql',
                                 sysdate,
                                 v_err_desc,
                                 'Error while processing  order - ' ||
                                  to_char(v_order_no) ||
                                 ' shipment - ' || to_char(v_shipment));
   commit;
END;
END LOOP;
   

Answer 1

Without analysing the code in detail, the
IGNORE_RECORD exception is raised in four places
within the BEGIN-END block that implements the loop.
When it's raised, processing drops to the exception
handler at the bottom, then the loop continues with
the next record. It's kind of a pre-11g CONTINUE.gotcha...thats what I wanted to know. Glad to know that it works as CONTINUE....couldn't figure out why some values are not showing up.
Thanks,
Chiru