To get rid of Schema name in output using DBMS_METADATA

Question

Hi all,
Would someone be able to tell me how to get rid of the schema name output given by the below select stmt.
Query
Select Dbms_metadata.Get_ddl('FUNCTION','ACCOUNT_CODE')
from dual;
Result
CREATE OR REPLACE FUNCTION "GOINGLIVE"."ACCOUNT_CODE" (PTransCode VarChar2,.............
I checked for the documentation, but could manage to eliminate only storage clauses, tablespace etc. but not teh schema name.
Please provide your advise on this.
Thanks
- Sandeep

Answer 1

Which version are you on?
In 10g, you can use DBMS_METADATA.SET_REMAP_PARAM to get rid of schema name:
SQL> create table md_test(x int, y varchar2(10));
Table created.
SQL> declare
  2    l_ctx number;
  3    l_ctxt number;
  4    l_ddl sys.ku$_ddls;
  5  begin
  6    l_ctx := dbms_metadata.open('TABLE');
  7    dbms_metadata.set_filter(l_ctx, 'NAME', 'MD_TEST');
  8    l_ctxt := dbms_metadata.add_transform(l_ctx, 'MODIFY');
  9    dbms_metadata.set_remap_param(l_ctxt, 'REMAP_SCHEMA', user, null);
10    l_ctxt := dbms_metadata.add_transform(l_ctx, 'DDL');
11    dbms_metadata.set_transform_param(l_ctxt, 'SEGMENT_ATTRIBUTES', false);
12    l_ddl := dbms_metadata.fetch_ddl(l_ctx);
13    dbms_output.put_line(l_ddl(1).ddltext);
14    dbms_metadata.close(l_ctx);
15  end;
16  /
CREATE TABLE "MD_TEST"
   (    "X" NUMBER(*,0),
        "Y" VARCHAR2(10)
PL/SQL procedure successfully completed.In 9i, you have to resort to some manual tricks (with REPLACE, probably):
SQL> create table md_test(x int, y varchar2(10));
Table created.
SQL> declare
  2    l_ctx number;
  3    l_ctxt number;
  4    l_ddl sys.ku$_ddls;
  5  begin
  6    l_ctx := dbms_metadata.open('TABLE');
  7    dbms_metadata.set_filter(l_ctx, 'NAME', 'MD_TEST');
  8    l_ctxt := dbms_metadata.add_transform(l_ctx, 'DDL');
  9    dbms_metadata.set_transform_param(l_ctxt, 'SEGMENT_ATTRIBUTES', false);
10    l_ddl := dbms_metadata.fetch_ddl(l_ctx);
11    dbms_output.put_line(
12      replace(l_ddl(1).ddltext, '"' || user || '".'));
13    dbms_metadata.close(l_ctx);
14  end;
15  /
CREATE TABLE "MD_TEST"
   (    "X" NUMBER(*,0),
        "Y" VARCHAR2(10)
PL/SQL procedure successfully completed.
SQL> select * from v$version where rownum = 1;
BANNER
Oracle9i Enterprise Edition Release 9.2.0.6.0 - ProductionHope this helps,
Andrew.