AppleScript error with iTunes: Can't get window 'iTunes' of class pcap ...

Question

Hi there. I'm working on a script that posts iTunes track names to Campfire based on the AirPlay device in use. I've been getting a "Can't get window 'iTunes' of <<class pcap>> 'iTunes' of application 'System Events'" and was hoping someone might see an obvious answer. The error pops up randomly. Some machines receive the error much more often than others. Here's the code:
global current_track
global last_track
global campfire_token
global airplay_device
global campfire_room
global current_device
(* Begin user defined settings ************)
set campfire_token to "123456" (* Your Campfire API authentication token *)
set airplay_device to "Apple TV" (* The name of your AirPlay device *)
set campfire_room to "https://yourorg.campfirenow.com/room/123456/speak.xml" (* The Campfire room you'd like to post to *)
(* End user defined settings *************)
set current_track to ""
set current_device to ""
set last_track to ""
on idle
          if application "iTunes" is running then
                    tell application "iTunes"
                              if player state is playing then
                                        tell application "System Events"
                                                  tell application "iTunes"
                                                            set minimized of front browser window to false (*This AppleScript can only function when iTunes is not minimized.  *)
                                                            delay 2
                                                            set visible of front browser window to true
                                                            delay 2
                                                            set current_track to current track
                                                  end tell
                                                  delay 2
                                                  set current_device to the description of button 8 of window "iTunes" of application process "iTunes" of application "System Events"
                                        end tell
                                        delay 2
                                        if current_track is not equal to last_track then
                                                  if current_device as string is equal to airplay_device & " AirPlay" then
                                                            tell application "iTunes"
                                                                      set current_track to current track
                                                                      tell current_track
                                                                                set trackName to (name)
                                                                                set artistName to (" :: " & artist)
                                                                                set albumName to (" :: " & album)
                                                                      end tell
                                                                      set track_info to (trackName & artistName & albumName) as string
  (* Replace apostrophes *)
                                                                      set search_string to "'"
                                                                      set replacement_string to "&#39;"
                                                                      set AppleScript's text item delimiters to the search_string
                                                                      set the item_list to every text item of track_info
                                                                      set AppleScript's text item delimiters to the replacement_string
                                                                      set track_info to the item_list as string
                                                                      set AppleScript's text item delimiters to ""
  (* Replace quotation marks *)
                                                                      set search_string to "\""
                                                                      set replacement_string to "&#34;"
                                                                      set AppleScript's text item delimiters to the search_string
                                                                      set the item_list to every text item of track_info
                                                                      set AppleScript's text item delimiters to the replacement_string
                                                                      set track_info to the item_list as string
                                                                      set AppleScript's text item delimiters to ""
                                                                      set shellCommand to ("curl -u " & campfire_token & ":X -H 'Content-Type: application/xml' -d '<message><type>TextMessage</type><body>" & track_info & "</body></message>' " & campfire_room)
                                                                      set shellCommand to shellCommand as string
  do shell script shellCommand
  (*display dialog shellCommand*)
  (*log "Posting to Campfire:" & shellCommand*)
                                                            end tell
                                                            delay 2
                                                  end if
                                        end if
                                        set last_track to current_track
                              end if
                              return 1
                    end tell
          end if
end idle
Thanks for your help. Any suggestions are appreciated!

Answer 1

well, for information's sake, the cleaned-up script looks like this:
(* Begin user defined settings ************)
property campfire_token : "123456" (* Your Campfire API authentication token *)
property airplay_device : "Apple TV" (* The name of your AirPlay device *)
property campfire_room : "https://yourorg.campfirenow.com/room/123456/speak.xml" (* The Campfire room you'd like to post to *)
(* End user defined settings *************)
global current_track, last_track, current_device
on run
  (* init at runtime*)
          set current_track to ""
          set current_device to ""
          set last_track to ""
end run
on idle
          if application "iTunes" is not running then return 60
          tell application "iTunes"
                    if (player state is not playing) or (current track is equal to last_track) then return
                    set last_track to current track
                    set minimized of front browser window to false
                    set visible of front browser window to true
                    set current_device to my getDevice()
                    if current_device as string is not equal to airplay_device & " AirPlay" then return
                    set track_info to my mungeText({name, artist, album} of last_track, "", "::")
                    set track_info to my mungeText(track_info, "'", "&#39;") -- Replace apostrophes
                    set track_info to my mungeText(track_info, "\"", "&#34;") -- Replace quotation marks
                    set shellCommand to ("curl -u " & campfire_token & ":X -H 'Content-Type: application/xml' -d '<message><type>TextMessage</type><body>" & track_info & "</body></message>' " & campfire_room)
  do shell script (shellCommand as string)
  (*display dialog shellCommand*)
  (*log "Posting to Campfire:" & shellCommand*)
                    return
          end tell
end idle
on getDevice()
          tell application "System Events"
                    tell process "iTunes"
                              return description of button 8 of window "iTunes"
                    end tell
          end tell
end getDevice
on mungeText(itxt, stxt, rtxt)
          set tid to AppleScript's text item delimiters
          if class of itxt is text then
                    set AppleScript's text item delimiters to stxt
                    set itxt to text items of itxt
          end if
          set AppleScript's text item delimiters to rtxt
          set otxt to itxt as text
          set AppleScript's text item delimiters to tid
          return otxt
end mungeText
I'm positive there's a better way to check if AirTunes is the active device (maybe by seeing if the current playlist is a device playlist, and checking the source name?), but I don't have any way to test that.