ALV Grid - Resource Issue?

Question

Morning All
I have a situation where I have a standard selection screen displaying an ALV grid.  The user can then double click a line to see a drill down ALV.  My error occurs if the user executes the program multiple times i.e. displaying the grid time and time again.  Eventually the session does not display the grid and on a subsequent attempt the session either crashes or locks.
I am currently destroying the 2 containers used every time the user exits the relevant screens using call method gr_alvgrid-> free but to no avail.
Has anyone else had similar problems?  I am on a 46B machine running on NT4 (yes I know I'm in the dark ages!)
Cheers
Ian

Answer 1

Hi,
Have you did something like that before creating event receiver?
IF cl_gui_alv_grid=>offline( ) IS INITIAL.
* Create the event reciever
    IF o_eventreceiver IS INITIAL.
      CREATE OBJECT o_eventreceiver.
    ENDIF.
  ENDIF.
In PAI of the screen,just try this.
module USER_COMMAND_9001 input.
  CASE sy-ucomm.
    WHEN 'EXIT' or  'CANC'.
      perform f9600_free_objects:
               using o_Alvgrid 'ALV' text-E02,
               using o_Dockingcontainer 'DOCKING'
                       TEXT-E01.
* leave program.
      LEAVE PROGRAM.
    when 'BACK'.
      perform f9600_free_objects:
               using o_Alvgrid 'ALV' text-E02,
               using o_Dockingcontainer 'DOCKING'
                       TEXT-E01.
      set screen '0'.
      leave screen.
* This leaves the program but you may need to re-call the
* transaction to go back to the original screen
    when others.
  ENDCASE.
endmodule.                 " USER_COMMAND_9001  INPUT
FORM f9600_free_objects USING pobject
                    value(ptype)
                    value(ptext).
  DATA: l_objectalv TYPE REF TO cl_gui_alv_grid.
* Need to type the field symbol or it does not work
  CASE ptype.
    WHEN 'ALV'.
      l_objectalv = pobject.
      IF NOT ( l_objectalv IS INITIAL ).
        CALL METHOD l_objectalv->free
          EXCEPTIONS
            cntl_error        = 1
           cntl_system_error = 2
            OTHERS            = 3.
        CLEAR: pobject, l_objectalv.
        PERFORM f9700_error_handle USING ptext.
      ENDIF.
    WHEN 'DOCKING'.
      DATA: lobjectdock TYPE REF TO cl_gui_docking_container.
      lobjectdock = pobject.
      IF NOT ( lobjectdock IS INITIAL ).
        CALL METHOD lobjectdock->free
          EXCEPTIONS
            cntl_error        = 1
           cntl_system_error = 2
            OTHERS            = 3.
        CLEAR: pobject, lobjectdock.
        PERFORM f9700_error_handle USING ptext.
      ENDIF.
    WHEN 'CONTAINER'.
      DATA: lobjectcontainer TYPE REF TO cl_gui_container.
      lobjectcontainer = pobject.
      IF NOT ( lobjectcontainer IS INITIAL ).
        CALL METHOD lobjectcontainer->free
          EXCEPTIONS
            cntl_error        = 1
           cntl_system_error = 2
            OTHERS            = 3.
        CLEAR: pobject, lobjectcontainer.
        PERFORM f9700_error_handle USING ptext.
      ENDIF.
    WHEN OTHERS.
      sy-subrc = 1.
      PERFORM f9700_error_handle USING
                                text-e04.
  ENDCASE.
ENDFORM.                    " f9600_free_objects
FORM f9700_error_handle USING    value(ptext).
  IF sy-subrc NE 0.
* add your handling, for example
    CALL FUNCTION 'POPUP_TO_INFORM'
         EXPORTING
              titel = text-e03
              txt2  = sy-subrc
              txt1  = ptext.
  ENDIF.
ENDFORM.                    " f9700_error_handle
Message was edited by: Jayanthi Jayaraman