Access to class attributs by coding in its mother class method definition

Question

Hi all,
How can I retrieve information about a class attributs by coding?
And is it possible to access to the attributs of the Child class from the Mother class?
REPORT  ztest_method.
******      CLASS mother DEFINITION
CLASS mother DEFINITION.
  PUBLIC SECTION.
    METHODS: get_data.
ENDCLASS.                    "mother DEFINITION
******      CLASS child DEFINITION
CLASS child DEFINITION inheriting from mother.
ENDCLASS.                    "child DEFINITION
*******      CLASS mother IMPLEMENTATION
CLASS mother IMPLEMENTATION.
  METHOD get_data.
***Can I access to child class attributs here?
  ENDMETHOD.                    "get_data
ENDCLASS.                    "mother IMPLEMENTATION
DATA oref TYPE REF TO CHILD.
DATA: method TYPE string.
DATA: cla_name(20).
START-OF-SELECTION.
  CREATE OBJECT oref .
  CALL METHOD oref->method).  "Here I want to access to this class's attribut without redefine it

Answer 1

Hi,
a very easy way is to define an attribute TYPE REF TO DATA in the super class and write generic access methods which work with it by dereferencing it and assigning a field symbol. This might even save you the effort of creating a class hierarchy, because one class may be able to handle all the data objects whose types are only known at run-time.
In the below example, the only specific thing about the sub class is the constructor in which the data object is created and typed:
REPORT  ztesta.
*       CLASS lcl_mother DEFINITION
CLASS lcl_mother DEFINITION.
  PUBLIC SECTION.
    METHODS get_data EXPORTING es_data TYPE any.
    METHODS set_data IMPORTING is_data TYPE any.
  PROTECTED SECTION.
    DATA mr_data TYPE REF TO data.
ENDCLASS.                    "lcl_mother DEFINITION
*       CLASS lcl_child1 DEFINITION
CLASS lcl_child1 DEFINITION INHERITING FROM lcl_mother.
  PUBLIC SECTION.
    METHODS constructor.
ENDCLASS.                    "lcl_child1 DEFINITION
DATA:
  lr_child      TYPE REF TO lcl_mother,
  ls_but000_in  TYPE        but000,
  ls_but000_out type        but000.
START-OF-SELECTION.
  CREATE OBJECT lr_child TYPE lcl_child1.
  ls_but000_in-partner = '0000004711'.
  lr_child->set_data( ls_but000_in ).
  lr_child->get_data( IMPORTING es_data = ls_but000_out ).
  write: / ls_but000_out-partner.
*       CLASS lcl_mother IMPLEMENTATION
CLASS lcl_mother IMPLEMENTATION.
  METHOD get_data.
    FIELD-SYMBOLS:
      <fs_data> TYPE ANY.
    ASSIGN mr_data->* TO <fs_data>.
    MOVE-CORRESPONDING <fs_data> TO es_data.
  ENDMETHOD.                    "get_data
  METHOD set_data.
    FIELD-SYMBOLS:
      <fs_data> TYPE ANY.
    ASSIGN mr_data->* TO <fs_data>.
    MOVE-CORRESPONDING is_data TO <fs_data>.
  ENDMETHOD.                    "set_data
ENDCLASS.                    "lcl_mother IMPLEMENTATION
*       CLASS lcl_child1 IMPLEMENTATION
CLASS lcl_child1 IMPLEMENTATION.
  METHOD constructor.
    super->constructor( ).
    CREATE DATA mr_data TYPE but000.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_child1 IMPLEMENTATION
Another variant would be to define an attribute MV_DATA which is typed individually in each sub class and program dynamically against it in the super class using field symbols.
*& Report  ZTESTA
REPORT  ztesta.
*       CLASS lcl_mother DEFINITION
CLASS lcl_mother DEFINITION.
  PUBLIC SECTION.
    METHODS get_data EXPORTING es_data TYPE any.
    METHODS set_data IMPORTING is_data TYPE any.
ENDCLASS.                    "lcl_mother DEFINITION
*       CLASS lcl_child1 DEFINITION
CLASS lcl_child1 DEFINITION INHERITING FROM lcl_mother.
  PUBLIC SECTION.
    DATA: ms_data TYPE but000.
    METHODS constructor.
ENDCLASS.                    "lcl_child1 DEFINITION
*       CLASS lcl_child2 DEFINITION
CLASS lcl_child2 DEFINITION INHERITING FROM lcl_mother.
  PUBLIC SECTION.
    DATA: ms_data TYPE t000.
    METHODS constructor.
ENDCLASS.                    "lcl_child1 DEFINITION
DATA:
  lr_child1     TYPE REF TO lcl_mother,
  lr_child2     TYPE REF TO lcl_mother,
  ls_but000     TYPE        but000,
  ls_t000       TYPE        t000.
START-OF-SELECTION.
  CREATE OBJECT lr_child1 TYPE lcl_child1.
  lr_child1->get_data( IMPORTING es_data = ls_but000 ).
  WRITE: / ls_but000-partner.
  CREATE OBJECT lr_child2 TYPE lcl_child2.
  lr_child2->get_data( IMPORTING es_data = ls_t000 ).
  WRITE: / ls_t000-mwaer.
*       CLASS lcl_mother IMPLEMENTATION
CLASS lcl_mother IMPLEMENTATION.
  METHOD get_data.
    FIELD-SYMBOLS:
      <fs_data> TYPE ANY.
    ASSIGN ('MS_DATA') TO <fs_data>.
    es_data = <fs_data>.
  ENDMETHOD.                    "get_data
  METHOD set_data.
    FIELD-SYMBOLS:
      <fs_data> TYPE ANY.
    ASSIGN ('MS_DATA') TO <fs_data>.
    <fs_data> = is_data.
  ENDMETHOD.                    "set_data
ENDCLASS.                    "lcl_mother IMPLEMENTATION
*       CLASS lcl_child1 IMPLEMENTATION
CLASS lcl_child1 IMPLEMENTATION.
  METHOD constructor.
    super->constructor( ).
    SELECT SINGLE * FROM but000 INTO ms_data.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_child1 IMPLEMENTATION
*       CLASS lcl_child2 IMPLEMENTATION
CLASS lcl_child2 IMPLEMENTATION.
  METHOD constructor.
    super->constructor( ).
    SELECT SINGLE * FROM t000 INTO ms_data.
  ENDMETHOD.                    "constructor
ENDCLASS.                    "lcl_child2 IMPLEMENTATION
I hope this helps!
Regards,
Thorsten