Reg: ALV (REUSE_ALV_GRID_DISPLAY)

Question

Hi Experts,
I need to know how to give drop down list in one of the field in my ALV.
I found some posting in sdn, but that are related to OOPS concepts.
But i am using REUSE function module.
Can you please provide me the solution how to achecive drop down list in ALV using REUSE_ALV_GRID_DISPLAY.
Thanks
Vijay.R

Answer 1

Hi Vijayendran,
   There is only oops method available to create drop down list in ALV.
Go through the program below and modify your program accordingly.
Only thing that you have to do is to create container for your alv and use this container for displaying drop down list.
This program displays a dropdown list in one of the fields of the ALV.
*& Report  Z_LISTBOX_ALV
*& Program to display a dropdown list in ALV.
REPORT  z_listbox_alv.
TYPE-POOLS: slis.
TYPES: BEGIN OF ty_rating,
         task(20) TYPE c,
         rating TYPE i,
         weightage(2) TYPE c,
         comments(40) TYPE c,
       END OF ty_rating.
DATA: g_alvgrid TYPE REF TO cl_gui_alv_grid,
      g_alv_container TYPE REF TO cl_gui_custom_container,
      int_fieldcat TYPE lvc_t_fcat,
      ok_code TYPE sy-ucomm.
DATA: int_outputdata TYPE TABLE OF ty_rating.
INITIALIZATION.
START-OF-SELECTION.
* call new screen for displaying the oop alv
  CALL SCREEN 1100.
* Double click on the screen, it takes you the screen painter (SE51). Create
* Custom Container on the screen and name is as u2018CONTAINERu2019. Set the Ok-Code
* the screen as u2018OK_CODEu2019. Also create a GUI status named 'STANDARD' and
* in set Ok-code '&F03' for the back button.
* The screen 1100 thus gets created to hold the grid ALV.
* In the PBO of the screen, call the modules to set pf-status, title and
* to display the ALV list.
* In case we have an interactive ALV or for additional functionalities we can
* create OK-CODES and based on the user command we do the coding in the PAI.
*&      Module  STATUS_0600  OUTPUT
*       set the PF status of the screen. Called in PBO of screen.
MODULE status_0600 OUTPUT.
  SET PF-STATUS 'STANDARD'.
ENDMODULE.                 " STATUS_0600  OUTPUT
*&      Module  DISPLAY_ALV  OUTPUT
*       Displays the alv list. Called in PBO of screen.
MODULE display_alv OUTPUT.
*  get the data.
  PERFORM retrieve_data.
*  prepare fieldcatalog for displaying the alv
  PERFORM prepare_fieldcatalog.
*  create a container to display the list
  CREATE OBJECT g_alv_container
    EXPORTING
      container_name = 'CONTAINER'.
*  create a reference for the alv
  CREATE OBJECT g_alvgrid
    EXPORTING
      i_parent = g_alv_container.
*  prepare a listbox for the rating column
  PERFORM fill_dropdown.
*  call the method to display the list
  CALL METHOD g_alvgrid->set_table_for_first_display
    EXPORTING
      i_bypassing_buffer            = 'X'
      i_save                        = 'X'
    CHANGING
      it_outtab                     = int_outputdata
      it_fieldcatalog               = int_fieldcat
    EXCEPTIONS
      invalid_parameter_combination = 1
      program_error                 = 2
      too_many_lines                = 3
      others                        = 4
  IF sy-subrc <> 0.
   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDMODULE.                    "DISPLAY_ALV OUTPUT
