Script for Compare same table 'TAB1' structures in different schemas

Question

Hello, i am having three schema and in all schema i have same table for example TAB1 and i want to Compare TAB1 table structures in all three schema but i don't know the script. the different should content at least  DATA_TYPE,DATA_LENGTH,DECODE(DATA_PRECISION,NULL,NULL,DATA_PRECISION||','||DATA_SCALE) columns in query. Oracle Database 10g Enterprise Edition Release 10.2.0.4.0 - 64bi Thanks..

Answer 1

If you want a generic script use below function to get the difference.. Run the below script and let me know in case of any issues
CREATE OR REPLACE TYPE nt_username IS TABLE OF VARCHAR2(50);
CREATE OR REPLACE TYPE obj_struc IS OBJECT (user_name1     VARCHAR2(30),
                                           user_name2      VARCHAR2(30),
                                           column_name1    VARCHAR2(30),
                                           column_name2    VARCHAR2(30),
                                           data_type1      VARCHAR2(106),
                                           data_type2      VARCHAR2(106),
                                           data_length1    NUMBER(10),
                                           data_length2    NUMBER(10),
                                           data_precision1 VARCHAR2(50),
                                           data_precision2 VARCHAR2(50),
                                           column_id1      NUMBER(10),
                                           column_id2      NUMBER(10)
CREATE OR REPLACE TYPE nt_struc IS TABLE OF obj_struc;
CREATE OR REPLACE FUNCTION tabstruc_script (p_tabnm   VARCHAR2,
                                            p_usernm  nt_username
RETURN nt_struc
AS
v_nt_struc nt_struc := nt_struc();
v_ntusrnm nt_username := p_usernm;
TYPE rec_stru IS RECORD (column_name    all_tab_columns.column_name%TYPE,
                         data_type      all_tab_columns.data_type%TYPE,
                         data_length    all_tab_columns.data_length%TYPE,
                         data_precision all_tab_columns.data_precision%TYPE,
                         data_scale     all_tab_columns.data_scale%TYPE,
                         column_id      all_tab_columns.column_id%TYPE
TYPE nt_stru IS TABLE OF rec_stru;
v_ntstru nt_stru  := nt_stru();
v_columnname all_tab_columns.column_name%TYPE;
v_reccnt NUMBER;
v_cnt NUMBER;
v_precision1 VARCHAR2(50);
v_precision2 VARCHAR2(50);                    
BEGIN
FOR i IN 1..v_ntusrnm.COUNT
  LOOP
     SELECT COUNT(*) INTO v_reccnt
     FROM all_tables
     WHERE owner = v_ntusrnm(i)
     AND table_name = p_tabnm;
      IF v_reccnt >= 1 THEN
         SELECT column_name,  
                data_type,    
                data_length, 
                data_precision,
                data_scale,
                column_id
         BULK COLLECT INTO v_ntstru
         FROM all_tab_columns
         WHERE owner = v_ntusrnm(i)
         AND table_name = p_tabnm;
          FOR j IN i+1..v_ntusrnm.COUNT
            LOOP
                 FOR k IN 1..v_ntstru.COUNT
                   LOOP
                      SELECT COUNT(*) INTO v_cnt
                      FROM all_tab_columns
                      WHERE owner = v_ntusrnm(j)
                      AND table_name = p_tabnm
                      AND column_name = v_ntstru(k).column_name;
                       IF v_cnt >= 1 THEN
                         FOR l IN (SELECT column_name,  
                                          data_type,    
                                          data_length, 
                                          data_precision,
                                          data_scale,
                                          column_id
                                   FROM all_tab_columns
                                   WHERE owner = v_ntusrnm(j)
                                   AND table_name = p_tabnm
                                   AND column_name = v_ntstru(k).column_name)
                            LOOP
                              IF ((v_ntstru(k).column_id <> l.column_id)
                                  OR (v_ntstru(k).data_type <> l.data_type)
                                  OR (NVL(v_ntstru(k).data_length,0) <> NVL(l.data_length,0))
                                  OR (NVL(v_ntstru(k).data_precision,0) <> NVL(l.data_precision,0))
                                  OR (NVL(v_ntstru(k).data_scale,0) <> NVL(l.data_scale,0))) THEN
                                 v_nt_struc.EXTEND;
                                 SELECT DECODE(v_ntstru(k).data_precision,NULL,NULL,v_ntstru(k).data_precision||','||v_ntstru(k).data_scale),
                                        DECODE(l.data_precision,NULL,NULL,l.data_precision||','||l.data_scale)
                                 INTO v_precision1,
                                      v_precision2
                                 FROM DUAL;
                                 v_nt_struc(v_nt_struc.COUNT) := obj_struc(v_ntusrnm(i),
                                                                           v_ntusrnm(j),
                                                                           v_ntstru(k).column_name,
                                                                           l.column_name,
                                                                           v_ntstru(k).data_type,
                                                                           l.data_type,
                                                                           v_ntstru(k).data_length,
                                                                           l.data_length,
                                                                           v_precision1,
                                                                           v_precision2,
                                                                           v_ntstru(k).column_id,
                                                                           l.column_id);
                              END IF;
                            END LOOP;
                       END IF;
                   END LOOP;
                  FOR m IN(SELECT column_name,  
                                  data_type,    
                                  data_length, 
                                  data_precision,
                                  data_scale,
                                  column_id
                           FROM all_tab_columns
                           WHERE owner = v_ntusrnm(i)
                           AND table_name = p_tabnm
                           AND column_name NOT IN(SELECT column_name
                                                  FROM all_tab_columns
                                                  WHERE owner = v_ntusrnm(j)
                                                  AND table_name = p_tabnm))
                      LOOP                                         
                        v_nt_struc.EXTEND;
                        SELECT DECODE(m.data_precision,NULL,NULL,m.data_precision||','||m.data_scale)
                        INTO v_precision1
                        FROM DUAL;
                        v_nt_struc(v_nt_struc.COUNT) := obj_struc(v_ntusrnm(i),
                                                                  v_ntusrnm(j),
                                                                  m.column_name,
                                                                  NULL,
                                                                  m.data_type,
                                                                  NULL,
                                                                  m.data_length,
                                                                  NULL,
                                                                  v_precision1,
                                                                  NULL,
                                                                  m.column_id,
                                                                  NULL);
                      END LOOP;
                     FOR n IN(SELECT column_name,  
                                      data_type,    
                                      data_length, 
                                      data_precision,
                                      data_scale,
                                      column_id
                               FROM all_tab_columns
                               WHERE owner = v_ntusrnm(j)
                               AND table_name = p_tabnm
                               AND column_name NOT IN(SELECT column_name
                                                      FROM all_tab_columns
                                                      WHERE owner = v_ntusrnm(i)
                                                      AND table_name = p_tabnm))
                       LOOP
                        v_nt_struc.EXTEND;
                        SELECT DECODE(n.data_precision,NULL,NULL,n.data_precision||','||n.data_scale)
                        INTO v_precision2
                        FROM DUAL;
                        v_nt_struc(v_nt_struc.COUNT) := obj_struc(v_ntusrnm(j),
                                                                  v_ntusrnm(i),
                                                                  n.column_name,
                                                                  NULL,
                                                                  n.data_type,
                                                                  NULL,
                                                                  n.data_length,
                                                                  NULL,
                                                                  v_precision2,
                                                                  NULL,
                                                                  n.column_id,
                                                                  NULL);
                       END LOOP;
                    END LOOP;
        END IF;
  END LOOP;
RETURN v_nt_struc;
EXCEPTION
WHEN OTHERS THEN
  RAISE;
END tabstruc_script;
SELECT * FROM TABLE(tabstruc_script(:tabnm,nt_username(:user1,:user2,:user3)));
You need to pass tablename and username to calling this function. Username is a nested table here so you can pass like nt_username(:user1,:user2,:user3)