Replace Mac line breaks with Windows linebreaks?

Question

Is there a simple AppleScript that could process a plain text file created on a Mac and replace the line breaks with Windows-compatible \r\n line breaks?
I thought this would be a very simple task but have been searching for quite a while and can't find anything.
Thanks.
Paul

Answer 1

There are several approaches to this. Here's one of them:
set theFile to (choose file)
set MacText to paragraphs of (read theFile)
set {oldDelims, my text item delimiters} to {my text item delimiters, (return & linefeed)}
set WindowsText to MacText as text
set my text item delimiters to oldDelims
set outputFile to (open for access theFile with write permission)
set eof outputFile to 0
write WindowsText to outputFile
close access outputFile
To explain, the first line asks you to choose the file in question - you could use any technique to identify the file, including hard-coding the path or using a drag-and-drop handler.
The second line gets the current paragraphs and calls them 'MacText'
The third line saves the current text item delimiters in oldDelims and sets the new text item delimiters to the CR+LF combination.
The fourth line performs the magic of transforming the file. It does this by coercing the list of paragraphs (obtained in line 2) into a single text block, and it inserts the current text item delimiters between each text item, miraculously giving you CRLF-terminated paragraphs.
The fifth line restores the text item delimiters to whatever they were before (you don't know what they were, but don't need to know what they were, as long as you restore the previous setting - it's unlikely you want CRLF moving forwards).
The rest of the script (lines 6 through 9) reopen the file you originally selected, sets the EOF to 0 (effectively wiping the file contents), then writes the CRLF-terminated text to the file and finally closes the file.
Note that some people might suggest using text item delimiters to break up the original text file on CRs but that would be wrong IMHO. The reason is that 'paragraphs of' can detect and handle both CR and CRLF-terminated paragraphs, leaving you with clean paragraphs into which you insert CRLFs.
This means that if the file originally had CRLF-terminated paragraphs you'd end up with the same data, but at least there was no harm done.
In contrast, if you simply searched for CRs and replaced them with CRLFs you could have the situation where you selected a CRLF-terminated file (maybe you didn't realize it was already in the Windows format) and your script would blindly replace each CR with CRLF, meaning you'd end up with CRLFLF combinations, which is very wrong.