Reg. entering another transaction from output list

Question

I am using 'REUSE_ALV_LIST_DISPLAY' for displaying output from a custom table. The custom table contains sales order and corresponding delivery. Now, on the output, if the user clicks on the sales order (like a hyperlink), it should go to VA02 transaction (where the user should be able to change if he wants and save and come back). If the user clicks on delivery, it should go to VF03 (only display, not change mode..but the user should be able to come back).
Can you tell me what code I need to add around with this ''REUSE_ALV_LIST_DISPLAY' for the above requirement? First of all, is this possible when I am displaying output with ''REUSE_ALV_LIST_DISPLAY'?
Thank you very much.

Answer 1

Sure, check out this sample program,  this illistrates using a hotspot in the ALV list,  all you need to do is the code for the delivery number as well.
report zrich_0001 .
* Global ALV Data Declarations
type-pools slis.
data: ivbak type table of vbak with header line.
start-of-selection.
  select * into corresponding fields of table ivbak
            from vbak
                 up to 100 rows.
  perform call_alv.
*  CALL_ALV
form call_alv.
  data: xfc type slis_fieldcat_alv.
  data: ifc type slis_t_fieldcat_alv.
  data: xevents type slis_alv_event.
  data: ievents type slis_t_event.
  data: repid type sy-repid.
  repid = sy-repid.
* Events
  clear ievents.  refresh ievents.
  xevents-name = 'USER_COMMAND'.
  xevents-form = 'HANDLE_HOTSPOT'.
  append xevents to ievents.
* Build Field cat
  clear ifc.  refresh ifc.
  clear xfc.
  xfc-reptext_ddic = 'Sales Document'.
  xfc-fieldname    = 'VBELN'.
  xfc-tabname      = 'IVBAK'.
  xfc-outputlen    = '10'.
  xfc-hotspot      = 'X'.
  append xfc to ifc.
  clear xfc.
  xfc-reptext_ddic = 'Order Type'.
  xfc-fieldname    = 'AUART'.
  xfc-tabname      = 'IVBAK'.
  xfc-outputlen    = '3'.
  append xfc to ifc.
* Call ABAP List Viewer (ALV)
  call function 'REUSE_ALV_LIST_DISPLAY'
       exporting
            it_fieldcat        = ifc
            i_callback_program = repid
            it_events          = ievents
       tables
            t_outtab           = ivbak.
endform.
*       FORM handle_hotspot
form handle_hotspot using w_ucomm type sy-ucomm
                          w_selfield type slis_selfield.
  case w_ucomm.
    when '&IC1'.
      read table ivbak index w_selfield-tabindex.
<b>      case w_selfield-fieldname.
        when 'VBELN'.
          set parameter id 'AUN' field ivbak-vbeln.
             call transaction 'VA03' and skip first screen.
*        when 'DELNOTE'.   "<-- What ever field is the delivery note
*          set parameter id 'VL' field <dn_value>.
*             call transaction 'VL03' and skip first screen.</b>
     endcase.
  endcase.
endform.
Regards,
Rich Heilman