ALV - Full Screen Mode

Question

All,
I have ALV grid using CONTAINER , i need to make it FULL SCREEN mode as per the user screen display resolution.
Any Info ?
PS: Please donot suggest to drag the screen to maximum. that will not work with different screen resolution.
a®

Answer 1

In that case, as Uwe suggested you have to use the docking control to generate the ALV
Try like this:
DATA: gt_outtab TYPE TABLE OF sflight.
DATA: gr_table  TYPE REF TO cl_salv_table.
DATA: lo_dock TYPE REF TO cl_gui_docking_container,
      lo_cont TYPE REF TO cl_gui_container.
DATA: ok_code TYPE sy-ucomm.
START-OF-SELECTION.
*... Select data
  SELECT * FROM sflight INTO CORRESPONDING FIELDS OF TABLE gt_outtab.
  CALL SCREEN 0100.
*&      Module  STATUS_0100  OUTPUT
MODULE status_0100 OUTPUT.
"* Normal PF
  SET PF-STATUS 'SALV_STANDARD' OF PROGRAM 'SALV_DEMO_TABLE_EVENTS'.
  CHECK lo_dock IS INITIAL.
  CREATE OBJECT lo_dock
    EXPORTING
      repid     = sy-cprog
      dynnr     = '0100'
      ratio     = 95
      side      = cl_gui_docking_container=>dock_at_left.
*      name      = 'DOCK_CONT'.
  IF sy-subrc <> 0.
    MESSAGE 'Error in the Docking control' TYPE 'S'.
  ENDIF.
  lo_cont ?= lo_dock.
*... Create Instance
  CALL METHOD cl_salv_table=>factory
    EXPORTING
      r_container  = lo_cont
    IMPORTING
      r_salv_table = gr_table
    CHANGING
      t_table      = gt_outtab.
"* ALV's PF
  data: lr_functions type ref to cl_salv_functions_list.
  lr_functions = gr_table->get_functions( ).
  lr_functions->set_default( abap_true ).
*... Display table
  gr_table->display( ).
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Module  USER_COMMAND_0100  INPUT
MODULE user_command_0100 INPUT.
  CASE ok_code.
    WHEN '&F03' or '&F15' or '&F12'.
      LEAVE PROGRAM.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
Regards,
Naimesh Patel