Alv not displaying top-of-page

Question

hi every buddy,
i am workiong on report where there  is a requirment of dislpaying alv
with top of page having some details . the event function mudule is calling the top-of-page fm properly
but perform for top-of page is not called up
i.e. controls are not goin to that point of perform
please give me your valuable suggestions
regards
prashant

Answer 1

Hi,
please check this code it is working
type-pools: slis.
* Including icon for icon display
include <icon>.
* Including symbol
include <symbol>.
* Declaring structure for vbak
types: begin of t_vbak,
        vbeln type vbeln_va,
        auart type auart,
        netwr type netwr,
        vkorg type vkorg,
        vtweg type vtweg,
        erdat type erdat,
        vbtyp type vbtyp,
        augru type augru,
        icon  type icon-id,
      end of t_vbak.
* Declaring structure for vbap
types: begin of t_vbap,
       vbeln type vbeln_va,
       posnr type posnr,
       matnr type matnr,
       arktx type arktx,
       lsmeng type dzmeng,
       auart type auart,
       netwr type netwr,
       vkorg type vkorg,
       vtweg type vtweg,
       erdat type erdat,
       vbtyp type vbtyp,
       augru type augru,
       icon  type icon-id,
     end of t_vbap.
* Declaring variables
data: v_vbeln type vbeln,
      my_tab type sy-tabix.
* Declaring internal table and wa for vbak and vbap
data: i_vbak type table of t_vbak,
      wa_vbak type t_vbak,
      i_vbap type table of t_vbap,
      i_pbo type table of t_vbap,
      wa_vbap type t_vbap.
* Declaring internal table and wa for alv components(fieldcatalog,layout,events,header)
data: i_fieldcat type slis_t_fieldcat_alv,
      wa_fieldcat type slis_fieldcat_alv,
      wa_layout   type slis_layout_alv,
      i_event    type slis_t_event,
      wa_event   type slis_alv_event,
      i_header   type slis_t_listheader,
      wa_header   type slis_listheader,
      wa_varient  type disvariant,
      wa_sort     type slis_sortinfo_alv,
      i_sort     type slis_t_sortinfo_alv.
* Declaring selection-screen details
selection-screen: begin of block b1 with frame title text-001.
selection-screen skip.
select-options: s_vbeln for v_vbeln.
selection-screen: begin of block b2 with frame title text-008.
parameter: ch1 type c as checkbox,       "check bos for Subtotal.
           ch2 type c as checkbox.       "check box for Grand total.
selection-screen: end of block b2.
selection-screen: end of block b1.
* Start of start-of-selection
start-of-selection.
* Fetching data from vbak table
  select vbeln
         auart
         netwr
         vkorg
         vtweg
         erdat
         vbtyp
         augru
       from vbak into table i_vbak
             where vbeln in s_vbeln.
  if sy-subrc = 0.
* Fetching data for vbap table
    select vbeln
           posnr
           matnr
           arktx
           lsmeng
         from vbap into table i_vbap
         for all entries in i_vbak
         where vbeln = i_vbak-vbeln.
  endif.
* Looping data for final output
  loop at i_vbak into wa_vbak.
* checking conditiions for icon
    if wa_vbak-netwr < 10000.
      wa_vbak-icon = '@08@'.
    elseif wa_vbak-netwr < 15000.
      wa_vbak-icon = '@09@'.
    else.
      wa_vbak-icon = '@0A@'.
    endif.
    modify i_vbak from wa_vbak index sy-tabix  .
  endloop.
*Looping data for final output
  loop at i_vbap into wa_vbap.
    my_tab = sy-tabix.
    read table i_vbak into wa_vbak with key vbeln = wa_vbap-vbeln.
    if sy-subrc = 0.
      wa_vbap-auart = wa_vbak-auart.
      wa_vbap-netwr = wa_vbak-netwr.
      wa_vbap-vkorg = wa_vbak-vkorg.
      wa_vbap-vtweg = wa_vbak-vtweg.
      wa_vbap-erdat = wa_vbak-erdat.
      wa_vbap-vbtyp = wa_vbak-vbtyp.
      wa_vbap-augru = wa_vbak-augru.
      wa_vbap-icon  = wa_vbak-icon.
      modify i_vbap from wa_vbap index  my_tab transporting
                             auart netwr vkorg vtweg erdat vbtyp augru icon.
    endif.
  endloop.
* Preparing fieldcatalog for final output
  perform main_fieldcat.
*Preparing final layout for final output
  perform layout.
