ALV Grid Refresh Issue

Question

Hello!
    I am using the FM 'REUSE_ALV_GRID_DISPLAY' to display a report we have written. The report displays sales orders and when the user double-clicks on a line they are taken in VA02. I put in a change to have the report refresh after the user came back from VA02. I put in the code p_selfield-refresh = 'X' in the user_command section. This was working before and now it is not refreshing. I'm wondering if this has to do with a default layout we added after these changes were put in. I've done some google searches and I can find object-oriented code but my report is not setup that way so hopefully there is a solution for me!
Thanks,
Wendy

Answer 1

If you set refresh subfield (and row/col_stable subfields if sort fields are not changed), then you should update the internal table record in your user_command form. You need to reload the data from database, but there may be a delay between leaving VA02 and actual update of database, you may try to lock the sales order to insure update task release the lock. (DO/ENQUEUE_EVVBAKE with WAIT/ENDDO and when/if successful DEQUEUE_EVVBAKE, if not successful after some tries, put a warning/status message)
* init data
CLEAR: lv_error,
refresh lt_bdcmsg.
* Read record
READ TABLE gt_data INTO old_data
  INDEX rs_selfield-tabindex.
CHECK sy-subrc EQ 0.
* Call VA02
SET PARAMETER ID 'AUN' FIELD old_data-vbeln.
CALL transaction 'VA02' AND SKIP FIRST SCREEN
  MESSAGES into lt_bdcmsg.
* Call successful ?
LOOP AT lt_bdcmsgcoll INTO ls_bdcmsg WHERE msgtyp = 'E' OR msgtyp = 'S'.
  MESSAGE message ID ls_bdcmsg-msgid TYPE ls_bdcmsg-msgtyp
    NUMBER ls_bdcmsg-msgnr WITH ls_bdcmsg-msgv1. " 2 3 4
  IF ls_bdcmsg-msgtyp EQ 'E'.
    lv_error = 'X'.
    EXIT.
  ENDIF.
ENDLOOP.
CHECK lv_error IS INITIAL.
* Is update ended
DO 10 TIMES.
  CALL FUNCTION 'ENQUEUE_EVVBAKE'
       EXPORTING
            vbeln          = old_data-vbeln
            _wait          = 'X'
       EXCEPTIONS
            foreign_lock   = 1
            system_failure = 1
            OTHERS         = 1.
  IF sy-subrc EQ 0.
    CALL FUNCTION 'DEQUEUE_EVVBAKE'
         EXPORTING
              vbeln  = old_data-vbeln
         EXCEPTIONS
              OTHERS = 0.
    EXIT.
  ENDIF.
ENDDO.
* Reload
new_data = old_data.
SELECT SINGLE * FROM vbak INTO CORRESPONDING FIELDS OF new_data
  WHERE vbeln = l_sdata-vbeln. " more coding for other fields
* Update internal table
IF new_data NE old_data.
  MODIFY gt_data FROM new_data.
  rs_selfield-refresh = 'X'.
ENDIF.
Regards,
Raymond