Temporary table - yes or no?

Question

I need to create a list of reports on the fly. The user will be able to pick from the list (with check boxes) which reports he wants printed. The reports will also be created on the fly. It's a long list of reports (30+) and it is always different.
The main problem are the check boxes. I could just run a query to generate the report list and then have a continuous form based on the result, but I need the check boxes, so I need another field that is editable, hence the idea for a temp table.
I've been testing it and creating a temp table in the front end with SQL strings is straightforward enough. But deleting and re-creating the table adds a lot of bloat to the FE really quick (after just 10 to 20 times I'm looking at double the file size).
If I create a temp db as well, will there be any bloat to my FE at all? How would I go about this? Do I have to programmatically link and unlink the external temp table every time?
Or is there a more elegant solution to my problem that doesn't involve a temp table and that I hadn't thought of?

Answer 1

I could just run a query to generate the report list
In that case why not use a multi-select list box, whose RowSource is the query?  The user can then simply select whatever reports they want from the list.  It's then a simple matter to loop through the list box's ItemsSelected collection to print
the reports.
Another technique I've employed is to use the Description property of the as the visible column in the list box, which allows you to show meaningful descriptions rather than cryptic object names, with the report's name in a hidden bound column.  The following
is code for a form's module where all reports with Description properties are listed, but it would not be difficult to be able to include specific reports in the list by using a suitable naming convention for the report names:
Option Compare Database
Option Explicit
Private Sub cmdPreview_Click()
     Dim strReport As String
     Dim varItem As Variant
     With Me.lstReports
        If .ItemsSelected.Count > 0 Then
            For Each varItem In .ItemsSelected
                strReport = .ItemData(varItem)
                DoCmd.OpenReport strReport, View:=acViewPreview
            Next varItem
        End If
    End With
End Sub
Private Sub Form_Open(Cancel As Integer)
    On Error GoTo Err_Handler
    Const NODESCRIPTION = 3270
    Dim ctrl As Control
    Dim dbs As DAO.Database
    Dim ctr As DAO.Container
    Dim doc As DAO.Document
    Dim strReportname As String
    Dim strDescription As String
    Set dbs = CurrentDb
    Set ctr = dbs.Containers("Reports")
    Set ctrl = Me.lstReports
    ctrl.RowSourceType = "Value List"
    ctrl.ColumnWidths = "0cm;8cm"
    ctrl.BoundColumn = 1
    ctrl.ColumnCount = 2
    For Each doc In ctr.Documents
        strReportname = doc.Name
        On Error Resume Next
        strDescription = doc.Properties("Description")
        Select Case Err.Number
            Case 0
            ' no error
            Case NODESCRIPTION
            ' report has no description
            ' so ignore and go to next report
            GoTo EndLoop
            Case Else
            ' unknown error
            GoTo Err_Handler
        End Select
        Err.Clear
        On Error GoTo Err_Handler
        ctrl.AddItem strReportname & ";" & strDescription
EndLoop:
    Next doc
Exit_Here:
    Exit Sub
Err_Handler:
    MsgBox Err.Description, vbExclamation, "Error"
    Resume Exit_Here
End Sub
Ken Sheridan, Stafford, England