Script to change a character in a file and opening it in Numbers

Question

Hello,
Is there an easy way with Applescript to replace all the "," with a "; " in a csv file and open it in Numbers ? The best would be to be able to drag/drop the file over an icon in the dock to do that.
Thank you

Answer 1

Yes, it's easy to do, but depends on the complexity of the csv file. For instance, if you're sure that the csv is simple (in the sense that commas only appear as delimiters and never occur inside text data), then the following will work. Save it as a script application and then drop your files on it):
on open csvFiles
          repeat with thisFile in csvFiles
                    set fp to open for access thisFile with write permission
                    set csvText to read fp
                    set csvSplitText to tid of csvText by ","
                    set csvNewText to tid of csvSplitText by ";"
  set eof fp to 0
  write csvNewText to fp
  close access fp
          end repeat
end open
on tid of input by delim
  -- handler for text items
          set {oldTID, my text item delimiters} to {my text item delimiters, delim}
          if class of input is list then
                    set output to input as text
          else
                    set output to text items of input
          end if
          set my text item delimiters to oldTID
          return output
end tid
If you have a more complx csv format and you have to account for commas that are within text data, then it would help to know more about the structure of the document. I mean, it could be done generically, but I'd rather not fiddle with the code if I don't have to.