Abap 00 and HR SAP classes

Question

Hi,
I am developer and beginner in HR
I found many classes for HR in the repository. I think, the most interesting class for me is
CL_HRBAS_PLAIN_INFOTYPE_ACCESS
because I need to read single infotypes and not all records. The problem is: I found no examples for this class.
Can someone help me further?
Thank you!
Have a nice time!
Patrizia

Answer 1

Hi Patrizia,
I know this is a bit late but hopefully it still helps.
In short you would be better to use one of the available function modules (e.g. HR_READ_INFOTYPE, HR_INFOTYPE_OPERATION) or to use the PNP logical database statements (GET PERNR, RP_PROVIDE) as Jamie alluded to.
For detailed info on how the HR Infotypes have been implemented using ABAP Objects  you can refer to this SAP Library content which explains the decoupled infotype framework
<a href="http://help.sap.com/saphelp_erp2005vp/helpdata/en/43/a503b963161bbfe10000000a1553f7/frameset.htm">Decoupling Infotypes</a>
For understanding why the HR Infotypes were decoupled you can refer to this SAP Library content introducing concurrent employment:
<a href="http://help.sap.com/saphelp_erp2005vp/helpdata/en/16/08c73c52aacf5be10000000a114084/frameset.htm">Infotype Framework for Concurrent Employment</a>
If you still really want to use ABAP Objects to perform this action then please ignore class CL_HRBAS_PLAIN_INFOTYPE_ACCESS since that is used for PD infotypes only. You can refer to the example code I'm pasting below for reading a PA infotype:
*& Report  zptest0002
*& Test program to use the ITF to read infotype 0002 for a person
REPORT  zptest0002.
* data declarations
DATA: prelp_tab       TYPE hrpad_prelp_tab.
DATA: a_read_infotype TYPE REF TO if_hrpa_read_infotype.
DATA: data_exists     TYPE boole_d.
DATA: i_pa0002      TYPE TABLE OF p0002,
      wa_pa0002 LIKE p0002.
DATA t_pernr TYPE pernr-pernr.
* supply existing pernr for testing or implement a parameter
t_pernr = 2.
* initiate the infotype framework
CALL METHOD cl_hrpa_masterdata_factory=>get_read_infotype
  IMPORTING
    read_infotype = a_read_infotype.
CLEAR i_pa0002.
REFRESH i_pa0002.
* perform the read operation
CALL METHOD a_read_infotype->read
  EXPORTING
    tclas         = 'A'
    pernr         = t_pernr
    infty         = '0002'
    subty         = space
    objps         = space
    sprps         = if_hrpa_read_infotype=>unlocked
    begda         = if_hrpa_read_infotype=>low_date
    endda         = if_hrpa_read_infotype=>high_date
    no_auth_check = 'X'
  IMPORTING
    infotype_tab  = prelp_tab
    data_exists   = data_exists.
* cast prelp return value into infotype structure
CALL METHOD cl_hr_pnnnn_type_cast=>prelp_to_pnnnn_tab
  EXPORTING
    prelp_tab = prelp_tab
  IMPORTING
    pnnnn_tab = i_pa0002.
* loop to process or get first record
CLEAR wa_pa0002.
READ TABLE i_pa0002 INDEX 1 INTO wa_pa0002.
* write to the screen or perform other operations
WRITE: / 'First name: ', wa_pa0002-vorna.
WRITE: / 'Last name: ' , wa_pa0002-nachn.
Please reward points if you found this helped. ***
regards,
Paul