Shortening file names

Question

Hi all,
Does anyone know of a way to shorten file names to the same length?
Here is my problem...
I receive hundreds of InDesign files named with a common file naming convention. for example ABC001_jobtitle / ABC002_nextjob / ABC003_etc. I use a great software package to automate the majority of the tasks that I need to do in the pre-press environment, to speed up repetitive jobs to pre-flight and produce PDFs for proofing and printing.
I then end up with a folder of files: ABC001_jobtitle.PDF / ABC002_nextjob.PDF / ABC003_etc.PDF
What I need to be able to do with Apple script or Automator is to truncate the file names to the same length to remove all the characters AFTER the code so that I end up with files named ABC001 / ABC002 / ABC003 (but NOT renaming them as these codes have to match up to a code on a packing list elsewhere).
Is this possible? There are plenty of file renaming options within Automator but none (that I can see) that solve this problem.

Answer 1

I just happen to have an Automator Run AppleScript action that trims file names to the specified number of (leftmost or rightmost) characters and renames the file(s). See if this will do what you want (I recommend testing on some copies):
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 335px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into an Automator 'Run AppleScript' action">
on run {input, parameters}
-- rename Finder items (aliases), keeping the left/rightmost characters in the name
-- names with fewer characters are not trimmed - errors are skipped
-- input: a list of Finder items to rename
-- output: a list of the renamed Finder items
set output to {}
set SkippedItems to {} -- this will be a list of skipped items
-- prompt for the number of characters to keep and set the start and end limits
display dialog "Enter the number of characters to keep:" default answer "all" buttons {"Cancel", "LeftMost", "RightMost"}
set {TheButton, TheNumber} to {button returned, text returned} of the result
try
set TheNumber to TheNumber as integer
on error
set TheNumber to "all"
end try
if TheNumber is "all" then
set {TheStart, TheEnd} to {1, -1}
else
if TheButton is "LeftMost" then
set {TheStart, TheEnd} to {1, TheNumber}
else
set {TheStart, TheEnd} to {-TheNumber, -1}
end if
end if
tell application "Finder" to repeat with SomeItem in the input -- step through each item in the input
-- get the item name and extension
set {TheName, TheExtension} to {name of SomeItem, name extension of SomeItem}
set TheContainer to (container of SomeItem) as text -- the containing folder
if TheExtension is in {missing value, ""} then
set TheExtension to ""
else
set TheExtension to "." & TheExtension
end if
set TheName to text 1 thru -((length of TheExtension) + 1) of TheName -- the name part
try
set FileName to (text TheStart thru TheEnd of TheName) & TheExtension
set name of SomeItem to FileName
set the end of output to (TheContainer & the result) as alias
on error
set the end of SkippedItems to (return & TheName & TheExtension)
end try
end repeat
if SkippedItems is not {} then -- handle skipped items
set TheCount to (count SkippedItems) as text
display alert "Error with renaming files" message "The following " & TheCount & " items(s) were skipped:" & return & SkippedItems as text
end if
return the output -- pass the result(s) to the next action
end run
</pre>