Trouble with a script that deletes event in iCal

Question

Used this script over the summer and it worked fine. Can't figure out the issue now, but it isn't working. Here is a few lines of the output I get and then the error I get is at the bottom. I'll post the full script at the bottom of this posting. Error # -1728??? File doesn;t exist?
Thanks,
dan
get summary of item 2 of every event of calendar "Untitled"
--> "Enviro C Lab Period 3-4"
get summary of item 2 of every event of calendar "Untitled"
--> "Enviro C Lab Period 3-4"
get description of item 2 of every event of calendar "Untitled"
--> missing value
get status of item 2 of every event of calendar "Untitled"
--> none
get start date of item 2 of every event of calendar "Untitled"
--> date "Tuesday, April 26, 2011 10:30:00 AM"
get summary of item 2 of every event of calendar "Untitled"
--> "Enviro C Lab Period 3-4"
get end date of item 2 of every event of calendar "Untitled"
--> date "Tuesday, April 26, 2011 11:55:00 AM"
get allday event of item 2 of every event of calendar "Untitled"
--> false
make new event at end of every event of calendar "Untitled" with properties {status:none, start date:date "Tuesday, April 26, 2011 10:30:00 AM", summary:"Enviro C Lab Period 3-4", end date:date "Tuesday, April 26, 2011 12:25:00 PM", allday event:false}
--> event id "AF27EFB6-3949-4977-A153-1EFE31FD8206" of calendar id "0EDA6DFD-52AD-4E7F-BC81-984CFF7D3F39"
delete item 2 of every event of calendar "Untitled"
--> error number -1728 from item 2 of every event of calendar "Untitled"
Result:
error "iCal got an error: Can’t get item 2 of every event of calendar \"Untitled\"." number -1728 from item 2 of every event of calendar "Untitled"
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into a HTML editor">
tell application "iCal"
repeat with theEvent in (events of calendar "Untitled")
set control to {}
set control to summary of theEvent
set AppleScript's text item delimiters to space
set theSummary to summary of theEvent
set textSummary to text items of theSummary
if the third item of textSummary is "Lab" then
if the fifth item of textSummary is "5-6" then
get theEvent
set theDescription to description of theEvent
set theStatus to status of theEvent
set theStartDate to (start date of theEvent) - 0.5 * hours
set theSummary to summary of theEvent
set theEndDate to end date of theEvent
set theAllDay to allday event of theEvent
set newEvent to (make new event at end of events of calendar "Untitled" with properties {status:theStatus, start date:theStartDate, summary:theSummary, end date:theEndDate, allday event:theAllDay})
set oldEvent to ""
set theEvent to oldEvent
get theEvent
delete theEvent
end if
if the fifth item of textSummary is "3-4" then
get theEvent
set theDescription to description of theEvent
set theStatus to status of theEvent
set theStartDate to start date of theEvent
set theSummary to summary of theEvent
set theEndDate to (end date of theEvent) + 0.5 * hours
set theAllDay to allday event of theEvent
set newEvent to (make new event at end of events of calendar "Untitled" with properties {status:theStatus, start date:theStartDate, summary:theSummary, end date:theEndDate, allday event:theAllDay})
delete theEvent
end if
end if
end repeat
end tell
</pre>

Answer 1

Hello
The posted event log indicates some inconsistent behaviour of iCal in referencing item 2 of every event. I.e., it could access it first and failed to do so after a new event is created. Scent of bug here. Or possibly inserting ugly small delay after event creation might let the script delete the newly created event...
Anyway, the 'by index' reference form of object must be used very carefully when object can be deleted or added dynamically.
Also I wish to add that it is not recommended to use an object specifier, that returns list of objects, as the base list for repeat statement, such as :
--CODE1
-- # not recommended
repeat with theEvent of (events of calendar "Untitled")
-- omitted
end repeat
--END OF CODE1
Instead, you'd better get the list first and use it, such as :
--CODE2
-- # recommended
repeat with theEvent of (get events of calendar "Untitled")
-- omitted
end repeat
--END OF CODE2
The reason is as follows.
In CODE1, the iterator is assigned as item k of events of calendar "Untitled", where k iterates from 1 to count of events of calendar "Untitled" at the time of loop entrance. The problem is that this list of events is dynamic list which may change when event is deleted or added, and consequently item k as iterator may no longer refer to the item k of the original collection of events.
In CODE2, the iterator is assigned as item k of a static list which is obtained by statement 'get events of calendar "Untitled" at the time of loop entrance. If the event object is returned in 'by ID' reference form (or any form other than that depends upon index in the container), item k as iterator is guaranteed to refer to the item k of the original collection of events whether or not collection changes.
Thus you may try something like this :
--SCRIPT
(* not tested *)
tell application "iCal"
tell calendar "Untitled"
repeat with theEvent in (get its events) -- # get the objects list
set theEvent to theEvent's contents -- # dereference each once
set AppleScript's text item delimiters to {space}
set textSummary to text items of summary of theEvent
set AppleScript's text item delimiters to {""} -- # reset astid
if item 3 of textSummary is "Lab" then
if item 5 of textSummary is "5-6" then
tell theEvent
set prop to {¬
start date:(its start date) - 0.5 * hours, ¬
end date:its end date, ¬
status:its status, ¬
summary:its summary, ¬
allday event:its allday event}
end tell
make new event at end of events with properties prop
delete theEvent
end if
if item 5 of textSummary is "3-4" then
tell theEvent
set prop to {¬
start date:its start date, ¬
end date:(its end date) + 0.5 * hours, ¬
status:its status, ¬
summary:its summary, ¬
allday event:its allday event}
end tell
make new event at end of events with properties prop
delete theEvent
end if
end if
end repeat
end tell
end tell
--END OF SCRIPT
Hope this may help,
H