ALL_DEPENDENCIES isn't updated well

Question

Hi all,
may be i found an oracle error.
SQL> select * from ALL_DEPENDENCIES  where name = 'EMP';
OWNER  NAME TYPE    REFERENCED_OWNER               REFERENC REFERENCE REFERENC DEPENDEN
PUBLIC EMP  SYNONYM HR                             EMP_PKG  PACKAGE            HARDso this tell me that the type is a SYNONYM, while the following
SQL> select object_name,object_type from user_objects where object_name='EMP';
OBJECT_NAME OBJECT_TYPE
EMP         TABLEtell me that this is a table and that is true, is this an oracle bug?
Thanks so much
Francesco

Answer 1

unfortunately there is no any reference in the pkg EMP_PKG
CREATE OR REPLACE PACKAGE BODY EMP_PKG IS
  TYPE BOOL_TABTYPE IS TABLE OF BOOLEAN INDEX BY BINARY_INTEGER;
  VALID_DEPARTMENTS BOOL_TABTYPE;
  EMP_TABLE         EMP_TABTYPE;
  FUNCTION VALID_DEPTID(DEPTID IN DEPARTMENTS.DEPARTMENT_ID%TYPE) RETURN BOOLEAN IS
    DUMMY PLS_INTEGER;
  BEGIN
    SELECT 1
    INTO   DUMMY
    FROM   DEPARTMENTS
    WHERE  DEPARTMENT_ID = DEPTID;
    RETURN TRUE;
  EXCEPTION
    WHEN NO_DATA_FOUND THEN
      RETURN FALSE;
  END VALID_DEPTID;
  PROCEDURE ADD_EMPLOYEE(FIRST_NAME EMPLOYEES.FIRST_NAME%TYPE
                        ,LAST_NAME  EMPLOYEES.LAST_NAME%TYPE
                        ,EMAIL      EMPLOYEES.EMAIL%TYPE
                        ,JOB        EMPLOYEES.JOB_ID%TYPE DEFAULT 'SA_REP'
                        ,MGR        EMPLOYEES.MANAGER_ID%TYPE DEFAULT 145
                        ,SAL        EMPLOYEES.SALARY%TYPE DEFAULT 1000
                        ,COMM       EMPLOYEES.COMMISSION_PCT%TYPE DEFAULT 0
                        ,DEPTID     EMPLOYEES.DEPARTMENT_ID%TYPE DEFAULT 30) IS
    PROCEDURE AUDIT_NEWEMP IS
      PRAGMA AUTONOMOUS_TRANSACTION;
      USER_ID VARCHAR2(30) := USER;
    BEGIN
      INSERT INTO LOG_NEWEMP
        (ENTRY_ID
        ,USER_ID
        ,LOG_TIME
        ,NAME)
      VALUES
        (LOG_NEWEMP_SEQ.NEXTVAL
        ,USER_ID
        ,SYSDATE
        ,FIRST_NAME || ' ' || LAST_NAME);
      COMMIT;
    END;
  BEGIN
    IF VALID_DEPTID(DEPTID) THEN
      AUDIT_NEWEMP;
      INSERT INTO EMPLOYEES
        (EMPLOYEE_ID
        ,FIRST_NAME
        ,LAST_NAME
        ,EMAIL
        ,JOB_ID
        ,MANAGER_ID
        ,HIRE_DATE
        ,SALARY
        ,COMMISSION_PCT
        ,DEPARTMENT_ID)
      VALUES
        (EMPLOYEES_SEQ.NEXTVAL
        ,FIRST_NAME
        ,LAST_NAME
        ,EMAIL
        ,JOB
        ,MGR
        ,TRUNC(SYSDATE)
        ,SAL
        ,COMM
        ,DEPTID);
    ELSE
      RAISE_APPLICATION_ERROR(-20204, 'Invalid department id, try again ');
    END IF;
  END ADD_EMPLOYEE;
  PROCEDURE GET_EMPLOYEE(EMPID IN EMPLOYEES.EMPLOYEE_ID%TYPE
                        ,SAL   OUT EMPLOYEES.SALARY%TYPE
                        ,JOB   OUT EMPLOYEES.JOB_ID%TYPE) IS
  BEGIN
    SELECT SALARY
          ,JOB_ID
    INTO   SAL
          ,JOB
    FROM   EMPLOYEES
    WHERE  EMPLOYEE_ID = EMPID;
  END;
  PROCEDURE ADD_EMPLOYEE(FIRST_NAME EMPLOYEES.FIRST_NAME%TYPE
                        ,LAST_NAME  EMPLOYEES.LAST_NAME%TYPE
                        ,DEPTID     EMPLOYEES.DEPARTMENT_ID%TYPE DEFAULT 30) IS
    EMAIL EMPLOYEES.EMAIL%TYPE;
  BEGIN
    EMAIL := UPPER(SUBSTR(FIRST_NAME, 1, 1) || SUBSTR(LAST_NAME, 1, 7));
    ADD_EMPLOYEE(FIRST_NAME, LAST_NAME, EMAIL, DEPTID => DEPTID);
  END;
  PROCEDURE INIT_DEPARTMENS IS
  BEGIN
    FOR REC IN (SELECT DEPARTMENT_ID
                FROM   DEPARTMENTS)
    LOOP
      VALID_DEPARTMENTS(REC.DEPARTMENT_ID) := TRUE;
    END LOOP;
  END;
  PROCEDURE PRINT_EMPLOYEES(EMPREC EMPLOYEES%ROWTYPE) IS
  BEGIN
    DBMS_OUTPUT.PUT_LINE(EMPREC.DEPARTMENT_ID || ' ' || EMPREC.EMPLOYEE_ID || ' ' || EMPREC.LAST_NAME);
  END;
  PROCEDURE GET_EMPLOYEE(DEPTID IN EMPLOYEES.DEPARTMENT_ID%TYPE) IS
  BEGIN
    SELECT * BULK COLLECT
    INTO   EMP_TABLE
    FROM   EMPLOYEES
    WHERE  DEPARTMENT_ID = DEPTID;
  END GET_EMPLOYEE;
  PROCEDURE SHOW_EMPLOYEES IS
    I NUMBER;
  BEGIN
    FOR I IN EMP_TABLE.FIRST .. EMP_TABLE.LAST
    LOOP
      PRINT_EMPLOYEES(EMP_TABLE(I));
    END LOOP;
     I := EMP_TABLE.COUNT;
     WHILE I IS NOT NULL
     LOOP
       PRINT_EMPLOYEES(EMP_TABLE(I));
       I := EMP_TABLE.NEXT(I);
     END LOOP;
  END;
  PROCEDURE SET_SALARY(ID_JOB         VARCHAR2
                      ,NEW_MIN_SALARY NUMBER) IS
  BEGIN
    UPDATE EMPLOYEES
    SET    SALARY = NEW_MIN_SALARY
    WHERE  JOB_ID = ID_JOB;
  END;
BEGIN
  INIT_DEPARTMENS;
END EMP_PKG;