XSLT does not put element into output

Question

HI Gentlemen,
I have the following code segment, reflecting a 4-level hierarchical structure. Only the first two levels are guaranteed to be present; the last two are optional (if pe:scheinuntergruppen_liste is present, then at least one pe:scheinuntergruppe must be present, too.)
          <xsl:for-each select="pe:bedingung/pe:scheinarten_liste">
            <xsl:variable name="span1" select="count(descendant::pe:scheinuntergruppe)"/>
            <xsl:variable name="pos1" select="position()"/>
            <xsl:for-each select="pe:scheinart">
              <xsl:variable name="span2" select="count(descendant::pe:scheinuntergruppe)"/>
              <xsl:variable name="pos2" select="position()"/>
              <xsl:for-each select="pe:scheinuntergruppen_liste">
                <xsl:variable name="span3" select="count(descendant::pe:scheinuntergruppe)"/>
                <xsl:variable name="pos3" select="position()"/>
                <xsl:for-each select="pe:scheinuntergruppe"> 
                  <tr>
                    <xsl:if test="position()=1">
                      <xsl:if test="$pos3=1">
                        <xsl:if test="$pos2=1">
                          <td rowspan="{$span1}"><xsl:value-of select="../../../@V"/></td>
                        </xsl:if>
                        <td rowspan="{$span2}"><xsl:value-of select="../../@V"/></td>
                      </xsl:if>
                      <td rowspan="{$span3}"><xsl:value-of select="../@V"/></td>
                    </xsl:if>
                    <td><xsl:value-of select="@V"/></td>
                  </tr>
                </xsl:for-each>
              </xsl:for-each>
            </xsl:for-each>
          </xsl:for-each>Since a tabular representation is not working for missing elements, I tried to insert them under pe:scheinart., using the following template:
<xsl:template name="fill" match="pe:scheinart">
  <xsl:if test="not(./pe:scheinuntergruppen_liste)">
    <xsl:element name="pe:scheinuntergruppen_liste" use-attribute-sets="V">
      <xsl:attribute name="V">
        <xsl:value-of select="XX"/>
      </xsl:attribute>
      <xsl:element name="pe:scheinuntergruppe" use-attribute-sets="V">
        <xsl:attribute name="V">
          <xsl:value-of select="YY"/>
        </xsl:attribute>
      </xsl:element>
    </xsl:element>
  </xsl:if>
</xsl:template>This should be executed once for each pe:scheinart node inserting a child and a grandchild node. The template is called by
<xsl:apply-templates select="pe:scheinart"/>Unfortunately, it does nothing; the rowspan values are not affected. Could anyone give me a hint, where I am wrong?
Thanks, kind regards,
Miklos HERBOLY
Edited by: mh**** on Aug 11, 2011 10:31 AM

Answer 1

[0]
Since a tabular representation is not working for missing elements, I tried to insert them under pe:scheinart., using the following template...I have'nt read into the template... but if you meant to setup a template within the same xslt document (not in cascade) as pre-processing of the xml document, then I doubt it would do as a matter of conceptual approach.
[1] In fact, there is no reason the possibility of missing element pe:scheinuntergruppen_liste and/or pe:scheinuntergruppe cannot be handled by the logic. It can and I would like to show you a realization to that effect.
[1.1] One crucial point is to count correctly the needed rows (tr) disregard whether one or both of the elements be absent or not. The number of rows to span for both pe:scheinarten_liste and pe:scheinart individually is to calculate how many ending tree node amongst the four named elements (in the sense of element of the descendant of them contains no more elements of the four named elements.) That calculation is reflected in the demo below at span1, span2 variables following your notations.
[1.2] And then, once the elements being absent, one has to insert something to avoid the html table collaping the cell --- use border="1" for inspection purpose, if you so desired. That's quite necessary as far as the html table is concerned. It is usually a non-breakable space ( ). That I do as well.
[1.3] There are two degenerate cases: pe:scheinuntergruppen_liste absent and pe:scheinuntergruppen_liste present but pe:scheinuntergruppe absent. It results in four branching out (reflecting in the use of xsl:choose).
[2] This is a demo realization containing the 4 levels of for-each which should behaviour properly with enough generality.
<xsl:for-each select="pe:bedingung/pe:scheinarten_liste">
  <xsl:variable name="span1" select="count(descendant-or-self::*[count(descendant::*)=0])" />
  <xsl:variable name="pos1" select="position()"/>
  <xsl:for-each select="pe:scheinart">
    <xsl:variable name="span2" select="count(descendant-or-self::*[count(descendant::*)=0])" />
    <xsl:variable name="pos2" select="position()"/>
    <xsl:choose>
      <xsl:when test="count(pe:scheinuntergruppen_liste)=0">
        <tr>
          <xsl:if test="$pos2=1">
            <td rowspan="{$span1}"><xsl:value-of select="../@V" /></td>
          </xsl:if>
          <td><xsl:value-of select="@V" /></td>
          <td><xsl:value-of select="'&#xa0;'" /></td>
          <td><xsl:value-of select="'&#xa0;'" /></td>
        </tr>
      </xsl:when>
      <xsl:otherwise>
        <xsl:for-each select="pe:scheinuntergruppen_liste">
          <xsl:variable name="span3" select="count(descendant-or-self::*[count(descendant::*)=0])" />
          <xsl:variable name="pos3" select="position()" />
          <xsl:choose>
            <xsl:when test="count(pe:scheinuntergruppe)=0">
              <tr>
                <xsl:if test="$pos3=1">
                  <xsl:if test="$pos2=1">
                    <td rowspan="{$span1}"><xsl:value-of select="../../@V" /></td>
                  </xsl:if>
                  <td rowspan="{$span2}"><xsl:value-of select="../@V" /></td>
               </xsl:if>
               <td><xsl:value-of select="@V" /></td>
               <td><xsl:value-of select="'&#xa0;'" /></td>
             </tr>
           </xsl:when>
           <xsl:otherwise>
             <xsl:for-each select="pe:scheinuntergruppe">
               <xsl:variable name="pos4" select="position()" />
               <tr>
                 <xsl:if test="$pos4=1">
                   <xsl:if test="$pos3=1">
                     <xsl:if test="$pos2=1">
                       <td rowspan="{$span1}"><xsl:value-of select="../../../@V" /></td>
                     </xsl:if>
                     <td rowspan="{$span2}"><xsl:value-of select="../../@V" /></td>
                   </xsl:if>
                   <td rowspan="{$span3}"><xsl:value-of select="../@V" /></td>
                 </xsl:if>
                 <td><xsl:value-of select="./@V" /></td>
               </tr>
             </xsl:for-each>
           </xsl:otherwise>
         </xsl:choose>
       </xsl:for-each>
     </xsl:otherwise>
   </xsl:choose>
  </xsl:for-each>
</xsl:for-each>