Ref Cursor Problem in Oracle Forms 6i

Question

Hi all.
In Oracle Forms 6i, can not I do this?
DECLARE
TYPE CUR_REF IS REF CURSOR;
CUR_PRODUCTS CUR_REF;
VAR_QUERY VARCHAR2(3000) := 'SELECT something FROM table';
BEGIN
OPEN CUR_PRODUCTS FOR VAR_QUERY;
END;
It generates error on opening that it expects a SELECT statement.
How can I open a dynamic ref cursor in Oracle Forms 6i??? The same thing works fine in PL/SQL.
Regards,
Zaaf
Thanks in advance.

Answer 1

It could be like this:
PROCEDURE dynamic_cursor ( PC$Clause  IN Varchar2 )
IS
  cursor_number EXEC_SQL.CursType;
  -- Variables for the data to be returned into
  LC$ACTYPE       Number;
  -- Control variables
  LN$count       Number;
  LC$sql_order   Varchar2(256);
BEGIN
     -- Open the cursor --
     cursor_number := Exec_SQL.Open_cursor;
     -- build the complete SQL order -- 
     LC$sql_order := PC$clause  ;
     -- Parse the SQL order --
     EXEC_SQL.PARSE(cursor_number, LC$sql_order);
     -- Define the columns for the data to be returned --
     EXEC_SQL.DEFINE_COLUMN(cursor_number,1,LC$ACTYPE);
     -- Execute the Cursor --
     LN$count := EXEC_SQL.EXECUTE(cursor_number);
     -- Loop and fetch each row from the result set --
     While EXEC_SQL.FETCH_ROWS(cursor_number) > 0 Loop
       EXEC_SQL.COLUMN_VALUE(cursor_number,1,LC$ACTYPE);
          begin
            select chqfac, pasfac, indbcr ,
            staxfl, excise, incchg, cat001 , trntyp , subtyp
            into s_chkbok, s_pasbok, s_intber,
            s_staxfl, s_excise, s_incchg, s_cat001 , ss_trntyp , ss_subtyp
            from stfeacty
            where brancd = s_brancd
            and actype = LC$ACTYPE;
            s_actype := LC$ACTYPE ;
          exception
            when no_data_found then
              NULL;
            when too_many_rows then
              NULL;
          end;
     End Loop ;
     -- Close the cursors
     EXEC_SQL.CLOSE_CURSOR(cursor_number);
EXCEPTION
  When EXEC_SQL.INVALID_CONNECTION Then
     message('Unexpected Invalid Connection error from EXEC_SQL');
  When EXEC_SQL.PACKAGE_ERROR Then
     message('Unexpected error from EXEC_SQL: '||to_char(EXEC_SQL.LAST_ERROR_CODE)|| EXEC_SQL.LAST_ERROR_MESG);
  If EXEC_SQL.IS_OPEN(cursor_number) Then
    EXEC_SQL.CLOSE_CURSOR(cursor_number);
    message('Exception - Cleaned up Cursor');
  End if;
END; That you could call with the following:
dynamic_cursor('SELECT ac_type FROM SYSADM.SAVINGS');But, if the query is as simple with only the table name change, you could aslo use a simpliest solution based on a record group.
Francois