Top of List event when using class cl_salv_hierseq_table

Question

Hi all,
  I am using above class to display Top of List .
I am to able to display one line at top using following :
gr_hierseq->set_top_of_list( lr_content ).
But i have to display 5 lines in top of list.
Please let me know how can this be achieved.
Thanks and Regards,
Taranam

Answer 1

Wow, that example did suck.  Sorry for that.  I have spent a little time revising the example program into such a form that you can easily see what you need to do.  SO here it is, hope it helps.   Pay close attention to the implementation of the on_top_of_page event handler method.
REPORT zsalv_demo_hierseq_form_events NO STANDARD PAGE HEADING.
TYPES: BEGIN OF g_type_s_master.
INCLUDE TYPE alv_chck.
TYPES:   expand   TYPE char01,
       END OF g_type_s_master,
       BEGIN OF g_type_s_slave.
INCLUDE TYPE alv_t_t2.
TYPES: END   OF g_type_s_slave.
TYPES: BEGIN OF g_type_s_test,
         amount      TYPE i,
         repid       TYPE syrepid,
         top_of_list TYPE i,
         end_of_list TYPE i,
       END OF g_type_s_test.
CONSTANTS: con_master TYPE lvc_fname VALUE 'ALV_CHCK',
           con_slave  TYPE lvc_fname VALUE 'ALV_T_T2'.
*... §5 Definition is later
CLASS lcl_handle_events_hierseq DEFINITION DEFERRED.
DATA: gs_test TYPE g_type_s_test.
DATA: gt_master TYPE STANDARD TABLE OF g_type_s_master,
      gt_slave  TYPE STANDARD TABLE OF alv_t_t2.
DATA: gr_hierseq TYPE REF TO cl_salv_hierseq_table.
*... §5 object for handling the events of cl_salv_table
DATA: gr_events_hierseq TYPE REF TO lcl_handle_events_hierseq.
*       CLASS lcl_handle_events DEFINITION
CLASS lcl_handle_events_hierseq DEFINITION.
  PUBLIC SECTION.
    METHODS:
      on_top_of_page FOR EVENT top_of_page OF cl_salv_events_hierseq
        IMPORTING r_top_of_page page table_index.
ENDCLASS.                    "lcl_handle_events DEFINITION
*       CLASS lcl_handle_events IMPLEMENTATION
CLASS lcl_handle_events_hierseq IMPLEMENTATION.
  METHOD on_top_of_page.
    DATA: lr_content TYPE REF TO cl_salv_form_element.
    DATA: lr_grid   TYPE REF TO cl_salv_form_layout_grid,
           lr_grid_1 TYPE REF TO cl_salv_form_layout_grid,
           lr_grid_2 TYPE REF TO cl_salv_form_layout_grid,
           lr_label  TYPE REF TO cl_salv_form_label,
           lr_text   TYPE REF TO cl_salv_form_text,
           l_text    TYPE string.
*... create a grid
    CREATE OBJECT lr_grid.
*... in the cell [1,1] create header information
    CONCATENATE 'TOP_OF_PAGE' text-h01 INTO l_text SEPARATED BY space.
    lr_grid->create_header_information(
      row    = 1
      column = 1
      text    = l_text
      tooltip = l_text ).
*... add a row to the grid -> row 2
    lr_grid->add_row( ).
*... in the cell [3,1] create a grid
    lr_grid_1 = lr_grid->create_grid(
                  row    = 3
                  column = 1 ).
*... in the cell [1,1] of the second grid create a label
    lr_label = lr_grid_1->create_label(
      row     = 1
      column  = 1
      text    = 'Number of Records'
      tooltip = 'Number of Records' ).
*... in the cell [1,2] of the second grid create a text
    lr_text = lr_grid_1->create_text(
      row     = 1
      column  = 2
      text    = gs_test-amount
      tooltip = gs_test-amount ).
    lr_label->set_label_for( lr_text ).
*... in the cell [2,1] of the second grid create a label
    lr_label = lr_grid_1->create_label(
      row    = 2
      column = 1
      text    = 'Output Tool'
      tooltip = 'Output Tool' ).
*... in the cell [2,2] of the second grid create a text
    lr_text = lr_grid_1->create_text(
      row    = 2
      column = 2
      text    = 'Seq List'
      tooltip = 'Seq List').
    lr_label->set_label_for( lr_text ).
*... in the cell [2,1] of the second grid create a label
    lr_label = lr_grid_1->create_label(
      row    = 3
      column = 1
      text    = 'Another Label'
      tooltip = 'Another Label' ).
*... in the cell [2,2] of the second grid create a text
    l_text = text-t15.
    lr_text = lr_grid_1->create_text(
      row    = 3
      column = 2
      text    = 'Another Text'
      tooltip = 'Another Text').
    lr_label->set_label_for( lr_text ).
