ALV Grid contents to be saved as Report Varaint

Question

Hello Folks,
There is a requirement to select and specify Table Fields on the Report Selection Screen. The UI should be something in a form of a Table Control or an Editable ALV grid. ALV Grid is the choice made for capturing the Table Fields (through classical Dynpro).
This Table Fields will be then read in the program to retrieve data from the DB table and finally display it in the dynamic ALV.
I am thinking of how to achieve the following:
- Is it possible to have an editable ALV grid on a Report Selection Screen? If yes, how can it be achieved.
- is it possible to save the contents (data) on the ALV grid in something like a report variant. So that the the user do not have to fill-up the data in the grid everytime.
Thank you

Answer 1

Well , Let this be a start for you. In the below code the alv is displayed in selection screen and the values can be saved as variant.
The dynamic table creation stuff's are discussed a lot here, please search for that. The below code is just written instantly and can be firther corrected and optimized.
Execute and check it once.
TYPE-POOLS:slis.
CLASS lcl_event_receiver DEFINITION DEFERRED.
TYPES:BEGIN OF ty,
      field TYPE fld_namev,
      END OF ty.
DATA:it TYPE TABLE OF ty,
     wa TYPE ty,
     fieldcat TYPE lvc_t_fcat,
     l_valid TYPE c,
     obj type ref to cl_gui_alv_grid,
     g_verifier type ref to lcl_event_receiver,
     wa_fcat type lvc_s_fcat,
     repid type sy-repid,
    dock type ref to cl_gui_docking_container.
CLASS lcl_event_receiver DEFINITION.
  PUBLIC SECTION.
    METHODS:
      handle_data_changed
         FOR EVENT data_changed OF cl_gui_alv_grid
             IMPORTING er_data_changed.
ENDCLASS.
CLASS lcl_event_receiver IMPLEMENTATION.
  METHOD handle_data_changed.
    DATA:ls_good TYPE lvc_s_modi.
    LOOP AT er_data_changed->mt_good_cells INTO ls_good.
    ENDLOOP.
  ENDMETHOD.
ENDCLASS.
PARAMETERS:pa_tab TYPE tabname16.
PARAMETERS:pa_str TYPE string NO-DISPLAY.
AT SELECTION-SCREEN OUTPUT.
  IF NOT sy-slset IS INITIAL.
    SPLIT pa_str AT cl_abap_char_utilities=>cr_lf INTO TABLE it.
  ENDIF.
  IF dock IS INITIAL.
    repid = sy-repid.
    CREATE OBJECT dock
         EXPORTING
           repid = repid
           dynnr = sy-dynnr
           ratio = 80
           side  = cl_gui_docking_container=>dock_at_bottom
           name  = 'DOCK_CONT'.
  ENDIF.
  IF obj IS INITIAL.
    CREATE OBJECT obj
     EXPORTING
         i_parent          =  dock.
  ENDIF.
  IF fieldcat IS INITIAL.
    wa_fcat-fieldname = 'FIELD'.
    wa_fcat-seltext = 'Field Name'.
    wa_fcat-edit = 'X'.
    APPEND wa_fcat TO fieldcat.
  ENDIF.
  if g_verifier is initial.
  CREATE OBJECT g_verifier.
  SET HANDLER g_verifier->handle_data_changed FOR obj.
  endif.
  CALL METHOD obj->set_table_for_first_display
   CHANGING
   it_fieldcatalog = fieldcat
   it_outtab = it.
  CALL METHOD obj->set_ready_for_input
   EXPORTING
    i_ready_for_input = 1.
AT SELECTION-SCREEN.
  IF sy-ucomm EQ 'SPOS'.
    CALL METHOD obj->check_changed_data
               IMPORTING e_valid = l_valid.
    LOOP AT it INTO wa.
      IF sy-tabix = 1.
        pa_str = wa-field.
      ELSE.
        CONCATENATE pa_str cl_abap_char_utilities=>cr_lf
                wa-field INTO pa_str.
      ENDIF.
    ENDLOOP.
  ENDIF.
START-OF-SELECTION.