Table maintenance - autorization check on field level

Question

Dear all,
I generated a table maintenance view for a custom table via SE11 --> Utilities --> Table maintenance generator.
The table for which the maint. view was generated has a field bukrs. When a user enters a company code via table maintenance in SM30, i want to check if he has the right authorizations for that company code. This check, is this something i have to implement in the modification events or are there other alternatives?
Suppose i want a non-key field to be unique, is there a way to automatically check this, or has this to be done via implementation of the same events?
Kind regards,
J

Answer 1

Hi,
You can do it via the events.
There is one more alternative also.
Create a Z report with the plant as parameter or select-options.
Do an authorisation check on it using the authority object.
Then call the FM of SM30.
The FM of SM30 is 'VIEW_MAINTENANCE_CALL'
See the following code
PARAMETERS: y_p_lgnm TYPE lgnum.
DATA : y_v_string   TYPE string.
CONSTANTS: y_k_u        TYPE char1   VALUE 'U',
           y_k_x        TYPE char1   VALUE 'X',
           y_k_lgnum    TYPE char7   VALUE 'LGNUM',
           y_k_lgtyp    TYPE char5   VALUE 'LGTYP',
           y_k_eq       TYPE char2   VALUE 'EQ',
           y_k_viewname TYPE tabname VALUE 'YLOMANAGTROL'.
*                   INTERNAL TABLE DECLARATION.
DATA: y_i_seltab TYPE STANDARD TABLE OF vimsellist.
*                   WORKAREA DECLARATION.
DATA: y_wa_seltab TYPE vimsellist.
START-OF-SELECTION.
*authority check for warehouse number
  AUTHORITY-CHECK OBJECT 'L_LGNUM'
              ID y_k_lgnum FIELD y_p_lgnm
              ID y_k_lgtyp FIELD '*'.
  IF sy-subrc NE 0.
* user not authorised
    CONCATENATE y_p_lgnm text-003 INTO y_v_string SEPARATED BY space.
    MESSAGE s015(ylo1) WITH text-001
                            sy-uname
                            text-002
                            y_v_string.
  ELSE.
*Clear Internal Table
    CLEAR y_i_seltab.
    CLEAR y_wa_seltab.
*passing the selection parameters to the function module
*view_maintenance_call.
    y_wa_seltab-viewfield = y_k_lgnum.
    y_wa_seltab-value     = y_p_lgnm.
    y_wa_seltab-operator  = y_k_eq.
    APPEND y_wa_seltab TO y_i_seltab.
    CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
      EXPORTING
        action               = y_k_u
        view_name            = y_k_viewname
        show_selection_popup = y_k_x
      TABLES
        dba_sellist          = y_i_seltab.
  ENDIF.
In my case i had a table YLOMANAGTROL with field LGNUM.
So i put an authority check on LGNUM.
Regards,
Ankur Parab