*Preparing list header for final output
  perform list_header.
*Preaparing events for alv display
  perform event.
*Getting subtotals for amount fields
  if ch1 eq 'X'.
    perform sub_total.
  endif.
*Showing final output data
  perform alv_display.
form main_fieldcat .
*Fieldcatalog for icon
  wa_fieldcat-fieldname = 'ICON'.
* WA_FIELDCAT-TECH     = 'X'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-icon      = 'X'.
  wa_fieldcat-seltext_l = 'ICON'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
* Fieldcatalog for salesorder
  wa_fieldcat-fieldname = 'VBELN'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C410'.
  wa_fieldcat-seltext_l = 'Sales order NO'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for salesordertype
  wa_fieldcat-fieldname = 'AUART'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C610'.
  wa_fieldcat-seltext_l = 'Sales order type'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for netamount
  wa_fieldcat-fieldname = 'NETWR'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-edit   = 'X'.
  wa_fieldcat-emphasize = 'C501'.
*  wa_fieldcat-input = 'X'.
  wa_fieldcat-seltext_l = 'Net Amount'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for salesorg
  wa_fieldcat-fieldname = 'VKORG'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C310'.
  wa_fieldcat-seltext_l = 'Sales Organization'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for salesdistribution
  wa_fieldcat-fieldname = 'VTWEG'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C210'.
  wa_fieldcat-seltext_l = 'Sales Distribution'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for date
  wa_fieldcat-fieldname = 'ERDAT'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C110'.
  wa_fieldcat-seltext_l = 'Sales OrderDate'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for salestype
  wa_fieldcat-fieldname = 'VBTYP'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C410'.
  wa_fieldcat-seltext_l = 'Sales type'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for orderreason
  wa_fieldcat-fieldname = 'AUGRU'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C710'.
  wa_fieldcat-seltext_l = 'Order reason '.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for itemnum
  wa_fieldcat-fieldname = 'POSNR'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C110'.
  wa_fieldcat-seltext_l = 'Item No '.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for materialnum
  wa_fieldcat-fieldname = 'MATNR'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C710'.
  wa_fieldcat-seltext_l = 'Material No '.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
  wa_fieldcat-fieldname = 'ARKTX'.
  wa_fieldcat-tabname   = 'IT_VBAP'.
  wa_fieldcat-emphasize = 'C310'.
  wa_fieldcat-seltext_l = 'Description'.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
*Fieldcatalog for quantity
  if ( ch1 = 'X' and ch2 = 'X' ) or ( ch1 = 'X' and ch2 = ' ' ) or ( ch2 = 'X' and ch1 = ' ' ).
    wa_fieldcat-fieldname = 'LSMENG'.
    wa_fieldcat-tabname   = 'IT_VBAP'.
    wa_fieldcat-emphasize = 'C510'.
    wa_fieldcat-seltext_l = 'Quantity '.
*    WA_FIELDCAT-edit   = 'X'.
    wa_fieldcat-do_sum     = 'X'.
  else.
    wa_fieldcat-fieldname = 'LSMENG'.
    wa_fieldcat-tabname   = 'IT_VBAP'.
    wa_fieldcat-emphasize = 'C510'.
    wa_fieldcat-seltext_l = 'Quantity '.
*    WA_FIELDCAT-edit   = 'X'.
  endif.
  append wa_fieldcat to i_fieldcat.
  clear wa_fieldcat.
endform.                    " MAIN_FIELDCAT
form alv_display .
  wa_varient-report = sy-repid.
  call function 'REUSE_ALV_GRID_DISPLAY'
    exporting
      i_callback_program       = sy-repid
      is_layout                = wa_layout
      it_fieldcat              = i_fieldcat
      it_sort                  = i_sort
      i_callback_pf_status_set = 'PF_STATUS'
      i_save                   = 'X'
      is_variant               = wa_varient
      it_events                = i_event
    tables
      t_outtab                 = i_vbap
    exceptions
      program_error            = 1
      others                   = 2.
  if sy-subrc <> 0.
    message id sy-msgid type sy-msgty number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  endif.
endform.                    " ALV_DISPLAY
form layout .
  wa_layout-colwidth_optimize = 'X'.
  wa_layout-subtotals_text    = 'SUBTOTAL SUM'.
  wa_layout-totals_text       = 'TOTAL'.
  wa_layout-zebra             = 'X'.
