Urgent: Calling web service from PL/SQl fails with XML parsing

Question

Hi,
I am trying to call a web service from PL/SQL (using SOAP protocol and UTL_HTTP built in Package).I am using Oracle 9i .I am calling from pl/sql block invoking web service method created in java.
I am getting the below response object as a SOAP protocol, but i couldn't able to parse the SOAP.
Could you please provide the values of FirstName, LastName and ErrorDescription
declare
request_env varchar2(32767);
v_xml XMLTYPE;
l_user_first_name varchar2(100);
l_user_last_name varchar2(100);
l_error_value varchar2(100);
begin
response_env:='<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
<soapenv:Body>
<UserInfoObjResponse xmlns:axis2ns1="http://www.test.com/services">
<axis2ns1:FirstName >First Name Output</axis2ns1:FirstName>
<axis2ns1:LastName>Last Name Output</axis2ns1:LastName>
<axis2ns1:ErrorDescription />
</UserInfoObjResponse>
</soapenv:Body>
</soapenv:Envelope>';
dbms_output.put_line('Length of Request:' || length(response_env));
dbms_output.put_line ('Request: ' || response_env);
v_xml := XMLTYPE(response_env);
-- SELECT EXTRACTVALUE(v_xml, '//UserInfoObjResponse/FirstName') INTO l_user_fast_name varchar2(100); FROM DUAL;
dbms_output.put_line ('l_user_first_name: ' || l_user_first_name);
dbms_output.put_line ('l_user_last_name : ' || l_user_last_name);
dbms_output.put_line ('l_error_value: ' || l_error_value);
end;

Answer 1

In Oracle 9i:
SQL> declare
  2    response_env varchar2(32767);
  3    v_xml XMLTYPE;
  4    l_user_first_name varchar2(100);
  5    l_user_last_name varchar2(100);
  6    l_error_value varchar2(100);
  7  begin
  8    response_env:='<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
  9                     <soapenv:Body>
10                       <UserInfoObjResponse xmlns:axis2ns1="http://www.test.com/services">
11                         <axis2ns1:FirstName >First Name Output</axis2ns1:FirstName>
12                         <axis2ns1:LastName>Last Name Output</axis2ns1:LastName>
13                         <axis2ns1:ErrorDescription />
14                       </UserInfoObjResponse>
15                     </soapenv:Body>
16                   </soapenv:Envelope>';
17
18    dbms_output.put_line('Length of Request:' || length(response_env));
19  --  dbms_output.put_line ('Request: ' || response_env);
20
21    v_xml := XMLTYPE(response_env);
22
23    select EXTRACTVALUE(v_xml,'/*:Envelope/*:Body/*:UserInfoObjResponse/*:FirstName/text()') first_name,
24           EXTRACTVALUE(v_xml,'/*:Envelope/*:Body/*:UserInfoObjResponse/*:LastName/text()') last_name,
25           EXTRACTVALUE(v_xml,'/*:Envelope/*:Body/*:UserInfoObjResponse/*:ErrorDescription/text()') error_description
26      into l_user_first_name, l_user_last_name, l_error_value
27      from dual;
28
29    dbms_output.put_line ('l_user_first_name: ' || l_user_first_name);
30    dbms_output.put_line ('l_user_last_name : ' || l_user_last_name);
31    dbms_output.put_line ('l_error_value: ' || l_error_value);
32  end;
33  /
Length of Request:530
l_user_first_name: First Name Output
l_user_last_name : Last Name Output
l_error_value:
PL/SQL procedure successfully completed.In Oracle 10g:
SQL> declare
  2    response_env varchar2(32767);
  3    v_xml XMLTYPE;
  4    l_user_first_name varchar2(100);
  5    l_user_last_name varchar2(100);
  6    l_error_value varchar2(100);
  7  begin
  8    response_env:='<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/">
  9                     <soapenv:Body>
10                       <UserInfoObjResponse xmlns:axis2ns1="http://www.test.com/services">
11                         <axis2ns1:FirstName >First Name Output</axis2ns1:FirstName>
12                         <axis2ns1:LastName>Last Name Output</axis2ns1:LastName>
13                         <axis2ns1:ErrorDescription />
14                       </UserInfoObjResponse>
15                     </soapenv:Body>
16                   </soapenv:Envelope>';
17
18    dbms_output.put_line('Length of Request:' || length(response_env));
19  --  dbms_output.put_line ('Request: ' || response_env);
20
21    v_xml := XMLTYPE(response_env);
22
23    select r.*
24      into l_user_first_name, l_user_last_name, l_error_value
25    from XMLTABLE('/' PASSING v_xml
26                  COLUMNS
27                  first_name varchar2(30) PATH '/*:Envelope/*:Body/*:UserInfoObjResponse/*:FirstName/text()',
28                  last_name varchar2(30) PATH '/*:Envelope/*:Body/*:UserInfoObjResponse/*:LastName/text()',
29                  error_description varchar2(30) PATH '/*:Envelope/*:Body/*:UserInfoObjResponse/*:ErrorDescrition/text()'
30                  ) r;
31
32    dbms_output.put_line ('l_user_first_name: ' || l_user_first_name);
33    dbms_output.put_line ('l_user_last_name : ' || l_user_last_name);
34    dbms_output.put_line ('l_error_value: ' || l_error_value);
35  end;
36  /
Length of Request:530
l_user_first_name: First Name Output
l_user_last_name : Last Name Output
l_error_value:
PL/SQL procedure successfully completed.Max
http://oracleitalia.wordpress.com
Edited by: Massimo Ruocchio on Feb 14, 2010 11:55 PM
Added the first one.