Pop up menu reference help

Question

I am new to numbers and am trying to develop a logbook to track my flight time.  I need to be able to keep running totals of total time and by aircra type.  I have a number of questions, but I think this is the one to start with:
i would like to have a pop-up menu (drop down list) to be able to select which aircraft type in a cell.  I want the pop-up menu items to be based on what is typed into a different cell (reference cell).
i would like whatever txt is typed in a range of cells to be what is available as a pop up in a different range of cells.
In table 1 if I type C182t in cell b1 thru b10, I want C182t to be available as a pop-up or drop down menu in table2, f2-f200.
i.e.
table 1, b1 I type C182t
table 2 (f2 thru f200) have C182t in pop up/dropdown
Next In table 1, b2 I type PA28R
table2 (F2 thru f200) now have C182t and PA28R as choices
and so on....
thanks in advance nce for the help
anthony

Answer 1

In table 1 if I type C182t in cell b1 thru b10, I want C182t to be available as a pop-up or drop down menu in table2, f2-f200
Inspired by quinn's script, here is a specific AppleScript solution to this problem.
Given a first table named 'Aircraft Types', with C182 in B1 and PA28r in B2:
C182t
PA28r
And a 'Table 2' like this:
A
B
C
D
E
F
PA28r
C182t
PA30
PA28r
PA30
C182t
You can copy-paste this this script into Script Editor and run it to populate column F with Pop-Up Menu containing the choices from 'Table 1'.  Whenever you add an item to 'Table 1' just one-click will update the Pop-Ups.  (It's not fully automatic the way it can be in Excel, but it's just one click. No need to get involved in the details of the script... unless you want to.).
--change to match where popup values are listed:
property source : {sht:"Sheet 1", tbl:"Aircraft Types", col:"B"}
--change to match range where you want the Popup Menu cells:
property target : {sht:"Sheet 1", tbl:"Table 2", col:"F"}
property guiDelay : 0.15 -- may need to increase on your machine
tell application "Numbers" to tell front document
  tell sheet (source's sht) to tell table (source's tbl)
  set the selection range to first cell -- put focus on table to sort
  sort by column (source's col) direction ascending -- omit if want orginal order
  set popSrcRng to my makeBodyRng(source's sht, source's tbl, source's col)
  set popSrcRng's format to pop up menu
  set selection range to popSrcRng's last cell --put 'first cell' if want default to be first value,etc.
  my copyPaste("c")
  set column (source's col)'s format to text -- restore format so can add new items as needed
  end tell
  tell sheet (target's sht) to tell table (target's tbl)
  set range (target's col)'s format to text -- clear any existing popups
  set selection range to my makeBodyRng(target's sht, target's tbl, target's col)
  my copyPaste("v")
  end tell
end tell
to makeBodyRng(theSht, theTable, theCol) -- builds the range for just the body cells in a column
  tell application "Numbers" to tell front document's sheet theSht's table theTable
  set theRange to range ((column theCol's cell (header row count + 1)'s name) & ¬
  ":" & (column theCol's cell (row count - footer row count)'s name))
  end tell
end makeBodyRng
to copyPaste(k)
  activate application "Numbers"
  delay guiDelay --gives user interface a chance to catch up
  tell application "System Events" to keystroke k using command down
end copyPaste
Be sure to change the values in the property statements (within the quotes) if your tables have different names, are on a different sheet, or if you want the Pop-Ups in a different column.  And, of course, make sure it runs the way you want on a test document before using it with your real data.
SG
P.S.  quinn, note that you can get AppleScript to indent properly on the forum by clicking 'html' and removing the minus sign wherever you see something with this pattern:  text-indent: -39.3px.  (The number will vary; just delete the - wherever you see it). Then click 'Show Full Editor' upper right to return to the normal view. A little bit of a pain, but it goes quickly, and does the trick until they fix whatever bug is inserting those minus signs.