*... content is the top grid
    lr_content = lr_grid.
*... set the content
    r_top_of_page->set_content( lr_content ).
  ENDMETHOD.                    "on_top_of_page
ENDCLASS.                    "lcl_handle_events IMPLEMENTATION
* SELECTION-SCREEN                                                     *
SELECTION-SCREEN BEGIN OF BLOCK gen WITH FRAME.
PARAMETERS:
p_amount TYPE i DEFAULT 30.
SELECTION-SCREEN END OF BLOCK gen.
* START-OF-SELECTION                                                   *
START-OF-SELECTION.
  gs_test-amount = p_amount.
  gs_test-repid = sy-repid.
*... §1 select data into global output table
  PERFORM select_data.
* END-OF-SELECTION                                                     *
END-OF-SELECTION.
  PERFORM display_hierseq.
*&      Form  select_data
* §1 select data into your global output table
FORM select_data.
  FIELD-SYMBOLS: <ls_master> TYPE g_type_s_master.
  DATA: lt_slave TYPE STANDARD TABLE OF g_type_s_slave.
  SELECT * FROM (con_master)
    INTO CORRESPONDING FIELDS OF TABLE gt_master
    UP TO gs_test-amount ROWS.                              "#EC *
  LOOP AT gt_master ASSIGNING <ls_master>.
    SELECT * FROM (con_slave) INTO CORRESPONDING FIELDS
               OF TABLE lt_slave
               UP TO gs_test-amount ROWS
               WHERE carrid EQ <ls_master>-carrid
                 AND connid EQ <ls_master>-connid.          "#EC *
    APPEND LINES OF lt_slave TO gt_slave.
  ENDLOOP.
ENDFORM.                    " select_data
*&      Form  display_hierseq
*       text
FORM display_hierseq.
  DATA:lt_binding TYPE salv_t_hierseq_binding,
       ls_binding TYPE salv_s_hierseq_binding.
  DATA:lr_functions TYPE REF TO cl_salv_functions_list.
  DATA:lr_columns TYPE REF TO cl_salv_columns_hierseq,
       lr_column  TYPE REF TO cl_salv_column_hierseq.
  DATA:lr_level TYPE REF TO cl_salv_hierseq_level.
*... create the binding information between master and slave
  ls_binding-master = 'MANDT'.
  ls_binding-slave  = 'MANDT'.
  APPEND ls_binding TO lt_binding.
  ls_binding-master = 'CARRID'.
  ls_binding-slave  = 'CARRID'.
  APPEND ls_binding TO lt_binding.
  ls_binding-master = 'CONNID'.
  ls_binding-slave  = 'CONNID'.
  APPEND ls_binding TO lt_binding.
*... §2 create an ALV hierseq table
  TRY.
      cl_salv_hierseq_table=>factory(
        EXPORTING
          t_binding_level1_level2 = lt_binding
        IMPORTING
          r_hierseq               = gr_hierseq
        CHANGING
          t_table_level1           = gt_master
          t_table_level2           = gt_slave ).
    CATCH cx_salv_data_error cx_salv_not_found.
  ENDTRY.
*... Functions
*... activate ALV generic Functions
  lr_functions = gr_hierseq->get_functions( ).
  lr_functions->set_all( abap_true ).
*... *** MASTER Settings ***
  TRY.
      lr_columns = gr_hierseq->get_columns( 1 ).
    CATCH cx_salv_not_found.
  ENDTRY.
*... set the columns technical
  TRY.
      lr_column ?= lr_columns->get_column( 'MANDT' ).
      lr_column->set_technical( if_salv_c_bool_sap=>true ).
    CATCH cx_salv_not_found.                            "#EC NO_HANDLER
  ENDTRY.
*... set expand column
  TRY.
      lr_columns->set_expand_column( 'EXPAND' ).
    CATCH cx_salv_data_error.                           "#EC NO_HANDLER
  ENDTRY.
*... set items expanded
  TRY.
      lr_level = gr_hierseq->get_level( 1 ).
    CATCH cx_salv_not_found.
  ENDTRY.
  lr_level->set_items_expanded( ).
*... *** GENERAL Settings ***
*... register to the events for top-of-page and end-of-page
  DATA: lr_events TYPE REF TO cl_salv_events_hierseq.
  lr_events = gr_hierseq->get_event( ).
  CREATE OBJECT gr_events_hierseq.
  SET HANDLER gr_events_hierseq->on_top_of_page FOR lr_events.
*... display the table
  gr_hierseq->display( ).
ENDFORM.                    "display_hierseq
REgards,
RIch Heilman