Setting icon size and sorting in 10.9

Question

I asked this question in the os X forum. Maybe I can get an answer here.
The following worked in 10.8 but not in 10.9:
tell its icon view options
set icon size to 128
set shows icon preview to true
set arrangement to arranged by name
end tell
icon size is not set and the icons are not rarranged.
Apparently icon size is now read only. There must be a way to resize the icons.
Any ideas?

Answer 1

For example:
tell application "Finder"
    activate
    try
        set theName to name of Finder window 1
    on error
        return beep 1 -- no open Finder window
    end try
end tell
tell application "System Events" to tell process "Finder"
    tell menu 1 of menu bar item "View" of menu bar 1
        if exists menu item "Show View Options" then keystroke "j" using {command down}
    end tell
    repeat until exists (window 1 whose (title is theName) and (subrole is "AXSystemFloatingWindow"))
    end repeat
    tell window 1
        set value of slider 1 of group 1 to 56.0 -- 128 x 128
        tell checkbox "Show icon preview" of group 1
            if value is 0 then click
        end tell
        click pop up button 1
        keystroke "Name" & return -- arrange by name
        click button 1 -- close
    end tell
end tell
You should also have a look at Accessibility Preferences and GUI Scripting.
Message was edited by: Pierre L.