Scripting iCal Events

Question

As part of a school project, my students gather weather data when a specific NASA satellite passes over our school. We have to keep an eye on the schedule we receive and collect our data. Every once in a while we forget and miss an overpass. I decided to enter the satellite overpasses as iCal events and have an alarm sound to remind us. This tedious task of entering the events sounds like a great job for AppleScript. This AppleScript project is a little over my head because I don't understand insides of iCal and AppleScripting.
The satellite schedule comes as text in an email and looks like this:
Date & Time | Satellite Position
Mo Day Year Local UT | view sat azm relative solar sat. position sat
Time | zenith fr. N azimuth zenith lat. long dir
Local Time = UT + (-6.0)
9 16 2008 12:19 18 19 | 6.46 104.44 51.37 40.32 39.94 249.13 des
9 17 2008 13:02 19 02 | 54.05 289.85 117.31 38.45 42.22 239.04 des
9 18 2008 12:07 18 07 | 27.40 102.13 49.98 42.00 39.43 252.03 des
9 19 2008 12:50 18 50 | 42.63 287.75 119.55 39.58 41.48 241.85 des
9 20 2008 11:55 17 55 | 43.58 99.08 49.57 43.80 39.09 254.98 des
The only important info for our observations is the Mo, Day, Year and UT time — the other satellite info is not relevant to our observations.
How would I write a AppleScript that would strip away the unimportant info and create a different event each time for the satellite overpass? The iCal event would need to start 15 minutes before and end 15 minutes after the UT time given.
TIA
Message was edited by: Stephen Bunker

Answer 1

Here is some sample code.
-- Code starts here --
property tFile : "HD01:Users:dev_sleidy:Desktop:SatelitePasses.txt" -- Location of Satellite information file.
property tCalendar : "Satellite" -- Name of 'iCal' 'Calendar'.
set tText to paragraphs 5 through -1 of (read file tFile) -- Obtain specific lines (paragraphs) of Satellite information file data.
set {oASTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, " "} -- Configure delimiter.
tell application "iCal" -- Focus on 'iCal' commands.
tell calendar tCalendar -- Focus within the 'tCalendar' calendar.
repeat with i in tText -- Cycle through the obtain paragraphs of data.
tell i to set {tMonth, tDay, tYear, tTime, uHour, uMinute} to {first text item as number, second text item as number, third text item as number, fourth text item, fifth text item, sixth text item} -- Obtain specific information from within a paragraaph.
-- Create a new 'date' based on obtained Satellite data.
set tDate to (((tYear as string) & "-" & my handle_Number(tMonth)) & "-" & my handle_Number(tDay)) & "T" & tTime as «class isot» as date
-- Create a new 'iCal' event, including 'display alarm' setting.
set tEvent to make new event at end with properties {start date:tDate, end date:tDate, description:(uHour & "." & uMinute & " UTC")}
tell tEvent to make new display alarm at end with properties {trigger interval:-15}
end repeat
end tell
end tell
set AppleScript's text item delimiters to oASTID -- Reset delimiter.
on handle_Number(lNumber) -- Manage single digit date values.
if (lNumber < 10) then set lNumber to "0" & lNumber
return (lNumber as string)
end handle_Number
-- Code ends here --
You may have to edit the code, as per the delimiters you use / set within 'System Preferences' 'International's 'Formats' 'Dates' and 'Times' configuration panels.