Traversing Directories

Question

Does anyone know if there is a way to Traverse Directories with AppleScript? I need to find folders within folders based on a number. For instance I need to find a folder named "8754 MyFolder", and this folder is within a containing folder. I did a search of the postings in the forum, but nothing is really what I'm looking for. If anyone knows where I can look at some example code I would appreciate it.

Answer 1

Why not script a Spotlight search instead?
Because a Spotlight search a) requires that Spotlight indexing is on, and b) will only show files that existed the last time the Spotlight index was updated.
Granted, this may not be a problem, and the faster execution time may be more advantageous than a real-time search, but they are things to consider.
As for the real-time question, there are two basic approaches to recursive searches in AppleScript.
One is a truly recursive script, the other is to leverage the Finder's 'entire contents' command:
tell application "Finder"
  set filesToFind to every folder of (entire contents of folder "Path:to:top:folder:" whose name is "8754 MyFolder"
  reveal filesToFind
end tell
The main drawback with this is that 'entire contents of...' can be very slow for large directory trees (don't try this on the top level of your disk, for example). For small directories it's not a big issue, though.
For a recursive script, use something like (untested):
on FindaFolder(folderName, folder2Search)
  global foundItems
  tell application "Finder"
    if exists folder folderName of folder folder2Search then
      copy (folder folderName of folder folder2Search ) as alias to end of foundItems
    end if
    -- now iterate through all the subfolders by calling yourself:
    repeat with eachFolder in (folders of folder2Search)
      my FindaFolder(folderName, eachFolder)
    end repeat
  end tell -- Finder
end FindaFolder
on run
  global foundItems
set foundItems to {}
  set startFolder to (choose folder with prompt "Please choose a folder to start the search in")
  FindAFolder("8754 My Folder", startFolder)
end run
The idea here is that given a folder name and a start point the script looks for that item in the starting folder. If found it adds it to the list of found items.
It then looks for any folder inside the startFolder and for each one it calls itself passing in each subdirectory in turn. The script takes care of keeping track of which folder you're in and will ensure that all folders are searched.
At the end of the script you'll have a list of all the folders that match the given name.