Need Help Creating A Script For Labeling Finder Files from Indesign

Question

Trying to figure out a way to have a script run in InDesign CS4 that will label a text file RED after it's been imported into InDesign.
We import numerous text files into an InDesign template. Since there are several text files in the same folder, we need to somehow "mark off" that we've imported that file and move to the next one to import. I have created an Automator "service" with a keyboard shortcut to label the file Red in the finder but it would be great if we could have this happen automatically after we import into InDesign.
If we import the wrong text file by accident and it gets missed in proofing, it costs us a lot of money with the printer.
Thanks for any ideas.
Jim

Answer 1

You know, these guys are absolutely right in their assessment that this is a good place for event listeners. You would need three scripts though.
Something like...
Label Placed Files Red.scpt
--Put this in a folder called IDScripts in your Documents folder
main(evt)
on main(myEvent)
tell application "Adobe InDesign CS4"
set placedFilePath to full name of myEvent
set placedFilePath to placedFilePath as alias
end tell
tell application "Finder"
--This turns the file color red
set label index of placedFilePath to 2
end tell
end main
And these two are in your InDesign scripts folder...
Start Placed File Finder Labelling.scpt
--Installs the afterImport event listener for the Label Placed Files Red script.
tell application "Adobe InDesign CS4"
set myHandler to path to documents folder
set myScriptName to "Label Placed Files Red.scpt"
set myHandler to "" & myHandler & "IDScripts:" & myScriptName
try
set myHandler to myHandler as alias
make event listener with properties {event type:"afterImport", handler:myHandler, captures:true}
display dialog "Placed File Labelling: ON" buttons "OK" default button 1
on error
display dialog "ERROR: Couldn't start handler!" & return & return & "Make sure the \"" & myScriptName & "\" script in a folder called \"IDScripts\" inside your Documents folder and try again" buttons "OK" default button 1
end try
end tell
Stop Placed File Finder Labelling.scpt
--Removes the afterImport event listener for the Label Placed Files Red script.
tell application "Adobe InDesign CS4"
set myHandler to path to documents folder
set myScriptName to "Label Placed Files Red.scpt"
set myHandler to "" & myHandler & "IDScripts:" & myScriptName
set myHandler to myHandler as alias
set myResult to remove event listener event type "afterImport" handler myHandler with captures
if (myResult is false) then
display dialog "ERROR: Couldn't remove handler! Are you sure it is active?" & return & return & "If so, please quit and relaunch InDesign to get rid of it." buttons "OK" default button 1
else
display dialog "Placed File Labelling: OFF" buttons "OK" default button 1
end if
end tell