endform.                    " LAYOUT
form event .
  call function 'REUSE_ALV_EVENTS_GET'
    importing
      et_events       = i_event
    exceptions
      list_type_wrong = 1
      others          = 2.
  if sy-subrc <> 0.
    message id sy-msgid type sy-msgty number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  endif.
  read table i_event into wa_event with key name = 'USER_COMMAND'.
  if sy-subrc = 0.
    wa_event-form = 'USER_COMMAND'.
    modify i_event from wa_event transporting form where name = 'USER_COMMAND'.
  endif.
  read table i_event into wa_event with key name = 'TOP_OF_PAGE'.
  if sy-subrc = 0.
    wa_event-form = 'TOP_OF_PAGE'.
    modify i_event from wa_event transporting form where name = 'TOP_OF_PAGE' .
  endif.
endform.                    " EVENT
form user_command using ucomm type sy-ucomm
                        selfield type slis_selfield.
  data: gstring type c.
  constants: l_c_repid type sy-repid value 'ZCOE_ALV_SIMPLE'.
  data: l_i_seltab type table of rsparams.
  case ucomm.
    when '&IC1'.
      if selfield-fieldname = 'VBELN'.
        set parameter id 'AUN' field selfield-value.
        call transaction 'VA02' and skip first screen.
      endif.
*  *  CASE ok_code.
    when 'SAVE'.
*  *A pop up is called to confirm the saving of changed data
      call function 'POPUP_TO_CONFIRM'
        exporting
          titlebar       = 'SAVING DATA'
          text_question  = 'Continue?'
          icon_button_1  = 'icon_booking_ok'
        importing
          answer         = gstring
        exceptions
          text_not_found = 1
          others         = 2.
      if sy-subrc ne 0.
*       MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      endif.
*      *When the User clicks 'YES'
      if ( gstring = '1' ).
        message 'Saved' type 'S'.
*Now the changed data is stored in the it_pbo internal table
        i_pbo = i_vbap.
      else.
*When user clicks NO or Cancel
        message 'Not Saved'  type 'S'.
      endif.
**When the user clicks the 'EXIT; he is out
    when 'EXIT'.
      leave program.
* Clicking on refresh button at toolbar
    when 'REF'.
* Calling fm to get refresh data
      call function 'RS_REFRESH_FROM_SELECTOPTIONS'
        exporting
          curr_report     = l_c_repid
        tables
          selection_table = l_i_seltab
        exceptions
          not_found       = 1
          no_report       = 2
          others          = 3.
      if sy-subrc <> 0.
        message id sy-msgid type sy-msgty number sy-msgno
                with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
      else.
*  * Calling the screen after refreshing
        submit zcoe_alv_simple with selection-table l_i_seltab.
      endif.
  endcase.
endform.                    " USER_COMMAND
form top_of_page .
  call function 'REUSE_ALV_COMMENTARY_WRITE'
    exporting
      it_list_commentary = i_header.
endform.                    " TOP_OF_PAGE
form list_header .
* Local data declaration
  data: l_date      type char10,    "Date
        l_time(8)   type c.         "Time
  wa_header-typ = 'H'.
  wa_header-info = 'Sales Order Information Report'.
  append wa_header to i_header.
* Run date Display
  clear l_date.
  wa_header-typ  = 'S'.
  write: sy-datum  to l_date dd/mm/yyyy.
  wa_header-key = 'Run Date :'(002).
  wa_header-info = l_date.
  append wa_header to i_header.
  clear: wa_header.
  wa_header-typ  = 'S'.
*  WRITE: sy-uzeit  TO l_time .
  l_time+0(2) = sy-uzeit+0(2).
  l_time+2(1) = ':'.
  l_time+3(2) = sy-uzeit+2(2).
  l_time+5(1) = ':'.
  l_time+6(2) = sy-uzeit+4(2).
  wa_header-key = 'Run Time :'(009).
  wa_header-info = l_time.
  append wa_header to i_header.
  clear: wa_header.
endform.                    " LIST_HEADER
form pf_status using rt_extab type slis_t_extab.
  set pf-status 'SSS'.
  set titlebar 'MAIN100'.
endform.                    "pf_status
form sub_total .
  wa_sort-fieldname = 'VBELN'.
  wa_sort-tabname   = 'I_VBAP'.
  wa_sort-spos      = 1.
  wa_sort-up        = 'X'.
  wa_sort-subtot    = 'X'.
*  wa_sort-group = 'X'.
*  WA_SORT-EXPA       = 'X'.
  append wa_sort to i_sort.
endform.                    " SUB_TOTAL