Trying to pass a variable to fuzzy search

Question

I'm trying to write code like this:
   for x in 1 .. 6 loop
       v_searchword := listgetat(replace(p_searchphrase,',',' '),x,' ');
       for c1 in (select * from
                      (select score(1) as score, searchterms, suggestions from suggestions_table
                       where contains(searchterms,'fuzzy({'||v_searchword||'},,,weight)',1)>0
                       order by score desc)
                   where rownum < 10) loop                                    
        end loop;                  
   end loop;Someone passes in a long search phrase. I separate it into words and take up to the first 6. The set of words is looped through. Each word in turn is assigned to the v_searchword variable. I then do an Oracle Text fuzzy search on that word. The above code, however, gives me an Oracle Text parser error (DRG-50901: text query parser syntax error...).
I've modified the code so that the all-important line reads *where contains(searchterms,'fuzzy({v_searchword},,,weight)',1)>0*, and whilst that doesn't produce a syntax error, it doesn't produce any results, either! Words that I know will generate suggestions when I do a manual fuzzy search in plain SQL (such as "womman" and "tomartoe") don't generate anything in this case, because (I think) instead of searching for 'womman' or 'tomartoe' it's actually just searching for the word 'v_searchword' each time.
Could someone tell me how to write my code so that the correct word is passed into the contains function each time, please? It seems syntactically not very difficult, but I'm stumped!

Answer 1

If any value for v_searchword is null it would result in an invalid syntax, searching for {}. This would happen if there was no such element, such as no sixth word in a string of five words. You might also want to remove duplciate spaces from the string. Please see the demonstration below that first reproduces, then corrects the error simply by adding a condition that v_searchword is not null.
SCOTT@orcl_11g> create table suggestions_table
  2    (searchterms  varchar2 (30),
  3       suggestions  varchar2 (20))
  4  /
Table created.
SCOTT@orcl_11g> insert all
  2  into suggestions_table values ('woman', null)
  3  into suggestions_table values ('women', null)
  4  into suggestions_table values ('tomato', null)
  5  into suggestions_table values ('tomatoes', null)
  6  select * from dual
  7  /
4 rows created.
SCOTT@orcl_11g> create index your_index
  2  on suggestions_table (searchterms)
  3  indextype is ctxsys.context
  4  /
Index created.
SCOTT@orcl_11g> CREATE OR REPLACE FUNCTION listgetat
  2       (p_string    VARCHAR2,
  3        p_element   INTEGER,
  4        p_separator VARCHAR2 DEFAULT ' ')
  5       RETURN          VARCHAR2
  6  AS
  7    v_string      VARCHAR2 (32767);
  8  BEGIN
  9    -- ensure there are starting and ending separators:
10    v_string := p_separator || p_string || p_separator;
11    -- remove all double separators:
12    WHILE INSTR (v_string, p_separator || p_separator) > 0 LOOP
13        v_string := REPLACE (v_string, p_separator || p_separator, p_separator);
14    END LOOP;
15    -- check if element exists:
16    IF LENGTH (v_string) - LENGTH (REPLACE (v_string, p_separator, '')) >
17         LENGTH (p_separator) * p_element
18    THEN
19        v_string := SUBSTR (v_string,
20                      INSTR (v_string, p_separator, 1, p_element)
21                      + LENGTH (p_separator));
22        RETURN SUBSTR (v_string, 1, INSTR (v_string, p_separator) - 1);
23    ELSE
24        RETURN NULL;
25    END IF;
26  END listgetat;
27  /
Function created.
SCOTT@orcl_11g> -- reproduction of error:
SCOTT@orcl_11g> create or replace procedure test_proc
  2    (p_searchphrase     in varchar2)
  3  as
  4    v_searchword    varchar2 (100);
  5  begin
  6       for x in 1 .. 6 loop
  7           v_searchword := listgetat(replace(p_searchphrase,',',' '),x,' ');
  8 
  9           for c1 in (select * from
10                    (select score(1) as score, searchterms, suggestions from suggestions_table
11                     where contains(searchterms,'fuzzy({'||v_searchword||'},,,weight)',1)>0
12                     order by score desc)
13                 where rownum < 10) loop
14              dbms_output.put_line
15             (lpad (c1.score, 3) || ' ' ||
16              rpad (c1.searchterms, 30) || ' ' ||
17              v_searchword);
18            end loop;
19       end loop;
20  end test_proc;
21  /
Procedure created.
SCOTT@orcl_11g> show errors
No errors.
SCOTT@orcl_11g> exec test_proc ('womman,and,tomartoe')
38 woman                          womman
25 women                          womman
29 tomato                         tomartoe
26 tomatoes                       tomartoe
BEGIN test_proc ('womman,and,tomartoe'); END;
ERROR at line 1:
ORA-29902: error in executing ODCIIndexStart() routine
ORA-20000: Oracle Text error:
DRG-50901: text query parser syntax error on line 1, column 8
ORA-06512: at "SCOTT.TEST_PROC", line 9
ORA-06512: at line 1
SCOTT@orcl_11g> -- correction of error:
SCOTT@orcl_11g> create or replace procedure test_proc
  2    (p_searchphrase     in varchar2)
  3  as
  4    v_searchword    varchar2 (100);
  5  begin
  6       for x in 1 .. 6 loop
  7           v_searchword := listgetat(replace(p_searchphrase,',',' '),x,' ');
  8           -- check if xth word exists:
  9           if v_searchword is not null then
10             for c1 in (select * from
11                      (select score(1) as score, searchterms, suggestions from suggestions_table
12                       where contains(searchterms,'fuzzy({'||v_searchword||'},,,weight)',1)>0
13                       order by score desc)
14                   where rownum < 10) loop
15             dbms_output.put_line
16               (lpad (c1.score, 3) || ' ' ||
17                rpad (c1.searchterms, 30) || ' ' ||
18                v_searchword);
19              end loop;
20           end if;
21       end loop;
22  end test_proc;
23  /
Procedure created.
SCOTT@orcl_11g> show errors
No errors.
SCOTT@orcl_11g> exec test_proc ('womman,and,tomartoe')
38 woman                          womman
25 women                          womman
29 tomato                         tomartoe
26 tomatoes                       tomartoe
PL/SQL procedure successfully completed.
SCOTT@orcl_11g>