Table(cast - invalid datatype problem

Question

Hi All,
Basic scenario:
PACKAGE
create or replace
PACKAGE C2_PAYMENT_DOC IS
TYPE bin_array IS TABLE OF NUMBER
INDEX BY BINARY_INTEGER;
FUNCTION test_fun(l_doc_id IN integer) RETURN bin_array;
PACKAGE_BODY
create or replace
package body C2_PAYMENT_DOC as
FUNCTION test_fun (l_doc_id IN integer) RETURN bin_array IS
l_gross bin_array;
begin
c2_purchase_invoice.get_inv_gross_amount(l_doc_id, l_gross(1));
return l_gross;
end;
END;
QUERY
select * from Table(Cast(c2_payment_doc.test_fun(1) As bin_array));
Result of the query is ORA-00902: invalid datatype
How can I make the select statement valid?
Thanks in advance,
Bartek

Answer 1

You can not use local collection types in SQL. You must create type bin_array as SQL nested table type. Also, depending on version you might not need to cast:
SQL> CREATE OR REPLACE
  2    TYPE bin_array
  3      AS TABLE OF NUMBER
  4  /
Type created.
SQL>  create or replace
  2   PACKAGE C2_PAYMENT_DOC IS
  3  FUNCTION test_fun(l_doc_id IN integer) RETURN bin_array;
  4  end;
  5  /
Package created.
SQL> create or replace
  2  package body C2_PAYMENT_DOC as
  3 
  4  FUNCTION test_fun (l_doc_id IN integer) RETURN bin_array IS
  5  l_gross bin_array := bin_array();
  6  begin
  7      l_gross.extend;
  8      l_gross(1) := l_doc_id;
  9  return l_gross;
10  end;
11  END;
12  /
Package body created.
SQL> select * from Table(Cast(c2_payment_doc.test_fun(1) As bin_array));
COLUMN_VALUE
           1
SQL> select * from Table(c2_payment_doc.test_fun(1))
  2  /
COLUMN_VALUE
           1
SQL> SY.