*&      Form  PREPARE_FIELDCATALOG
*       prepares fieldcatalog
FORM prepare_fieldcatalog .
  DATA: lws_fieldcat TYPE lvc_s_fcat.
  CLEAR int_fieldcat.
  CLEAR lws_fieldcat.
  lws_fieldcat-col_pos   = 1.
  lws_fieldcat-fieldname = 'TASK'.
  lws_fieldcat-scrtext_m = 'TASK'.
  APPEND lws_fieldcat TO int_fieldcat.
  CLEAR lws_fieldcat.
  lws_fieldcat-col_pos   = 2.
  lws_fieldcat-fieldname = 'RATING'.
  lws_fieldcat-edit = 'X'.
  lws_fieldcat-scrtext_m = 'RATING'.
  lws_fieldcat-just = 'L'.
  lws_fieldcat-outputlen = '6'.
  lws_fieldcat-drdn_hndl = '1'.        "handle for listbox
  APPEND lws_fieldcat TO int_fieldcat.
  CLEAR lws_fieldcat.
  lws_fieldcat-col_pos   = 3.
  lws_fieldcat-fieldname = 'WEIGHTAGE'.
  lws_fieldcat-scrtext_m = 'WEIGHTAGE'.
  lws_fieldcat-outputlen = '9'.
  APPEND lws_fieldcat TO int_fieldcat.
  CLEAR lws_fieldcat.
  lws_fieldcat-col_pos   = 4.
  lws_fieldcat-fieldname = 'COMMENTS'.
  lws_fieldcat-scrtext_m = 'COMMENTS'.
  lws_fieldcat-edit = 'X'.
  APPEND lws_fieldcat TO int_fieldcat.
ENDFORM.                    " PREPARE_FIELDCATALOG
*&      Form  RETRIEVE_DATA
*       retreives the data to be displayed
FORM retrieve_data .
  DATA: lws_outputdata TYPE ty_rating.
  CLEAR int_outputdata.
  CLEAR lws_outputdata.
  lws_outputdata-task = 'proj. related'.
  lws_outputdata-weightage = '20'.
  APPEND lws_outputdata TO int_outputdata.
  CLEAR lws_outputdata.
  lws_outputdata-task = 'process. related'.
  lws_outputdata-weightage = '10'.
  APPEND lws_outputdata TO int_outputdata.
  CLEAR lws_outputdata.
  lws_outputdata-task = 'knowledge mgnt.'.
  lws_outputdata-weightage = '30'.
  APPEND lws_outputdata TO int_outputdata.
ENDFORM.                    " RETRIEVE_DATA
*&      Form  FILL_DROPDOWN
*       prepares the listbox to be displayed and assigns it to the alv
FORM fill_dropdown .
  DATA: lint_dropdown TYPE lvc_t_drop,
        lws_dropdown TYPE lvc_s_drop.
  CLEAR lint_dropdown.
  CLEAR lws_dropdown.
  lws_dropdown-handle = '1'.
  lws_dropdown-value = '5'.
  APPEND lws_dropdown TO lint_dropdown.
  CLEAR lws_dropdown.
  lws_dropdown-handle = '1'.
  lws_dropdown-value = '4'.
  APPEND lws_dropdown TO lint_dropdown.
  CLEAR lws_dropdown.
  lws_dropdown-handle = '1'.
  lws_dropdown-value = '3'.
  APPEND lws_dropdown TO lint_dropdown.
  CLEAR lws_dropdown.
  lws_dropdown-handle = '1'.
  lws_dropdown-value = '2'.
  APPEND lws_dropdown TO lint_dropdown.
  CLEAR lws_dropdown.
  lws_dropdown-handle = '1'.
  lws_dropdown-value = '1'.
  APPEND lws_dropdown TO lint_dropdown.
  CALL METHOD g_alvgrid->set_drop_down_table
    EXPORTING
      it_drop_down = lint_dropdown.
ENDFORM.                    " FILL_DROPDOWN
*&      Module  HANDLE_GOBACK  INPUT
*       handles 'back' button. Called in PAI of the screen.
MODULE handle_goback INPUT.
  IF ok_code EQ '&F03'.
    LEAVE PROGRAM.
  ENDIF.
ENDMODULE.
Get back to me for any clarification.
Regards,
Bhavesh