Urgent: Finding sessions in SQL server 2000

Question

Hi,
Can you help me how to find out sessions in SQL Server 2000.
Also is there any way to see the outstanding sessions for a database?
Thanks in advance,
Vasu.

Answer 1

You can do this graphically in Enterprise Manager, or you can use this script:
SET NOCOUNT ON
create table #ProcCheck(
 Status varchar(50) ,
 SPID int ,
 CPU int ,
 Pys_IO int ,
 WaitTime int ,
 BlockSPID int ,
 HostName varchar(36) ,
 ProgName varchar(100) ,
 NTUser varchar(50) ,
 LoginTime datetime ,
 LastBatch datetime ,
 OpenTrans int ,
 LastCmd varchar(4000))
create table #ProcInfo(
 EventType varchar(100) ,
 Parameters int ,
 EventInfo varchar(7000)
INSERT INTO #ProcCheck(Status, SPID, CPU, Pys_IO, WaitTime, BlockSPID, HostName, ProgName, NTUSer, LoginTime, LastBatch, OpenTrans)
SELECT status, SPID, CPU, Physical_IO, WaitTime, Blocked, SUBSTRING(HostName, 1, 36), SUBSTRING(Program_Name, 1, 100), SUBSTRING(nt_username, 1, 50), Login_Time, Last_Batch, Open_Tran
FROM master..sysprocesses
where (blocked > 0
or spid in (select blocked from master..sysprocesses (NOLOCK) where blocked > 0)
or open_tran > 0)
and SPID <> @@SPID
declare @spid int ,
 @cmd varchar(7000)
declare Procs cursor fast_forward for
SELECT SPID FROM #ProcCheck
OPEN Procs
FETCH NEXT FROM Procs INTO @SPID
WHILE @@FETCH_STATUS = 0
 BEGIN
 SET @cmd = 'DBCC INPUTBUFFER(' + CONVERT(varchar, @SPID) + ')'
 INSERT INTO #ProcInfo
 EXEC(@cmd)
 SELECT @cmd = EventInfo
 FROM #ProcInfo
 DELETE FROM #ProcInfo
 UPDATE #ProcCheck
 SET LastCmd = SUBSTRING(@cmd, 1, 500)
 WHERE SPID = @SPID
 FETCH NEXT FROM Procs INTO @SPID
 END
CLOSE Procs
DEALLOCATE Procs
SELECT * FROM #ProcCheck 
DROP TABLE #ProcCheck
DROP TABLE #ProcInfo