Using more than one sysrefcursors in a procedure.

Question

Hi,
can we use 2 -3 sysrefcursors to get 3 different resultset out from a single plsql procedure for particular page on front end? each sysrefcursor with with different select?
I have to fetch resultset and fire a query for searching data, finding aggregate on few fields and one more query for finding aggregates.
can we do this?
Could you please reply this with simple example?
Thanks a lot.

Answer 1

>
can we use 2 -3 sysrefcursors to get 3 different resultset out from a single plsql procedure for particular page on front end? each sysrefcursor with with different select?
I have to fetch resultset and fire a query for searching data, finding aggregate on few fields and one more query for finding aggregates.
can we do this?
Could you please reply this with simple example?
>
You can pretty use as many as you like. Just define them as OUT parameters (or IN OUT) and open them all before the procedure returns.
I've seen 50 used in one procedure at a large financial institution. Of course they had performance problems related to that.
Keep in mind that every cursor you open causes Oracle to perform ALL of the parsing and read consistency work needed to service ALL of the cursors. So if you open three cursors but the user only uses one of them the work for the other two is wasted and can contribute to performance issues.
Here is an example using one cursor. You can add more to expand the example.
CREATE OR REPLACE TYPE SCOTT.local_type IS OBJECT (
    empno   NUMBER(4),
    ename   VARCHAR2(10));
CREATE OR REPLACE TYPE SCOTT.local_tab_type IS TABLE OF local_type;
CREATE OR REPLACE PACKAGE SCOTT.test_refcursor_pkg
AS
    TYPE my_ref_cursor IS REF CURSOR;
     -- add more cursors as OUT parameters
     PROCEDURE   test_proc(p_ref_cur_out OUT test_refcursor_pkg.my_ref_cursor);
END test_refcursor_pkg;
CREATE OR REPLACE PACKAGE BODY SCOTT.test_refcursor_pkg
AS
     PROCEDURE  test_proc(p_ref_cur_out OUT test_refcursor_pkg.my_ref_cursor)
     AS
        l_recs local_tab_type;
     BEGIN
         -- Get the records to modify individually.
         SELECT local_type(empno, ename) BULK COLLECT INTO l_recs
         FROM EMP;
         -- Perform some complex calculation for each row.
         FOR i IN l_recs.FIRST .. l_recs.LAST
         LOOP
             DBMS_OUTPUT.PUT_LINE(l_recs(i).ename);
         END LOOP;
         -- Put the modified records back into the ref cursor for output.  
         OPEN p_ref_cur_out FOR
         SELECT * from TABLE(l_recs);      
         -- open more ref cursors here before returning
     END test_proc;
END;
SET SERVEROUTPUT ON SIZE 1000000
DECLARE
  l_cursor  test_refcursor_pkg.my_ref_cursor;
  l_ename   emp.ename%TYPE;
  l_empno   emp.empno%TYPE;
BEGIN
  test_refcursor_pkg.test_proc (l_cursor);
  LOOP
    FETCH l_cursor
    INTO  l_empno, l_ename;
    EXIT WHEN l_cursor%NOTFOUND;
    DBMS_OUTPUT.PUT_LINE(l_ename || ' | ' || l_empno);
  END LOOP;
  CLOSE l_cursor;
END;
/